Multithreading

BlitzMax Forums/BlitzMax Programming/Multithreading

Twinprogrammer

(Posted 2013) [#1]

Hey guys,

I was wondering if there is a way to utilize multithreading in Blitz Max, and if there is, is it a mod, or is it already in Blitz Max?

xlsior

(Posted 2013) [#2]

It's already built in.

Works fairly well, with some limitations -- for example, you can only draw to the screen from the main program thread, the drawing commands aren't thread-safe. You can use most of the other commands in different threads, though. (game logic, network communications, etc.)

Twinprogrammer

(Posted 2013) [#3]

Ok, cool. How do I use it, could you give me an example?

Hardcoal

(Posted 2013) [#4]

example will be welcomed .. here as well

Twinprogrammer

(Posted 2013) [#5]

I found a sample on multithreading, which is at the bottom of the samples list. REMEMBER TO RUN ON THREADED BUILD!

Twinprogrammer

(Posted 2013) [#6]

I also found an example in the blitz max docs (not the manual on the website). Here's the example on the Blitz Max docs:

'Make sure to have 'Threaded build' enabled!
'
Strict

'Custom print that shows which thread is doing the printing
Function MyPrint( t$ )
	If CurrentThread()=MainThread() 
		Print "Main thread: "+t
	Else
		Print "Child thread: "+t
	EndIf
End Function

'Our thread function
Function MyThread:Object( data:Object )

	'show data we were passed
	Myprint data.ToString()

	'do some work
	For Local i=1 To 1000
		MyPrint "i="+i
	Next
	
	'return a value from the thread
	Return "Data returned from child thread."
	
End Function

MyPrint "About to start child thread."

'create a thread!
Local thread:TThread=CreateThread( MyThread,"Data passed to child thread." )

'wait for thread to finish and print value returned from thread
MyPrint WaitThread( Thread ).ToString()

And here's the sample in the samples folder:





' -----------------------------------------------------------------------------
' MAKE SURE "Threaded Build" IS CHECKED IN THE Program -> Build Options menu!
' -----------------------------------------------------------------------------





' -----------------------------------------------------------------------------
' Simple thread demo...
' -----------------------------------------------------------------------------

' Mutexes are used to allow only one thread to access a variable or object in
' memory.

' A thread (including the main program's thread) can call LockMutex
' on a mutex, and if another thread has already locked the mutex, it will
' wait until the other thread has unlocked the mutex, then gain the lock. It's
' important that a thread calls UnlockMutex when it's done what it needs to do!

' The main program's thread and the spawned thread will both attempt to lock
' this mutex throughout, waiting on each other if they can't lock it...

Global Mutex = CreateMutex ()

' Try commenting out the above line, then scroll back through the output of
' the program, and you should see that the threads are fighting for access to
' the output console, creating intermeshing, gibberish text...

Print ""
Print "NOTE: Output of the two threads may not always alternate between 'Main' and 'Thread'..."
Print ""

' Create thread using Test () function and pass Null parameter...

thread:TThread = CreateThread (Test, Null)

' The new thread has now started. Do some stuff in the main program...

For a = 1 To 100

	' Other thread may be using the Print command (which isn't thread-friendly),
	' so LockMutex will wait until the thread has unlocked the mutex, and then
	' lock it so main program can call Print. It will then unlock the mutex so
	' the other thread can continue if it's ready (ie. waiting at its own
	' LockThread call)...
	
	If Mutex Then LockMutex (Mutex)
		Print "Main: " + a
	If Mutex Then UnlockMutex (Mutex)

	' Note: You'd normally just do this like the Rem'd out code below! The
	' "If Mutex" check here is to allow you to comment out the line
	' "Global Mutex = CreateMutex ()" to see why mutexes are needed...

	' You would also not normally use LockMutex so heavily, as it will
	' slow things down if over-used...
	
	Rem
	
		LockMutex (Mutex)
			Print "Main: " + a
		UnlockMutex (Mutex)
	
	End Rem
	
Next

' Other thread may still be running, so wait for it to end...

WaitThread (thread)

End

' -----------------------------------------------------------------------------
' Test function. Locks same mutex as main program, or waits until it
' can do so, calls Print, then unlocks the mutex so main program can
' lock it and proceed...
' -----------------------------------------------------------------------------

Function Test:Object (data:Object)

	For a = 1 To 100

		If Mutex Then LockMutex (Mutex)
			Print "--------> Thread: " + a
		If Mutex Then UnlockMutex (Mutex)

	Next

End Function

Hope this helps anyone else!

Hardcoal

(Posted 2013) [#7]

thanks it does

Twinprogrammer

(Posted 2013) [#8]

I realized that this only works when threaded build is on. Is there a way to change this? Because I want to give people my games just as an exe, not a .mt.exe file.

zzz	(Posted 2013) [#9]

Just remove the .mt, it has no bearing on how the file is executed. I guess its just there so you can tell the compiled binaries apart.

Twinprogrammer

(Posted 2013) [#10]

Oh... Stupid question :)