GLSL framework for BlitzMax

BlitzMax Forums/OpenGL Module/GLSL framework for BlitzMax

taumel

(Posted 2011) [#1]

I have to do some image heavy stuff and after trying it out in BlitzMax directly (single as well as threaded) i got frustrated by the speed results, so the only option was to use the GPU.

Now after i got it running i was wondering if there also exists some lightweight framework for GLSL usage in BlitzMax.

I know that there exists glsl.bmx. As the copyright is unknown, can you use this without any problems and does there exist some more information/docs about it beside of comment fields in the code?

xlsior

(Posted 2011) [#2]

duct.mod/protog2d.mod has a bunch of shader routines for Blitzmax:

https://github.com/komiga/duct-max

Noobody

(Posted 2011) [#3]

Here's a TShader class I always use in GLSL experiments, with a small GLSL Mandelbrot example:

SuperStrict

Framework BRL.Basic
Import BRL.Timer
Import BRL.GLGraphics
Import Pub.OpenGL
Import Pub.Glew

Const GWIDTH:Int  = 1024
Const GHEIGHT:Int = 768

InitGL()

Local Shader:TShader = New TShader.Create(VERTEX_CODE, FRAGMENT_CODE)

Local Timer:TTimer = CreateTimer(60), Frame:Int

While Not (KeyHit(KEY_ESCAPE) Or AppTerminate())
	glClear(GL_COLOR_BUFFER_BIT)
	
	Local T:Float = Sin(Frame)
	Local RealMin:Float      = Blend(-4, -1,    T)
	Local RealMax:Float      = Blend( 4, -0,    T)
	Local ImaginaryMin:Float = Blend(-3, -1,    T)
	Local ImaginaryMax:Float = Blend( 3, -0.25, T)
	
	Shader.Enable()
	glBegin(GL_QUADS)
		glTexCoord2f(RealMin, ImaginaryMin); glVertex2f(0,      0      )
		glTexCoord2f(RealMax, ImaginaryMin); glVertex2f(GWIDTH, 0      )
		glTexCoord2f(RealMax, ImaginaryMax); glVertex2f(GWIDTH, GHEIGHT)
		glTexCoord2f(RealMin, ImaginaryMax); glVertex2f(0,      GHEIGHT)
	glEnd()
	Shader.Disable()
	
	Frame :+ 1
	
	Flip(0)
	WaitTimer(Timer)
Wend
End

Const VERTEX_CODE:String = .. 'Of course you shouldn't put these in code normally. This is just for the sake of not having to use external files for this example
	"void main( void ) {~n" + ..
		"gl_Position = gl_ModelViewProjectionMatrix*gl_Vertex;~n" + ..
		"gl_TexCoord[0]  = gl_MultiTexCoord0;~n" + ..
	"}"

Const FRAGMENT_CODE:String = ..
	"~n" + ..
	"void main(void) {~n" + ..
		"vec4 C = gl_TexCoord[0];~n" + ..
		"vec4 Z = C;~n" + ..
		"vec2 CSq;~n" + ..
		"~n" + ..
		"int Iteration = 0;~n" + ..
		"CSq.x = C.x*C.x;~n" + ..
		"CSq.y = C.y*C.y;~n" + ..
		"float OrbitTrap = 1000.0;~n" + ..
		"while(Iteration++ < 32 && CSq.x + CSq.y < 8.0) {~n" + ..
			"Z.w = CSq.x - CSq.y + C.x;~n" + ..
			"Z.y = 2.0*Z.x*Z.y + C.y;~n" + ..
			"Z.x = Z.w;~n" + ..
			"OrbitTrap = min(OrbitTrap, min(abs(Z.x), abs(Z.y)));~n" + ..
			"CSq.x = Z.x*Z.x;~n" + ..
			"CSq.y = Z.y*Z.y;~n" + ..
		"}~n" + ..
		"~n" + ..
		"float Ratio = OrbitTrap*7.0;~n" + .. '"float(Iteration)/128.0*7.0;~n" + ..
		"float Rise = mod(Ratio, 1.0);~n" + ..
		"float Fall = 1.0 - Rise;~n" + ..
		"Ratio = floor(Ratio);~n" + ..
		"~n" + ..
		"     if(Ratio == 0.0) gl_FragColor = vec4(Rise, 0.0, 0.0, 1.0);~n" + ..
		"else if(Ratio == 1.0) gl_FragColor = vec4(1.0, Rise, 0.0, 1.0);~n" + ..
		"else if(Ratio == 2.0) gl_FragColor = vec4(Fall, 1.0, 0.0, 1.0);~n" + ..
		"else if(Ratio == 3.0) gl_FragColor = vec4(0.0, 1.0, Rise, 1.0);~n" + ..
		"else if(Ratio == 4.0) gl_FragColor = vec4(0.0, Fall, 1.0, 1.0);~n" + ..
		"else if(Ratio == 5.0) gl_FragColor = vec4(Rise, 0.0, 1.0, 1.0);~n" + ..
		"else if(Ratio == 6.0) gl_FragColor = vec4(1.0, Rise, 1.0, 1.0);~n" + ..
	"}"
	
Function Blend:Float(A:Float, B:Float, T:Float)
	Return A*(1 - T) + B*T
End Function

Function InitGL()
	GLGraphics GWIDTH, GHEIGHT
	
	glewInit()
	
	glMatrixMode(GL_PROJECTION)
	glLoadIdentity()
	glOrtho(0, GWIDTH, GHEIGHT, 0, -1, 1)
	
	glMatrixMode(GL_MODELVIEW)
	glLoadIdentity()
	
	If Not TShader.CheckCompability() Then Notify("Shader support not available", True); End
End Function

Type TShader
	Field ProgramObject:Int
	
	Method Load:TShader(VertexPath:String, FragmentPath:String)
		Local VertexCode:String, FragmentCode:String
		
		Try
			VertexCode   = LoadText(VertexPath)
			FragmentCode = LoadText(FragmentPath)
		Catch Dummy:Object
			Return Null
		EndTry
		
		Create(VertexCode, FragmentCode)
		
		Return Self
	End Method
	
	Method Create:TShader(VertexCode:String, FragmentCode:String)
		If Not ProgramObject Then ProgramObject = glCreateProgramObjectARB()
		
		Local VertexShader  :Int = glCreateShaderObjectARB(GL_VERTEX_SHADER_ARB)
		Local FragmentShader:Int = glCreateShaderObjectARB(GL_FRAGMENT_SHADER_ARB)
		
		Local ErrorMessage:String
		
		_LoadShader(VertexCode, VertexShader)
		glCompileShaderARB(VertexShader)
		
		If _CheckForErrors(VertexShader, ErrorMessage) Then
			glDeleteObjectARB(VertexShader)
			
			Throw ErrorMessage
		EndIf
		
		_LoadShader(FragmentCode, FragmentShader)
		glCompileShaderARB(FragmentShader)
		
		If _CheckForErrors(FragmentShader, ErrorMessage) Then
			glDeleteObjectARB(VertexShader)
			glDeleteObjectARB(FragmentShader)
			
			Throw ErrorMessage
		EndIf
		
		glAttachObjectARB(ProgramObject, VertexShader)
		glAttachObjectARB(ProgramObject, FragmentShader)
		
		glDeleteObjectARB(VertexShader)
		glDeleteObjectARB(FragmentShader)
		
		glLinkProgramARB(ProgramObject)
		If _CheckForErrors(ProgramObject, ErrorMessage, False) Then Throw ErrorMessage
		
		Return Self
	End Method
	
	Method Enable()
		glUseProgramObjectARB(ProgramObject)
	End Method
	
	Method Disable()
		glUseProgramObjectARB(0)
	End Method
	
	Method GetUniformLocation:Int(Name:String)
		Return glGetUniformLocationARB(ProgramObject, Name)
	End Method
	
	Method Delete()
		glDeleteObjectARB(ProgramObject)
	End Method
	
	Function _LoadShader(ShaderCode:String, ShaderObject:Int)
		Local ShaderCodeC:Byte Ptr = ShaderCode.ToCString()
		Local ShaderCodeLen:Int    = ShaderCode.Length
		
		glShaderSourceARB(ShaderObject, 1, Varptr ShaderCodeC, Varptr ShaderCodeLen)
		
		MemFree(ShaderCodeC)
	End Function
	
	Function _CheckForErrors:Int(ShaderObject:Int, ErrorString:String Var, Compiled:Int = True)
		Local Successful:Int
		
		If Compiled Then
			glGetShaderiv (ShaderObject, GL_COMPILE_STATUS, Varptr Successful)
		Else
			glGetProgramiv(ShaderObject, GL_LINK_STATUS,    Varptr Successful)
		EndIf
		
		If Not Successful Then
			Local ErrorLength:Int
			glGetObjectParameterivARB(ShaderObject, GL_OBJECT_INFO_LOG_LENGTH_ARB, Varptr ErrorLength)
			
			Local Message:Byte Ptr = MemAlloc(ErrorLength), Dummy:Int
			
			glGetInfoLogARB(ShaderObject, ErrorLength, Varptr Dummy, Message)
			
			ErrorString = String.FromCString(Message)
			MemFree(Message)
			
			Return -1
		EndIf
		
		Return 0
	End Function
	
	Function CheckCompability:Int()
		Local Extensions:String = String.FromCString(Byte Ptr glGetString(GL_EXTENSIONS))
		Local GLVersion:String  = String.FromCString(Byte Ptr glGetString(GL_VERSION))
		Local GLVersionInt:Int  = GLVersion[.. 3].Replace(".", "").ToInt()
		
		If Extensions.Find("GL_ARB_shader_objects" ) >= 0 And ..
		   Extensions.Find("GL_ARB_vertex_shader"  ) >= 0 And ..
		   Extensions.Find("GL_ARB_fragment_shader") >= 0 Or GLVersionInt >= 20 Then Return True
		
		Return False
	End Function
End Type

It supports the basic operations, such as loading from strings or files, compiler/linker error handling, compatibility checks and enabling/disabling the shader.

ImaginaryHuman

(Posted 2011) [#4]

Cool, thanks for sharing. this'll come in handy.

taumel

(Posted 2011) [#5]

Thanks @xlsior and @Noobody as well.

I also tested my Julia code i did once and it's just a shame how slow it is compared to the GPU version, same with a less intensive copper plasma, it all was about 20x faster than the CPU threaded versions.

Actually it would be interesting using the GPU shaders for visualising and calculating a 2D game. With a proper GPU this should enable a new interesting gameplay.

@Noobody
I just tried your example, got some freaky mandbrot set, and after some zooming it boomed my machine.

Last edited 2011

ImaginaryHuman

(Posted 2011) [#6]

It works fine for me. The coloring isn't what I typically see for mandelbrodts but kinda funky. Works pretty fast for me, mostly 60fpsish. And your framework is pretty handy for setting up the shaders.

Last edited 2011

Noobody

(Posted 2011) [#7]

I just tried your example, got some freaky mandbrot set, and after some zooming it boomed my machine.

If you have an old graphics card, it is possible that it isn't fast enough to execute the inner loop inside the shader for real-time rendering. Depending on your drivers, this can have different outcomes - either your driver resets or the machine freezes (operating systems really don't like it if one application hogs the graphics card). I'm interested in your machine though, since even my shitty 3 year old laptop with Intel GMA is able to render it at 30-60fps :)

So basically, it's more of a problem with the shader, not the framework.

The coloring isn't what I typically see for mandelbrodts but kinda funky.

Regular mandelbrot coloring is a bit boring, so I added in a few simple orbit traps to mix it up a little. If you're interested, I talked a bit about them in this blog post. The color gradients are admittedly not very pretty, it was just something I still had lying around.

taumel

(Posted 2011) [#8]

MacBookPro 2.53GHz, 4GB RAM, GT330M, OSX 10.6.8.

I had no crashes so far with the things i did, also tesuje's shaderexamples work fine here. The only other thing which freezes a part of my machine is returning from fullscreen to windowed mode with Unity's webplayer whilst certain new image effects are enabled.