Opengl & Pointers

BlitzMax Forums/OpenGL Module/Opengl & Pointers

Jayjay

(Posted 2011) [#1]

Hi and thanks in advance

I want to use picking in opengl and am happy to use the colour picking method abd I have a function as follows:

Function ColourPick(Mx, My)
	Local viewport:Int[4]
	Local pixel:Byte[3]
	
	Local viewport_ptr:Int Ptr = Varptr viewport[0]
	Local Pixel_ptr:Byte Ptr = Varptr Pixel[0]


	glGetIntegerv GL_VIEWPORT, viewport_ptr
	
	glReadPixels Mx, My, 600, 500, GL_RGB, GL_UNSIGNED_BYTE, Pixel_ptr


	If pixel[0] = 255
		Print "You clicked the line"
	Else
		Print "nothing Clicked"
	End If

End Function

However this crashes! I think it is due to the use of pointers but am not sure. Am I using pointers correctly here??

JoshK

(Posted 2011) [#2]

http://www.opengl.org/sdk/docs/man/xhtml/glPixelStore.xml

I always set GL_PACK_ROW_LENGTH and GL_UNPACK_ROW_LENGTH any time I get or set pixels in OpenGL, just to be safe. If you don't call whichever is needed before a read/set call you will cause random errors that are extremely hard to track down, so I just always call them both in case I make a mistake.

You can also just do this:
glReadPixels Mx, My, 600, 500, GL_RGB, GL_UNSIGNED_BYTE, pixel

Last edited 2011

Samichan

(Posted 2011) [#3]

SuperStrict

SetGraphicsDriver GLMax2DDriver()
Graphics 1024, 768

Local myimg:TImage = LoadImage(LoadBank("http::home.tiscali.nl/t876506/cdt.jpg"))

While Not (KeyDown(KEY_ESCAPE) Or AppTerminate())
	Cls
	
	SetColor 255, 255, 255
	
	If myimg
		DrawImage myimg, 0, 0
	Else
		DrawText "Can't find myimg!", 20, 20
	End If
	
	Local rr:Byte
	Local gg:Byte
	Local bb:Byte
	mygl_GetPixelColorAt(MouseX(), MouseY(), rr, gg, bb)
	
	DrawRect GraphicsWidth() - 140, 20, 100, 100
	SetColor rr, gg, bb
	DrawRect GraphicsWidth() - 130, 30, 80, 80
	
	Flip 1
Wend

Function mygl_GetPixelColorAt:Int(X:Int, Y:Int, R:Byte var, G:Byte var, B:Byte var)
	Local pixbytes:Byte[3]
	glReadPixels(X, GraphicsHeight() - Y, 1, 1, GL_RGB, GL_UNSIGNED_BYTE, pixbytes)
	R = pixbytes[0]
	G = pixbytes[1]
	B = pixbytes[2]
End Function

glReadPixels Mx, My, 600, 500, GL_RGB, GL_UNSIGNED_BYTE, Pixel_ptr
vs
glReadPixels(X, GraphicsHeight() - Y, 1, 1, GL_RGB, GL_UNSIGNED_BYTE, pixbytes)

You want to flip your y-coordinate because OpenGL handles buffers "upside down".
If you want to pick only a single pixel then surely the area should be 1x1.
Apparently we don't need a separate pointer for this.