Target Selection

BlitzMax Forums/BlitzMax Programming/Target Selection

Cruis.In

(Posted 2013) [#1]

Hey guys, I am trying to use a mouse click to switch targets.

I've setup a dummy image at the mouse x/y, I've converted the position to world coordinates using the mouse x/y, since I am checking against world object x/y

The collision works fine when I click. So if my mouse pointer (which has the dummy alphad image) is over an image of another object and I click, the collision is successful.

Now based on that I'd like to be able iterate through a list of objects and return the object ID of the object clicked and of course get its x/y... I've tried for eachin loop which does return the coordinates and I am 'locked' onto those coordinates whereever the target object moves to.

But when I click a different object even if of the same type....it doesn't change to that objects position.

Method SelectTarget()
	
                'dummy image
		DrawImage(testpic, mouseoffsetx, mouseoffsety)
		
		
		'Translate the MouseX and MouseY to world Coordinates
		MouseOffsetx = (Player.x + MouseX()) - screen_width/2
		MouseOffsety = (Player.y + MouseY()) - screen_height/2
		
	for local E:Enemy = eachin list	
		If GetDistance (ship.x, ship.y, X, y) < 2000
			If MouseHit(1)
				If ImagesCollide2(testpic, MouseoffsetX, MouseOffsetY, 0, 0, viewfactor, viewfactor, E.Image, E.X, EY, 0 , E.angle, viewfactor, Viewfactor)
							
						targetx  = E.x
						targety  = E.y						 
				End If
											 
			End If
		End If

     'keep updating your chosen targetx/y no matter where it moves 				
	        TargetX = E.x
		TargetY = E.y

       next

			
		
					
	End Method

Cruis.In

(Posted 2013) [#2]

It seems that the collision stops working, once there is more than one enemy object. So if I isntance an enemy object, I can click him and get my target x/y to be his own. But if I instance another one and try clicking it, the collision isn't executing, I guess thats because I am saying for each ship in the list, if collide, and since my mouse pointer with my dummy image cannot be over all the images at the same time, it is not true and therefore no collision and therefore, won't get a new set of target coords.

Now to work around that..

Jesse

(Posted 2013) [#3]

there is a problem here:

     'keep updating your chosen targetx/y no matter where it moves 				
	        TargetX = E.x
		TargetY = E.y

because its inside the for/next loop targetx and targety will always have the last enemy coordinates.

why don't you do it like this instead:


	For Local E:Enemy = EachIn list	
		If GetDistance (ship.x, ship.y, X, y) < 2000
			If MouseHit(1)
				If ImagesCollide2(testpic, MouseoffsetX, MouseOffsetY, 0, 0, viewfactor, viewfactor, E.Image, E.X, EY, 0 , E.angle, viewfactor, Viewfactor)
						
						target = E						 
				End If
											 
			End If
		End If


       Next

where target is of type enemy

also are you using strict or super strict?
I see an error in the imagescollide2 line.

Cruis.In

(Posted 2013) [#4]

hey thanks for the reply, I am using strict, where is the error? SO i can make sure it didn't happen in my adjustment after I pasted it.

not sure how target = e gets the x/y?

Jesse

(Posted 2013) [#5]

you have:

E.X, EY,

I think it should be:

E.X, E.Y

...

not sure how target = e gets the x/y?

target in this case is a type Enemy and instead of crating a variable for targetx and targety, you just create a variable to hold the address of the type enemy:

field target:Enemy

target becomes a temporary place holder for the selected enemy. obviously target in this case will hold the actual enemy targeted. you are not creating new instances, you are just using a temporary variable to hold the selected object in the list.

[edited]

also target can be used to determine if an object was selected for targeting

if target = null no target has been selected
if target <> null target has been chosen

[edit]

another, once you find the target, there is no need to go through the for/next loop. just use exit to exit the loop.

Who was John Galt?

(Posted 2013) [#6]

Also, does the first call to mousehit not clear the hit event? May want to assign mousehit to a variable before checking it for each enemy. I may be barking up the wrong tree. Haven't run the code.

Cruis.In

(Posted 2013) [#7]

Field target:tenemyship


'Select Player Target
Method SelectTarget()

SetAlpha 1
DrawImage(testpic, mouseoffsetx, mouseoffsety)
DrawImage(testpic, targetx, targety)

'Translate the MouseX and MouseY to world Coordinates
MouseOffsetx = (ship.x + MouseX()) - screen_width/2
MouseOffsety = (ship.y + MouseY()) - screen_height/2

For Local E:tenemyship = EachIn ShipMasterlist

If GetDistance (x, y, E. X, E.y) < 2000
If MouseHit(1)
If ImagesCollide2(testpic, MouseoffsetX, MouseOffsetY, 0, 0, viewfactor, viewfactor, E.Image, E.X, E.Y, 0 , E.angle, viewfactor, Viewfactor)

target = E

End If

End If
End If


Next


End Method

Still only gets the first one. Won't switch either. I'm keeping at it, if I've implemented it wrong inform me :)

The issue is as I am tracking, the collision won't return 'true' unless I click the first enemy I 'generate'

Jesse

(Posted 2013) [#8]

John Galt made an interesting point that I overlooked.

every mouse hit is stored in a sort of a stack. Every time you make a call to mousehit an imput is removed from the stack so since you are calling it from with in the for loop(which you don't need to do) if you hit the mouse only one time, the mouse hit will be removed from the stack on the first iteration of the loop. so after the first iteration(first mouse hit call) is as if no mouse mousehit occurred.

I made some modifications, try and see if that helps. otherwise, if you don't mind sending me the code, I can help you from there. otherwise you are pretty much on your own.

	Field target:tenemyship


	'Select Player Target
	Method SelectTarget()
	
		SetAlpha 1
		
		DrawImage(testpic, mouseoffsetx, mouseoffsety)
		
		If target
			DrawImage(testpic, target.x, target.y)
		EndIf
		
		'Translate the MouseX and MouseY to world Coordinates
		MouseOffsetx = (ship.x + MouseX()) - screen_width/2
		MouseOffsety = (ship.y + MouseY()) - screen_height/2
		
		If Not Target
			If MouseHit(1)
				For Local E:tenemyship = EachIn ShipMasterlist
				
					If GetDistance (x, y, E. X, E.y) < 2000
						If ImagesCollide2(testpic, MouseoffsetX, MouseOffsetY, 0, 0, viewfactor, viewfactor, E.Image, E.X, E.Y, 0 , E.angle, viewfactor, Viewfactor)
						
							target = E
							Exit
							
						End If
					End If
				Next
			End If
		EndIf
		
		
	End Method

Zeke	(Posted 2013) [#9]

i have never liked mousehit/keyhit behavior, so i changed polledinput.bmx:


Strict

Rem
bbdoc: User input/Polled input
End Rem
Module BRL.PolledInput

ModuleInfo "Version: 1.01"
ModuleInfo "Author: Mark Sibly, Simon Armstrong"
ModuleInfo "License: zlib/libpng"
ModuleInfo "Copyright: Blitz Research Ltd"
ModuleInfo "Modserver: BRL"

ModuleInfo "History: 1.01 Release"
ModuleInfo "History: Fixed charQueue bug"

Import BRL.System
Import BRL.Graphics 'ADDED

Private

Global enabled
Global autoPoll=True
Global inputSource:Object
Global suspended,terminate

Global keyStates[256],keyHits[256]
Global charGet,charPut,charQueue[256]

Global mouseStates[4],mouseHits[4]
Global mouseLocation[4],lastMouseLocation[4]

'Added
Function ResetHITShook:Object( id:Int,data:Object,context:Object)
	MemClear(keyhits,1024) '256*4
	MemClear(mousehits,16) '4*4
End Function

Function Hook:Object( id,data:Object,context:Object )

	Local ev:TEvent=TEvent(data)
	If Not ev Return data
	
	If inputSource And inputSource<>ev.source Return data
	
	Select ev.id
	Case EVENT_KEYDOWN
		If Not keyStates[ev.data]
			keyStates[ev.data]=1
			keyHits[ev.data]:+1
		EndIf
	Case EVENT_KEYUP
		keyStates[ev.data]=0
	Case EVENT_KEYCHAR
		If charPut-charGet<256
			charQueue[charPut & 255]=ev.data
			charPut:+1
		EndIf
	Case EVENT_MOUSEDOWN
		If Not mouseStates[ev.data]
			mouseStates[ev.data]=1
			mouseHits[ev.data]:+1
		EndIf
	Case EVENT_MOUSEUP
		mouseStates[ev.data]=0
	Case EVENT_MOUSEMOVE
		mouseLocation[0]=ev.x
		mouseLocation[1]=ev.y
	Case EVENT_MOUSEWHEEL
		mouseLocation[2]:+ev.data
	Case EVENT_APPSUSPEND
		FlushKeys
		FlushMouse
		suspended=True
	Case EVENT_APPRESUME
		FlushKeys
		FlushMouse
		suspended=False
	Case EVENT_APPTERMINATE
		terminate=True
	End Select

	Return data

End Function

Public

Rem
Currently only called by Graphics/bglCreateContext.
Private for now, as it really needs a source:object parameter.
End Rem
Function EnablePolledInput( source:Object=Null )
	If enabled Return
	inputSource=source
	FlushKeys
	FlushMouse
	AddHook EmitEventHook,Hook,Null,0
	AddHook FlipHook,ResetHITShook,Null,0 'ADDED
	enabled=True
End Function

Rem
Currently only called by EndGraphics/bglDeleteContext
End Rem
Function DisablePolledInput()
	If Not enabled Return
	RemoveHook EmitEventHook,Hook
	RemoveHook FlipHook, ResetHITShook 'ADDED
	FlushKeys
	FlushMouse
	inputSource=Null
	enabled=False
End Function

Rem
bbdoc: Get app suspended state
returns: True if application is currently suspended.
End Rem
Function AppSuspended()
	If autoPoll PollSystem
	Return suspended
End Function

Rem
bbdoc: Return app terminate state
returns: True if user has requested to terminate application
End Rem
Function AppTerminate()
	If autoPoll PollSystem
	Local n=terminate
	terminate=False
	Return n
End Function

Rem
bbdoc: Check for key hit
returns: Number of times @key has been hit.
about:
The returned value represents the number of the times @key has been hit since the last
call to #KeyHit with the same @key.

See the #{key codes} module for a list of valid key codes.
End Rem
Function KeyHit( key )
	If autoPoll PollSystem
	'Local n=keyHits[key]
	'keyHits[key]=0
	'Return n
	Return keyhits[key]
End Function

Rem
bbdoc: Check for key state
returns: #True if @key is currently down
about:
See the #{key codes} module for a list of valid keycodes.
End Rem
Function KeyDown( key )
	If autoPoll PollSystem
	Return keyStates[key]
End Function

Rem
bbdoc: Get next character
returns: The character code of the next character.
about:
As the user hits keys on the keyboard, BlitzMax records the character codes of these 
keystrokes into an internal 'character queue'.

#GetChar removes the next character code from this queue and returns it the application.

If the character queue is empty, 0 is returned.
End Rem
Function GetChar()
	If autoPoll PollSystem
	If charGet=charPut Return 0
	Local n=charQueue[charGet & 255]
	charGet:+1
	Return n
End Function

Rem
bbdoc: Flush key states and character queue.
about:
#FlushKeys resets the state of all keys to 'off', and resets the character queue
used by #GetChar.
End Rem
Function FlushKeys()
	PollSystem
	charGet=0
	charPut=0
	For Local i=0 Until 256 'memclear keystates,1024 FASTER
		keyStates[i]=0
		keyHits[i]=0
	Next
End Function

Rem
bbdoc: Get mouse x location
returns: Mouse x axis location
about:
The returned value is relative to the left of the screen.
end rem
Function MouseX()
	If autoPoll PollSystem
	Return mouseLocation[0]
End Function

Rem
bbdoc: Get mouse y location
returns: Mouse y axis location
about:
The returned value is relative to the top of the screen.
end rem
Function MouseY()
	If autoPoll PollSystem
	Return mouseLocation[1]
End Function

Rem
bbdoc: Get mouse wheel
returns: Mouse wheel value
about:
The mouse wheel value increments when the mouse wheel is rolled 'away' from the user, and
decrements when the mouse wheel is rolled 'towards' the user.
end rem
Function MouseZ()
	If autoPoll PollSystem
	Return mouseLocation[2]
End Function

Rem
bbdoc: Get mouse x speed
returns: Mouse x speed
End Rem
Function MouseXSpeed()
	If autoPoll PollSystem
	Local d=mouseLocation[0]-lastMouseLocation[0]
	lastMouseLocation[0]=mouseLocation[0]
	Return d
EndFunction

Rem
bbdoc: Get mouse y speed
returns: Mouse y speed
End Rem
Function MouseYSpeed()
	If autoPoll PollSystem
	Local d=mouseLocation[1]-lastMouseLocation[1]
	lastMouseLocation[1]=mouseLocation[1]
	Return d
EndFunction

Rem
bbdoc: Get mouse z speed
returns: Mouse z speed
End Rem
Function MouseZSpeed()
	If autoPoll PollSystem
	Local d=mouseLocation[2]-lastMouseLocation[2]
	lastMouseLocation[2]=mouseLocation[2]
	Return d
EndFunction

Rem
bbdoc: Flush mouse button states
about:
#FlushMouse resets the state of all mouse buttons to 'off'.
End Rem
Function FlushMouse()
	PollSystem
	For Local i=0 Until 4
		mouseStates[i]=0
		mouseHits[i]=0
	Next
	mouseLocation[2]=0
End Function

Rem
bbdoc: Check for mouse button click
returns: Number of times @button has been clicked.
about:
The returned value represents the number of the times @button has been clicked since the
last call to #MouseHit with the same @button.

@button should be 1 for the left mouse button, 2 for the right mouse button or 3 for the
middle mouse button.
End Rem
Function MouseHit( button )
	If autoPoll PollSystem
	'Local n=mouseHits[button]
	'mouseHits[button]=0
	'Return n
	Return mousehits[button]
End Function

Rem
bbdoc: Check for mouse button down state
returns: #True if @button is currently down
about:
@button should be 1 for the left mouse button, 2 for the right mouse button or 3 for the
middle mouse button.
end rem
Function MouseDown( button )
	If autoPoll PollSystem
	Return mouseStates[button]
End Function

Rem
bbdoc: Wait for a key press
returns: The keycode of the pressed key
about:
#WaitKey suspends program execution until a key has been hit. The keycode of this
key is then returned to the application.

See the #{key codes} module for a list of valid keycodes.
End Rem
Function WaitKey()
	FlushKeys
	Repeat
		WaitSystem
		For Local n=1 To 255
			If KeyHit(n) Return n
		Next
	Forever
End Function

Rem
bbdoc: Wait for a key press
returns: The character code of the pressed key
about:
#WaitChar suspends program execution until a character is available from #GetChar. This
character is then returned to the application.
End Rem
Function WaitChar()
	FlushKeys
	Repeat
		WaitSystem
		Local n=GetChar()
		If n Return n
	Forever
End Function

Rem
bbdoc: Wait for mouse button click
returns: The clicked button
about:
#WaitMouse suspends program execution until a mouse button is clicked.

#WaitMouse returns 1 if the left mouse button was clicked, 2 if the right mouse button was
clicked or 3 if the middle mouse button was clicked.
End Rem
Function WaitMouse()
	FlushMouse
	Repeat
		WaitSystem
		For Local n=1 To 3
			If MouseHit(n) Return n
		Next
	Forever
End Function

this will not reset keyhit/mousehit states until Flip.

Derron

(Posted 2013) [#10]

@Zeke.
I think the default Behaviour is okay as long as there is no "ResetKey/Button"-Method available. I myself am using a Keywrapper/Mousewrapper lib to get the functions I want.

It is like saying: hey someone wants to check mouse button state: it will surely care about others wanting that information too. The stack-principle can befound in multiple parts of blitzmax so it is no surprise.
Better have a mouse/keywrapper running each "update" to store certain variables. Additional you can store things like "last click" "last click position" etc.
Better than suggesting core modifications for beginners.

bye
Ron

Cruis.In

(Posted 2013) [#11]

Hey guys thanks for the help, Jesse, John, Derron, Zeke as usual. You solved it quite early on up...I had a left over piece of code from testing it which was messing up the solution. After hours of trying various stuff etc, and re-trying I hope you can forgive me that it slipped past me. Funny since it was mainly just one or two things.

Either way can work target = E or targetx targety

I somehow prefer Target = E because its way cooler :)

Also I put a check for the mouse hit and a call to the function, instead of running it in the main loop and having the mouse hit in function.

Also the mousehit thing which John rose was an issue too, remember I said it wasn't returning another collision once I had selected a target? Removing the house hit from the loop squished that.

@Zeke Thanks for that, I had an issue with flushmouse recently which I went into the blitz source code for and altered and it fixed it. But your re-code to not flush until flip is good. So think I'll borrow i'll use it if you don't mind :)

	Method SelectTarget()
	
		SetAlpha 1
		
		'Translate the MouseX and MouseY to world Coordinates
		MouseOffsetx = (ship.x + MouseX() - screen_width/2) *viewfactor
		MouseOffsety = (ship.y + MouseY() - screen_height/2) *viewfactor
		
		DrawImage(testpic,  mouseoffsetx , mouseoffsety  )
		
		
			For Local E:tenemyship = EachIn ShipMasterlist
			
				If GetDistance (x, y, E. X, E.y) < 2000
					If ImagesCollide2(testpic, MouseoffsetX, MouseOffsetY, 0, 0, viewfactor, viewfactor, E.Image, E.X, E.Y, 0 , E.angle, viewfactor, Viewfactor)
					
						target = E
						Exit
						
					End If
				End If
			Next
	
		
		
		
	End Method

Since I am scaling everything based on the player position for a zooming in and out effect, I now have to adjust the formula for moving the dummy image with the mouse pointer when I scale. Although that's ringing bells in my head since the mouse pointer itself will not be affected by any scale. :)

Might have to adjust the target images to screen coords instead of the mouse pointer to world coords.

Thanks again

Cruis.In

(Posted 2013) [#12]

here is a test of the issue.

http://speedy.sh/8JfmJ/test.zip

contains three files, test.bmx, test dummy image, and two image graphics for targets. Total 33kb.

http://speedy.sh/8JfmJ/test.zip

once you 'zoom' out or in the mouseoffset x/y is no longer = to the enemy image x/y

best to just zoom out, and create one BOT. So you can see the numbers on the screen.

Press 'P' to create a bot.

thanks :)

Jesse

(Posted 2013) [#13]

you need to compensate for the scale when checking collision and placing objects on the screen.
I marked all of the changes I made hopefully you can figure it out.
I also modified the flushz part since my version( the newest version) of Blitzmax does not support flushz.

Strict

AutoMidHandle True

Global defiant:		TImage = LoadImage("defiant.png")
Global birdofprey:	TImage = LoadImage("birdofprey.png")
Global testpic:		TImage = LoadImage("test.png")



Const SCREEN_WIDTH  = 800
Const SCREEN_HEIGHT = 600

Graphics SCREEN_WIDTH , SCREEN_HEIGHT

'new player
Global Ship:tShip = New tShip

'default zoom is 1 (standard scale)
Global viewfactor:Double = 1

'Mouse offset
Global mouseoffsetx
Global mouseoffsety


'Player
Type TShip

Global list:TList = CreateList()



Field X:			Double
Field Y:			Double

Field Image:		TImage = defiant
Field Angle = 0

'for drawing enemy for scaling/zooming
Field OffsetX:	Double
Field OffsetY:	Double
Field link:		TLink

'hold Enemy here
Field Target:Tenemy

	'Construct
	Method New()
	
		link = ListAddLast(list, Self)		
		
	End Method
	
	'Draw
	Method Draw()
		SetOrigin SCREEN_WIDTH / 2 - X, SCREEN_HEIGHT / 2 - Y
		
		SetScale viewfactor, viewfactor
		DrawImage(image, x, y)
		
	End Method
	
	
Rem 
the dummy image will be alphad once working, but it is used to check a collision
and based on a collision and mouse input in the real code, it'll select the image 
clicked as its current target. It works, it is just the scaling which throws things
off, which I knew would happen but having trouble compensating for it, and wondering
if it is possible to achieve with the mouse pointer, the dummy image and scaling.
End Rem	
	
	'Selects the target which your dummy image is over, which follows the mouse 
	'pointer
	Method TargetPointer()
	
		
		'Translate the MouseX and MouseY to world Coordinates
		MouseOffsetx = ship.x + ( MouseX() -X - SCREEN_WIDTH / 2 )  
		MouseOffsety = ship.y + ( MouseY() -Y - SCREEN_HEIGHT / 2 ) 
		
		SetRotation 0 
		SetScale 1,1
		DrawText "Mouse OffsetX= "+(mouseoffsetx), ship.x  - 50, ship.y + 60
		DrawText "Mouse OffsetY= "+(mouseoffsety), ship.x  - 50, ship.y + 80

		'test images
		SetScale viewfactor, viewfactor
		DrawImage(TestPic,  MouseOffsetX , MouseOffsetY  )
		
		If Target
			DrawImage(TestPic, Target.X*viewfactor, Target.Y*viewfactor) '******************************
		End If
		
		'Select target which the 'red circle' is over
		If MouseHit(1)
			For Local E:tEnemy = EachIn Tenemy.Elist
				If ImagesCollide2(testpic, MouseoffsetX, MouseOffsetY, 0, 0,viewfactor, viewfactor, E.Image,..
								 E.X*viewfactor,..   '*************************************************
								 E.Y*viewfactor,..   '*************************************************
								 0 , E.angle, viewfactor, Viewfactor)
					target = E
					
					Exit
						
				End If				
			Next
		End If	
		
	End Method	
End Type



'Enemy
Type Tenemy Extends Tship


Global Elist:	TList = CreateList()
Field IMAGE:	TImage = BirdofPrey

	
	Method draw()		
		SetScale viewfactor, viewfactor
		SetRotation 0
		DrawImage(Image, OffsetX, OffsetY)
	End Method
	
	'constructor
	Method New()
		link = ListAddLast(ELIST, Self)		
	End Method	
	
	'random placement of enemy
	Function Create()
		If KeyHit(Key_P)
		
			Local E:Tenemy = New Tenemy
			e.x= Rand(-400, -200)
			e.y= Rand(-200, 400)

		End If 
	End Function
	
	
	
	'draw update...	
	Function DrawAll()
		For Local E:tenemy = EachIn tenemy.Elist
		
			'offset required for zooming
			e.offsetx = ship.x + ((e.x - ship.x) * viewfactor)
			e.offsety = ship.y + ((e.y - ship.y) * viewfactor)
			e.draw()
			
			
			SetScale 1,1
			DrawText "Enemy X= "+Int(E.X), ship.x -50, ship.y +140
			DrawText "Enemy Y= "+Int(E.y), ship.x -50, ship.y +160
		Next
	End Function
End Type






'Zoom function
Function Zooming() 	
	
	Global MinZ:Double = 0.3
	Global MaxZ:Double = 2.0
	Global ZoomSpeed:Double = 0.05 		
	Global TargetScale:Double = 1.0	
	Global oldmz:Double '****************************
	
	TargetScale :+ (Double(MouseZ())-oldmz) * 0.07:Double   '******************************
	TargetScale =  Min( Max(TargetScale,MinZ), MaxZ) 


	Local diff:Double = (TargetScale - viewfactor) * ZoomSpeed
	
	viewfactor :+ diff 
	oldmz = Double(MouseZ()) '**********************************
	End Function



While Not KeyHit(KEY_ESCAPE)

Cls
ResetCollisions

	

	SetRotation 0

	'Control Scale
	Zooming()
	
	'Player
	Ship.Draw()
	
	
	'Enemy
	Tenemy.Create()	
	Tenemy.DrawAll()

	'Dummy Reticule used for collision checking
	Ship.TargetPointer()

	'Draw Coords Info	
	SetScale 1,1
	If ship.target
		DrawText "Target X= "+Int(ship.target.x), ship.x - 50, ship.y + 180
		DrawText "Target Y= "+Int(ship.target.y), ship.x  - 50, ship.y + 200
	End If
		
	DrawText "RealMouseX= "+MouseX(), ship.x - 50, ship.y+ 100
	DrawText "RealMouseY= "+MouseY(), ship.x - 50, ship.y + 120
	
Flip
Wend

Cruis.In

(Posted 2013) [#14]

that is my fault sorry...I modified the source to make a flushmousez() function.

I see you don't need it anyhow.

Ah such a mistake I should really be kicking myself, I know I have to test at rotation and scalling, and hence since my application runs on the global viewfactor (everything is scaled by it), I figured that is enough for the imagescollide2 check to satisfy its need for knowing the current scale of all images.

But because of the way its done, the objects screen coordinates are drawn different than the world coordinates using the offset, and so I need to test at their screen coord and not the world coord.

Damn probably got the whole forest/trees syndrome, been going for weeks at 4-6 hours a day lol.....

Not spotting these things.....

With your pointing out of my error, the other simple change to was

Check at the actual Offset...since that has the viewfactor included in its calculation already.

If ImagesCollide2(testpic, MouseoffsetX, MouseOffsetY, 0, 0,viewfactor, viewfactor, E.Image,..
E.OffsetX,.. '*************************************************
E.OffsetY,..

If Target
DrawImage(TestPic, Target.OffsetX, Target.OffsetY) '******************************
End If

Thanks again Jesse.

Jesse

(Posted 2013) [#15]

haha! I am surprised I didn't see that. my defense is that I didn't look at it for more than 10 minutes.

I am glad you got it all together now.

Cruis.In

(Posted 2013) [#16]

You don't need to defend yourself friend....certainly not from me!

Also the example was easy to follow yes?

Jesse

(Posted 2013) [#17]

Yes.