What's wrong with this?

BlitzMax Forums/OpenGL Module/What's wrong with this?

Brucey

(Posted 2015) [#1]

Hallo :-)

I'm trying to apply an orthographic matrix to a shader, but it's not drawing anything. Can anyone see what I'm doing wrong?

Platform is iOS, OpenGL ES 2

Here's the original without the matrix :

SuperStrict

Framework sdl.sdlgraphics
Import Pub.OpenGLES
Import brl.standardio

Global screen_width:Int = DesktopWidth()
Global screen_height:Int = DesktopHeight()

If screen_width < screen_height Then
	Local tmp:Int = screen_height
	screen_height = screen_width
	screen_width = tmp
End If
 
Graphics screen_width, screen_height, 32


Local r:TRenderer = New TRenderer
r.run()


End



Type TRenderer

	Const VERTEX_SHADER_CODE:String = ..
		"attribute vec4 Position;~n" + ..
		"attribute vec4 SourceColor;~n" + ..
		"~n" + ..
		"varying vec4 DestinationColor;~n" + ..
		"~n" + ..
		"void main(void) {~n" + ..
		"  DestinationColor = SourceColor;~n" + ..
		"  gl_Position = Position;~n" + ..
		"}~n"

	Const FRAGMENT_SHADER_CODE:String = ..
		"varying lowp vec4 DestinationColor;~n" + ..
		"~n" + ..
		"void main(void) {~n" + ..
		"    gl_FragColor = DestinationColor;~n" + ..
		"}~n"


	Field _positionSlot:Int
	Field _colorSlot:Int
	Field _projectionMatrix:Int

	Field vertices:Float[]
	
	Field vertexBuffer:Int
	Field indexBuffer:Int
	
	Field indices:Byte[]
	
	Method createGeometry()
		
		vertices = [ 1.0, -1.0, 0.0,   1.0, 1.0, 0.0, 1.0, ..
					 1.0,  1.0, 0.0,   0.0, 1.0, 0.0, 1.0, ..
					-1.0,  1.0, 0.0,   0.0, 0.0, 1.0, 1.0, ..
					-1.0, -1.0, 0.0,   0.0, 0.0, 0.0, 1.0]

		glGenBuffers(1, Varptr vertexBuffer)
		glBindBuffer(GL_ARRAY_BUFFER, vertexBuffer)
		glBufferData(GL_ARRAY_BUFFER, 28 * 4, vertices, GL_STATIC_DRAW)

		indices = [0:Byte, 1:Byte, 2:Byte, 2:Byte, 3:Byte, 0:Byte]
		
		glGenBuffers(1, Varptr indexBuffer)
		glBindBuffer(GL_ELEMENT_ARRAY_BUFFER, indexBuffer)
		glBufferData(GL_ELEMENT_ARRAY_BUFFER, 6, indices, GL_STATIC_DRAW)
		
	End Method
	
	Method compileShader:Int(shaderType:Int, code:String)
		Local handle:Int = glCreateShader(shaderType)
		
		Local length:String = code.length
		Local s:Byte Ptr = code.ToCString()
		glShaderSource(handle, 1, Varptr s, Null)
		MemFree(s)
		
		glCompileShader(handle)
		
		Local compileSuccess:Int
		glGetShaderiv(handle, GL_COMPILE_STATUS, Varptr compileSuccess)
		If Not compileSuccess Then
			Print "Shader compilation error: " + GetErrorLog(handle)
			End
		End If
		
		Return handle
		
	End Method
	
	Method loadShaders()
		Local vertex:Int = compileShader(GL_VERTEX_SHADER, VERTEX_SHADER_CODE)
		Local fragment:Int = compileShader(GL_FRAGMENT_SHADER, FRAGMENT_SHADER_CODE)

		If Not glIsShader( vertex )  Then 
			Print "ERROR vertex is not a valid shader!"
			End
		EndIf

		If Not glIsShader( fragment )  Then
			Print "ERROR : fragment is not a valid shader!"
			End
		EndIf
		
		Local program:Int = glCreateProgram()
		glAttachShader(program, vertex)
		glAttachShader(program, fragment)
		glLinkProgram(program)
		
		glUseProgram(program)
		
		_positionSlot = glGetAttribLocation(program, "Position")
		_colorSlot = glGetAttribLocation(program, "SourceColor")
		glEnableVertexAttribArray(_positionSlot)
		glEnableVertexAttribArray(_colorSlot)
		
	End Method
	
	Method run()
	
		createGeometry()
		loadShaders()
	
		While Not AppTerminate
		
			glClearColor(0.1, 0.2, 0.1, 1.0)
			glClear(GL_COLOR_BUFFER_BIT)' | GL_DEPTH_BUFFER_BIT)
			
			' Set up the viewport
			glViewport(0, 0, screen_width, screen_height)
			
			' Tell OpenGL about the structure of our data
			glVertexAttribPointer(_positionSlot, 3, GL_FLOAT, GL_FALSE, 7 * 4, 0);
			glVertexAttribPointer(_colorSlot, 4, GL_FLOAT, GL_FALSE, 7 * 4, 12);

			' Draw it!
			glDrawElements(GL_TRIANGLES, 6, GL_UNSIGNED_BYTE, 0)
			
			Flip
		Wend
	
	End Method

	Method GetErrorLog:String( pid:Int )

		Local logsize:Int = 0
		glGetShaderiv( pid, GL_INFO_LOG_LENGTH, Varptr logsize )

		Local msg:Byte[logsize]
		Local size:Int = 0

		glGetShaderInfoLog( pid, logsize, Varptr size, Varptr msg[0] )

		Local str:String = ""
		For Local i:Int = 0 To MSG.length - 1
			str :+ Chr( msg[i] )
		Next

		Return str

	End Method

