GLSL Vertex Lighting

BlitzMax Forums/OpenGL Module/GLSL Vertex Lighting
BLaBZ
(Posted 2012) [#1]
I think I'm missing something here...

I'm trying to do some simple vertex lighting but I think there's something wrong with the normals yet I'm not sure.

shaders -
http://www.infotread.com/downloads/vertexlightingvert.txt
http://www.infotread.com/downloads/vertexlightingfrag.txt
SuperStrict

'Framework BRL.Basic
Import BRL.Timer
'Import BRL.GLGraphics
Import Pub.OpenGL
Import Pub.Glew

Const GWIDTH:Int  = 1024
Const GHEIGHT:Int = 768

InitGL()


'Local VCODE1:String = GetFileData("nonevert.txt")
'Local FCODE1:String = GetFileData("nonefrag.txt")

Local VCODE1:String = GetFileData("vertexlightingvert.txt")
Local FCODE1:String = GetFileData("vertexlightingfrag.txt")






Local Shader:TShader = New TShader.Create(VCODE1, FCODE1)


Local Timer:TTimer = CreateTimer(60), Frame:Int

Global angle:Float = 0.0

'/diffuse light color variables
Global dlr:Float = 1.0;
Global dlg:Float = 1.0;
Global dlb:Float = 1.0;

'//ambient light color variables
Global alr:Float = 0.0;
Global alg:Float = 0.0;
Global alb:Float = 0.0;

'//light position variables
Global lx:Float = 2.0;
Global ly:Float = 2.0;
Global lz:Float = -2.0;
Global lw:Float = 0.0;

Function SetLighting() 
    Local DiffuseLight:Float[] = [dlr, dlg, dlb]'; //set DiffuseLight[] To the specified values
    Local AmbientLight:Float[] = [alr, alg, alb]'; //set AmbientLight[] To the specified values

     
    glLightfv (GL_LIGHT0, GL_DIFFUSE, DiffuseLight)'; //change the light accordingly
    glLightfv (GL_LIGHT1, GL_AMBIENT, AmbientLight)'; //change the light accordingly
    
    Local LightPosition:Float[] = [lx, ly, lz, lw]'; //set the LightPosition To the specified values
    
    glLightfv (GL_LIGHT0, GL_POSITION, LightPosition)'; //change the light accordingly
End Function

Const VERTEX_INDX:Int = 0
Local vertices:Float[] = [0.5, 0.5, -0.5,  ..
						- 0.5, 0.5, -0.5,  ..
						- 0.5, -0.5, -0.5,  ..
						0.5, -0.5, -0.5,  ..
						0.5, -0.5, 0.5,  ..
						0.5, 0.5, 0.5,  ..
						- 0.5, 0.5, 0.5,  ..
						- 0.5, -0.5, 0.5]
Local indices:Int[] = [0, 1, 2, 0, 2, 3,  ..
						0, 3, 4, 0, 4, 5,  ..
						0, 5, 6, 0, 6, 1,  ..
						7, 6, 1, 7, 1, 2,  ..
						7, 4, 5, 7, 5, 6,  ..
						7, 2, 3, 7, 3, 4]
						


glEnable(GL_DEPTH_TEST)
glDepthFunc(GL_LESS)

While Not (KeyHit(KEY_ESCAPE) Or AppTerminate())

	

	glClearColor (0.0,0.0,0.0,1.0);
    glClear (GL_COLOR_BUFFER_BIT | GL_DEPTH_BUFFER_BIT);
    glLoadIdentity() 
	gluLookAt (0.0, 0.0, 5.0, 0.0, 0.0, 0.0, 0.0, 1.0, 0.0)
    
    
SetLighting()
    Shader.Enable()
		
	glEnableVertexAttribArray(VERTEX_INDX)
	glVertexAttribPointer(VERTEX_INDX, 3, GL_FLOAT, GL_FALSE, 0, vertices)

	glDrawElements(GL_TRIANGLES, indices.length, GL_UNSIGNED_INT, indices)
	Shader.Disable()
	

	
	Frame :+ 1
	
	Flip(0)
	WaitTimer(Timer)
Wend
End




Function GetFileData:String(path:String)
	Local str:String = ""
	Local stream:TStream = ReadFile(path)
	While Not Eof(stream)
		str:+ReadLine(stream)
	Wend
	CloseStream(stream)
	Return str
End Function



Function InitGL()
	GLGraphics GWIDTH, GHEIGHT
	
	glewInit()
	
	glMatrixMode(GL_PROJECTION)
	glLoadIdentity()
	glOrtho(0, GWIDTH, GHEIGHT, 0, -1, 1)
	
	glMatrixMode(GL_MODELVIEW)
	glLoadIdentity()
	
	If Not TShader.CheckCompability() Then Notify("Shader support not available", True); End
End Function

Type TShader
	Field ProgramObject:Int
	
	Method Load:TShader(VertexPath:String, FragmentPath:String)
		Local VertexCode:String, FragmentCode:String
		
		Try
			VertexCode   = LoadText(VertexPath)
			FragmentCode = LoadText(FragmentPath)
		Catch Dummy:Object
			Return Null
		EndTry
		
		Create(VertexCode, FragmentCode)
		
		Return Self
	End Method
	
	Method Create:TShader(VertexCode:String, FragmentCode:String)
		If Not ProgramObject Then ProgramObject = glCreateProgram()
		
		Local VertexShader  :Int = glCreateShader(GL_VERTEX_SHADER)
		Local FragmentShader:Int = glCreateShader(GL_FRAGMENT_SHADER)
		
		Local ErrorMessage:String
		
		_LoadShader(VertexCode, VertexShader)
		glCompileShader(VertexShader)
		
		If _CheckForErrors(VertexShader, ErrorMessage) Then
			glDeleteShader(VertexShader)
			
			Throw ErrorMessage
		EndIf
		
		_LoadShader(FragmentCode, FragmentShader)
		glCompileShader(FragmentShader)
		
		If _CheckForErrors(FragmentShader, ErrorMessage) Then
			glDeleteShader(VertexShader)
			glDeleteShader(FragmentShader)
			
			Throw ErrorMessage
		EndIf
		
		glAttachShader(ProgramObject, VertexShader)
		glAttachShader(ProgramObject, FragmentShader)
		
		glBindAttribLocation(ProgramObject, 0, "vPosition") ;
		
	
		
		glDeleteShader(VertexShader)
		glDeleteShader(FragmentShader)
		
		glLinkProgram(ProgramObject)
		If _CheckForErrors(ProgramObject, ErrorMessage, False) Then Throw ErrorMessage
		
		
'		glValidateProgram(ProgramObject)
		
		Return Self
	End Method
	
	Method Enable()
		glUseProgram(ProgramObject)
	End Method
	
	Method Disable()
		glUseProgram(0)
	End Method
	
	Method GetUniformLocation:Int(Name:String)
		Return glGetUniformLocation(ProgramObject, Name)
	End Method
	
	Method Delete()
		glDeleteObjectARB(ProgramObject)
	End Method
	
	Function _LoadShader(ShaderCode:String, ShaderObject:Int)
		Local ShaderCodeC:Byte Ptr = ShaderCode.ToCString()
		Local ShaderCodeLen:Int    = ShaderCode.Length
		
		glShaderSource(ShaderObject, 1, Varptr ShaderCodeC, Varptr ShaderCodeLen)
		
		MemFree(ShaderCodeC)
	End Function
	
	Function _CheckForErrors:Int(ShaderObject:Int, ErrorString:String Var, Compiled:Int = True)
		Local Successful:Int
		
		If Compiled Then
			glGetShaderiv(ShaderObject, GL_COMPILE_STATUS, Varptr Successful)
		Else
			glGetProgramiv(ShaderObject, GL_LINK_STATUS,    Varptr Successful)
		EndIf
		
		If Not Successful Then
			Local ErrorLength:Int
			'glGetObjectParameterivARB(ShaderObject, GL_OBJECT_INFO_LOG_LENGTH_ARB, Varptr ErrorLength)
			glGetShaderiv(ShaderObject,GL_INFO_LOG_LENGTH,Varptr ErrorLength)
			Local Message:Byte Ptr = MemAlloc(ErrorLength), Dummy:Int
			
			glGetInfoLogARB(ShaderObject, ErrorLength, Varptr Dummy, Message)
			
			ErrorString = String.FromCString(Message)
			MemFree(Message)
			
			Return -1
		EndIf
		
		Return 0
	End Function
	
	Function CheckCompability:Int()
		Local Extensions:String = String.FromCString(Byte Ptr glGetString(GL_EXTENSIONS))
		Local GLVersion:String  = String.FromCString(Byte Ptr glGetString(GL_VERSION))
		Local GLVersionInt:Int  = GLVersion[.. 3].Replace(".", "").ToInt()
		
		If Extensions.Find("GL_ARB_shader_objects" ) >= 0 And ..
		   Extensions.Find("GL_ARB_vertex_shader"  ) >= 0 And ..
		   Extensions.Find("GL_ARB_fragment_shader") >= 0 Or GLVersionInt >= 20 Then Return True
		
		Return False
	End Function
End Type
AdamRedwoods
(Posted 2012) [#2]
in the vertex shader, you need a vector from the light to the point, not just the light position.