Setting timeout for LoadImage()/LoadBank()

BlitzMax Forums/BlitzMax Programming/Setting timeout for LoadImage()/LoadBank()

Richard Betson

(Posted 2013) [#1]

Hi,

I am using the following code to download images off the net.

LoadImage(LoadBank("http::phoenixusc.com/myimage.jpg"))

The problem is if there is no TCP access due to whatever reason the compiled application stalls for about 5 or seconds. Is there a way to set the timeout range so that it's not waiting for the file so long?

Thanks,
- Rich -

GfK	(Posted 2013) [#2]

Could you not try opening a stream to the URL first, and if that succeeds, THEN load the image?

Richard Betson

(Posted 2013) [#3]

Hi,

I could but I would have the same problem of it hanging up the application if there is no URL resource available. Using Bnetex I also get a delay of about 5 seconds when say opening a TCP stream if there is no stream TCP resource available. I looked over vertex's code and it looks like the problem lies in BRL's stream or socket code.

I might give it a shot to check, but not hopeful.

My gut feeling is that this might be a good use for threading. But I would really like to avoid that as it might not be possible to use in my well developed game (25k+ lines).

- Rich -

Grisu

(Posted 2013) [#4]

You could use Brucey's libcurl for such multi-threadding tasks.

I used it to eliminate the "hangs" of my internal updater function.

Some source code can be found here (2 half of the thread):
http://www.blitzbasic.com/Community/posts.php?topic=99640#1172307

BlitzSupport

(Posted 2013) [#5]

I also get a delay of about 5 seconds when say opening a TCP stream if there is no stream TCP resource available

In what situation do you get this delay? This, for example, exits immediately for me:

Local image:TImage = LoadImage(LoadBank("http::lalala.madeup/myimage.jpg"))

Failing that, perhaps you could try this code, setting up some Prints to see where exactly it freezes up?


SuperStrict

Function DownloadToBank:TBank (url:String)

	If Not url Then Return Null
	
	Local success:Int = False	' File downloaded OK...
	Local done:Int = False		' Exit download loop (for retries, etc)...
	
	Local host:String
	Local file:String
	
	Local bytestoread:Int
	Local location:String
	Local pos:Int

	Local bank:TBank
	
	Print ""
	Print "Downloading..."
	Print ""
	
	Repeat
	
		If Left (url, 7) = "http://"
			url= Right (url, Len (url) - 7)
		EndIf
		
		Local slash:Int = Instr (url, "/")
	
		If slash
			host = Left (url, slash - 1)
			file = Right (url, Len (url) - slash + 1)
		Else
			host = url
			file = "/"
		EndIf

		Local http:TSocket = CreateTCPSocket ()
		
		If http
		
			If ConnectSocket (http, HostIp (host), 80)
				
				Local www:TStream = CreateSocketStream (http)
				
				WriteLine www, "GET " + file + " HTTP/1.1" ' "GET /" gets default page...
				WriteLine www, "Host: " + host
				WriteLine www, "User-Agent: BlitzGet Deluxe"
				WriteLine www, "Accept: */*"
				WriteLine www, ""
	
				Local response:String = ReadLine (www)
		
				Print "Server response: " + response
				
				Local replycode:String
				
				If Left (response, 5) = "HTTP/"
					pos = Instr (response, " ")
					replycode = Mid (response, pos + 1, 3)
				EndIf
	
				Local header:String
	
				Repeat
			
					header = ReadLine (www)
			
					Local reply:String = ""
	
					pos = Instr (header, ": ")
	
					If pos
						reply = Left (header, pos + 1)
					EndIf
			
					Select Lower (reply)
						Case "content-length: "
							bytestoread = Int (Right (header, Len (header) - Len (reply)))
						Case "location: "
							location = Right (header, Len (header) - Len (reply))
					End Select
	
					If header Then Print header ' Skip blank line (if header = "" then nothing is printed)...
									
				Until header$ = "" Or (Eof (www))
	
				Select replycode$
		
					Case "200" ' File found...
		
						Print "Downloading file..."
						
						bank = CreateBank (bytestoread)
						Local save:TStream = CreateBankStream (bank)
	
						If save
					
							' Crude download routine!
							
							CopyBytes www, save, bytestoread
					
							done = True
						
						Else
							Print "Failed to create local file!"
						EndIf
	
					Case "404" ' File Not found...
					
						Print "File not found"
						done = True
					
					Case "301" ' File permanently moved...
					
						url = location

					Case "302" ' File temporarily moved...
			
						url = location
		
					Case "303" ' File moved...
		
						url = location
		
					Case "307" ' Naughty...
		
						url = location
						
				End Select
	
			EndIf
			
			CloseSocket http
			
		EndIf

		' If 'done' is still false, go back to the start with new URL (from '30*' responses)...
		
	Until done
		
	Return bank
	
End Function

Graphics 640, 480

Local download:String = "http://www.hi-toro.com/boing.png"

Local imagebank:TBank = DownloadToBank (download)

If imagebank
	
	Print ""
	Print "File downloaded successfully!"
	
	Local image:TImage = LoadImage (imagebank)
	
	If image = Null Then RuntimeError "Image not loaded!"
	
	Repeat
	
		Cls
		DrawImage image, MouseX (), MouseY ()
		Flip
		
	Until KeyHit (KEY_ESCAPE)
	
	End
	
Else
	Print ""
	Print "Download failed!"
EndIf

Brucey

(Posted 2013) [#6]

In what situation do you get this delay?

It's possible for DNS resolution to be slow under certain circumstances.
So you can't really assume that everything is always going to be instantaneous - especially over the internet.

xlsior

(Posted 2013) [#7]

Another possibility is a firewall (like zonealarm) blocking the TCP stream, which will cause the application to time out