End Type

This renders a full-screen coloured box.

And here's the modified version that doesn't seem to draw anything.

SuperStrict

Framework sdl.sdlgraphics
Import Pub.OpenGLES
Import brl.standardio

Global screen_width:Int = DesktopWidth()
Global screen_height:Int = DesktopHeight()

If screen_width < screen_height Then
	Local tmp:Int = screen_height
	screen_height = screen_width
	screen_width = tmp
End If
 
Graphics screen_width, screen_height, 32


Local r:TRenderer = New TRenderer
r.run()


End



Type TRenderer

	Const VERTEX_SHADER_CODE:String = ..
		"attribute vec4 Position;~n" + ..
		"attribute vec4 SourceColor;~n" + ..
		"~n" + ..
		"varying vec4 DestinationColor;~n" + ..
		"uniform mat4 u_pmatrix;~n" + ..
		"~n" + ..
		"void main(void) {~n" + ..
		"  DestinationColor = SourceColor;~n" + ..
		"  gl_Position = u_pmatrix * Position;~n" + ..
		'"  gl_Position = Position;~n" + ..
		"}~n"

	Const FRAGMENT_SHADER_CODE:String = ..
		"varying lowp vec4 DestinationColor;~n" + ..
		"~n" + ..
		"void main(void) {~n" + ..
		"    gl_FragColor = DestinationColor;~n" + ..
		"}~n"


	Field _positionSlot:Int
	Field _colorSlot:Int
	Field _projectionMatrix:Int

	Field vertices:Float[]
	
	Field vertexBuffer:Int
	Field indexBuffer:Int
	
	Field indices:Byte[]
	
	Field u_pmatrix:TMatrix

	Method createGeometry()
		
		vertices = [0.0, 0.0, 0.0, 1.0, 1.0, 0.0, 1.0, ..
				Float(screen_width), 0.0, 0.0, 0.0, 1.0, 0.0, 1.0, ..
				Float(screen_width), Float(screen_height), 0.0, 0.0, 0.0, 1.0, 1.0, ..
				0.0, Float(screen_height), 0.0, 0.0, 0.0, 0.0, 1.0]

		glGenBuffers(1, Varptr vertexBuffer)
		glBindBuffer(GL_ARRAY_BUFFER, vertexBuffer)
		glBufferData(GL_ARRAY_BUFFER, 28 * 4, vertices, GL_STATIC_DRAW)

		indices = [0:Byte, 1:Byte, 2:Byte, 2:Byte, 3:Byte, 0:Byte]
		
		glGenBuffers(1, Varptr indexBuffer)
		glBindBuffer(GL_ELEMENT_ARRAY_BUFFER, indexBuffer)
		glBufferData(GL_ELEMENT_ARRAY_BUFFER, 6, indices, GL_STATIC_DRAW)
		
		u_pmatrix = New TMatrix
		u_pmatrix.SetOrthographic( 0, screen_width, 0, screen_height, -1, 1 )
	End Method
	
	Method compileShader:Int(shaderType:Int, code:String)
		Local handle:Int = glCreateShader(shaderType)
		
		Local length:String = code.length
		Local s:Byte Ptr = code.ToCString()
		glShaderSource(handle, 1, Varptr s, Null)
		MemFree(s)
		
		glCompileShader(handle)
		
		Local compileSuccess:Int
		glGetShaderiv(handle, GL_COMPILE_STATUS, Varptr compileSuccess)
		If Not compileSuccess Then
			Print "Shader compilation error: " + GetErrorLog(handle)
			End
		End If
		
		Return handle
		
	End Method
	
	Method loadShaders()
		Local vertex:Int = compileShader(GL_VERTEX_SHADER, VERTEX_SHADER_CODE)
		Local fragment:Int = compileShader(GL_FRAGMENT_SHADER, FRAGMENT_SHADER_CODE)

		If Not glIsShader( vertex )  Then 
			Print "ERROR vertex is not a valid shader!"
			End
		EndIf

		If Not glIsShader( fragment )  Then
			Print "ERROR : fragment is not a valid shader!"
			End
		EndIf
		
		Local program:Int = glCreateProgram()
		glAttachShader(program, vertex)
		glAttachShader(program, fragment)
		glLinkProgram(program)
		
		glUseProgram(program)
		
		_positionSlot = glGetAttribLocation(program, "Position")
		_colorSlot = glGetAttribLocation(program, "SourceColor")
		glEnableVertexAttribArray(_positionSlot)
		glEnableVertexAttribArray(_colorSlot)
		
		_projectionMatrix = glGetUniformLocation(program, "u_pmatrix")
		glUniformMatrix4fv(_projectionMatrix, 1, False, u_pmatrix.grid )
	End Method
	
	Method run()
	
		createGeometry()
		loadShaders()
	
		While Not AppTerminate
		
			glClearColor(0.1, 0.2, 0.1, 1.0)
			glClear(GL_COLOR_BUFFER_BIT)' | GL_DEPTH_BUFFER_BIT)
			
			' Set up the viewport
			' Not required? 'glViewport(0, 0, screen_width, screen_height)
			
			' Tell OpenGL about the structure of our data
			glVertexAttribPointer(_positionSlot, 3, GL_FLOAT, GL_FALSE, 7 * 4, 0);
			glVertexAttribPointer(_colorSlot, 4, GL_FLOAT, GL_FALSE, 7 * 4, 12);

			' Draw it!
			glDrawElements(GL_TRIANGLES, 6, GL_UNSIGNED_BYTE, 0)
			
			Flip
		Wend
	
	End Method

	Method GetErrorLog:String( pid:Int )

		Local logsize:Int = 0
		glGetShaderiv( pid, GL_INFO_LOG_LENGTH, Varptr logsize )

		Local msg:Byte[logsize]
		Local size:Int = 0

		glGetShaderInfoLog( pid, logsize, Varptr size, Varptr msg[0] )

		Local str:String = ""
		For Local i:Int = 0 To MSG.length - 1
			str :+ Chr( msg[i] )
		Next

		Return str

	End Method

End Type

Type TMatrix

	Field grid:Float Ptr = Float Ptr( MemAlloc( 4 * 16 ) )
	
	Method SetOrthographic( pl:Float, pr:Float, pt:Float, pb:Float, pn:Float, pf:Float )

		LoadIdentity()
		grid[00] =  2.0 / ( pr - pl )
		grid[05] =  2.0 / ( pt - pb )
		grid[10] = -2.0 / ( pf - pn )
		grid[15] =  1.0
		grid[12] = -( ( pr + pl ) / ( pr - pl ) )
		grid[13] = -( ( pt + pb ) / ( pt - pb ) )
		grid[14] = -( ( pf + pn ) / ( pf - pn ) )

	End Method
	
	Method Clear()

		For Local i:Int = 0 Until 16
			grid[i] = 0.0
		Next

	End Method
	
	Method LoadIdentity()

		Clear()
		grid[00] = 1.0
		grid[05] = 1.0
		grid[10] = 1.0
		grid[15] = 1.0

	End Method

	Method dump()
		Local s:String
		For Local i:Int = 0 Until 16
			s :+ grid[i] + " "
		Next
		Print s
	End Method
End Type

Similar code does work on the Pi and Android, so I'm not sure if there's anything specific to iOS that I'm doing wrong?

Thanks in advance for any help.

Floyd

(Posted 2015) [#2]

Wild guess, perhaps the roles of -Z and +Z got swapped somewhere. That seems like something that could easily happen in multi-platform development.

You might try swapping them again in the matrix and seeing if it helps.

		u_pmatrix.SetOrthographic( 0, screen_width, 0, screen_height, +1, -1 )

Brucey

(Posted 2015) [#3]

Interestingly, if I use an identity matrix on the second example, and set the viewport, and use the original vertex data, it renders correctly - as you would expect - which I think proves the code for applying the matrix itself is okay.

Which leaves 2 things as far as I can tell :
1) the ortho math is wrong
2) something to do the viewport is wrong? I am not calling glViewport() in the second version because I thought that's what the ortho is for?

Floyd

(Posted 2015) [#4]

I would imagine you need a viewport in any case.

Perspective projection is like real life. As things get farther away they look smaller.

Orthographic project is done with parallel lines and there is no perspective. Identical objects will look the same at all distances. You can also think of it as the limiting case of standing very far away and looking through a powerful telescope. Suppose you look at two things at distances 1 and 2. The far one looks half as big. Now move back so distances are 1001 and 1002, but look through a 1000x zoom lens. The objects look as if the distances were 1.001 and 1.002 so they look practically identical. Orthographic projection is the limiting case as distance goes to infinity, but zoom cancels it out.

In any case the projected result must get put on the screen. I think you still need a viewport for that.

LT	(Posted 2015) [#5]

The orthographic matrix and the viewport are two different things, I think. It's just that computing the matrix happens to need similar values. I believe that glViewport does some kind of additional transformation from device to window coords.

Brucey

(Posted 2015) [#6]

Thanks for the help guys :-)

I appear to have got my head around it now...

DStastny

(Posted 2015) [#7]

Nice

markcw

(Posted 2015) [#8]

markcw

(Posted 2015) [#9]

Sorry for the silly post, I had a bit much to drink. I guess I was trying to say brilliant work.