Save mesh

BlitzMax Forums/MiniB3D Module/Save mesh

Hezkore

(Posted 2011) [#1]

Does anyone have any code for saving meshes loaded in MiniB3d? :o
I'd like to load a bunch of meshes, merge them into one mesh and finally save that one mesh as a single B3D file. (or some other format)
It's important that the textures are there though...

Last edited 2011

Warner

(Posted 2011) [#2]

You could try this archive entry:
http://www.blitzbasic.com/codearcs/codearcs.php?code=866
It can be autoconverted by using File->Import bb file.
Then it needs a few tweaks to get it running:

Import sidesign.minib3d

Global b3d_stack[100+1]
Global b3d_file,b3d_tos



' ID: 866
' Author: jfk EO-11110
' Date: 2003-12-24 01:23:50
' Title: SaveB3D
' Description: Save multisurface textured Mesh as .B3D

Graphics3D 640,480,32,2

meshname$="testsurf.b3d" ' Mesh To save... (one that is using textures)

' BTW: you should run this from inside the folder where the Mesh resides, unless you edit the
' Part labeled by "<<<<<<<<<<<<"

Include "b3dfile.bmx"
' this file can be found here: <a href="http://www.blitzbasic.com/sdkspecs/sdkspecs/b3dfile_utils.zip" target="_blank">http://www.blitzbasic.com/sdkspecs/sdkspecs/b3dfile_utils.zip</a>
cam=CreateCamera()
TranslateEntity cam,0,0,-10
If  FileType(meshname$) <> 1 Then
	RuntimeError "File not found: " + meshname$
End If

mesh=LoadMesh(meshname$)
Global c_surfs=CountSurfaces(mesh)

Print "Mesh "+meshname$+" has "+ c_surfs+" Surfaces, using the following textures:"

Global c_surf[c_surfs+1]
Global c_brush[c_surfs+1]
Global c_tex[c_surfs+1]
Global c_tex_name$[c_surfs+1]

' track down used textures (thanks Mark!)
For i=1 To c_surfs
 c_surf(i)= GetSurface(mesh,i)
 c_brush(i)=GetSurfaceBrush( c_surf(i) )
 c_tex(i)=GetBrushTexture( c_brush(i) )
 If c_tex(i) <> Null
	 c_tex_name$(i)=Lower$(TextureName$( c_tex(i))) ' Full (!) Texture Path
	 curdir$=Lower$(CurrentDir$()) 
	 c_tex_name$(i)= Replace$(c_tex_name$(i),curdir$,"") '<<<<<<<<<<<<<<<<<<<
 End If
 Print c_tex_name$(i)
 If c_tex_name$(i)="" Then Print "Error: Surface No."+i+" has no Texture"
 If FileType(c_tex_name$(i))<>1 Then Print "Warning: Surface No."+i+" uses nonexistant Texture ("+c_tex_name$(i)+")."
Next

Print "Press any key to save this Mesh as TEMP.B3D"


WaitKey()

' End

WriteBB3D( "temp.b3d",mesh )

For i=1 To c_surfs
 FreeBrush c_brush(i)' Release memory
 If c_tex(i) <> Null FreeTexture c_tex(i)
Next


' test If it worked...
FreeEntity mesh
mesh2=LoadMesh("temp.b3d")
While Not KeyDown(27)
 TurnEntity mesh2,1,2,3
 RenderWorld()
 Text 0,0,"TEMP.B3D"
 Flip
Wend
End


Function WriteBB3D( f_name$,mesh )

	file=WriteFile( f_name$ )

	b3dSetFile( file )
	
	b3dBeginChunk( "BB3D" )
		b3dWriteInt( 1 )	'version

		b3dBeginChunk( "TEXS" ) ' list all textures used by the mesh
		For i=1 To c_surfs
			b3dWriteString( c_tex_name$(i) ) 	'texture file
			b3dWriteInt( 1 )					'flags
			b3dWriteInt( 2 )					'blend
			b3dWriteFloat( 0 )					'x in tex 0 (hu?)
			b3dWriteFloat( 0 )					'y in tex 0
			b3dWriteFloat( 1 )					'x scale 1
			b3dWriteFloat( 1 )					'y scale 1
			b3dWriteFloat( 0 )					'rotation 0
			
		Next
		b3dEndChunk()	'End of TEXS chunk

		
		For i=1 To c_surfs
			b3dBeginChunk( "BRUS" ) ' describe all brushes used by the mesh
		
			b3dWriteInt( 1 )					'number of textures per brush ; (eg 2 with lightmap)
			b3dWriteString( "brush"+(i-1) )		'brushname
			b3dWriteFloat( 1 )					'red
			b3dWriteFloat( 1 )					'green
			b3dWriteFloat( 1 )					'blue
			b3dWriteFloat( 1 )					'alpha
			b3dWriteFloat( 0 )					'shininess
			b3dWriteInt( 1 )					'blendmode
			b3dWriteInt( 0 )					'FX
			b3dWriteInt( i-1 )					'used texture index 
'			b3dWriteInt( ? )					;additional texture index (eg lightmap), but here we only use 1 (see above)

			b3dEndChunk()	'End of BRUS chunk
		Next
		
		b3dBeginChunk( "NODE" )
			b3dWriteString( "entity_name_here!" )
			b3dWriteFloat( 0 )	'x_pos
			b3dWriteFloat( 0 )	'y_pos
			b3dWriteFloat( 0 )	'z_pos
			b3dWriteFloat( 1 )	'x_scale
			b3dWriteFloat( 1 )	'y_scale
			b3dWriteFloat( 1 )	'z_scale
			b3dWriteFloat( 1 )	'rot_w
			b3dWriteFloat( 0 )	'rot_x
			b3dWriteFloat( 0 )	'rot_y
			b3dWriteFloat( 0 )	'rot_z
			WriteMESH( mesh )
		b3dEndChunk()	'End of NODE chunk
		
	b3dEndChunk()	'End of BB3D chunk
	
	CloseFile file
End Function

Function WriteMESH( mesh )

	n_surfs=CountSurfaces( mesh )
	
	b3dBeginChunk( "MESH" )
		b3dWriteInt( -1 )				'no 'entity' brush -1
		
		b3dBeginChunk( "VRTS" )
			b3dWriteInt( 0 )			'flags - 0=no normal/color
			b3dWriteInt( 1 )			'number of tex_coord sets (eg: 2 with lightmap)
			b3dWriteInt( 2 )			'coords per set (u,v,w?) 2 with uv, 3 with uvw
			
			For k=1 To n_surfs
				surf=GetSurface( mesh,k )
				n_verts=CountVertices( surf )-1
				
				For j=0 To n_verts
					b3dWriteFloat( VertexX( surf,j ) )
					b3dWriteFloat( VertexY( surf,j ) )
					b3dWriteFloat( VertexZ( surf,j ) )
					b3dWriteFloat( VertexU#( surf,j,0 ) )
					b3dWriteFloat( VertexV#( surf,j,0 ) )
'					b3dWriteFloat( VertexW#( surf,j,0 ) )
';					b3dWriteFloat( VertexU#( surf,j,1 ) ) ; lightmap uv
';					b3dWriteFloat( VertexV#( surf,j,1 ) ) ; lightmap uv
'					b3dWriteFloat( VertexW#( surf,j,1 ) )
				Next
			Next
		b3dEndChunk()	'End of VRTS chunk
		
		first_vert=0
		For k=1 To n_surfs
			surf=GetSurface( mesh,k )
			n_tris=CountTriangles( surf )-1
			
			b3dBeginChunk( "TRIS" )
				b3dWriteInt( k-1 )		'brush For these triangles (surf -1 !!!)
				
				For j=0 To n_tris
					b3dWriteInt( first_vert+TriangleVertex( surf,j,0 ) )
					b3dWriteInt( first_vert+TriangleVertex( surf,j,1 ) )
					b3dWriteInt( first_vert+TriangleVertex( surf,j,2 ) )
				Next
				
			b3dEndChunk()	'End of TRIS chunk
			
			first_vert=first_vert+CountVertices( surf )
			
		Next
		
	b3dEndChunk()	'End of MESH chunk
	
End Function


'-------------------------------------------------------------------------------------------------




'
'b3d file utils to be included
'


Function b3dSetFile( file )
	b3d_tos=0
	b3d_file=file
End Function

'***** functions for reading from B3D files *****

Function b3dReadByte()
	Return ReadByte( b3d_file )
End Function

Function b3dReadInt()
	Return ReadInt( b3d_file )
End Function

Function b3dReadFloat#()
	Return ReadFloat( b3d_file )
End Function

Function b3dReadString$()
	Repeat
		ch=b3dReadByte()
		If ch=0 Return t$
		t$=t$+Chr$(ch)
	Forever
End Function

Function b3dReadChunk$()
	For k=1 To 4
		tag$=tag$+Chr$(b3dReadByte())
	Next
	sz=ReadInt( b3d_file )
	b3d_tos=b3d_tos+1
	b3d_stack(b3d_tos)=StreamPos( b3d_file )+sz
	Return tag$
End Function

Function b3dExitChunk()
	SeekStream b3d_file,b3d_stack(b3d_tos)
	b3d_tos=b3d_tos-1
End Function

Function b3dChunkSize()
	Return b3d_stack(b3d_tos)-StreamPos( b3d_file )
End Function

'***** Functions for writing to B3D files *****

Function b3dWriteByte( n )
	WriteByte( b3d_file,n )
End Function

Function b3dWriteInt( n )
	WriteInt( b3d_file,n )
End Function

Function b3dWriteFloat( n# )
	WriteFloat( b3d_file,n )
End Function

Function b3dWriteString( t$ )
	For k=1 To Len( t$ )
		ch=Asc(Mid$(t$,k,1))
		b3dWriteByte(ch)
		If ch=0 Return
	Next
	b3dWriteByte( 0 )
End Function

Function b3dBeginChunk( tag$ )
	b3d_tos=b3d_tos+1
	For k=1 To 4
		b3dWriteByte(Asc(Mid$( tag$,k,1 )))
	Next
	b3dWriteInt( 0 )
	b3d_stack(b3d_tos)=StreamPos( b3d_file )
End Function

Function b3dEndChunk()
	n=StreamPos( b3d_file )
	SeekStream b3d_file,b3d_stack(b3d_tos)-4
	b3dWriteInt( n-b3d_stack(b3d_tos) )
	SeekStream b3d_file,n
	b3d_tos=b3d_tos-1
End Function

The program loads a file, then saves it. If you run it, it will give a 'file not found' error because it can't find "testsurf.b3d".

Hezkore

(Posted 2011) [#3]

Yeah but Warner... you seem pretty high on this 3D stuff...
What I want to do is merge a bunch of meshes (over 300) and they all have one texture of their own.
I'd like to merge those 300 into one file, so I was thinking about merging the meshes using the merge mesh function and then resaving the mesh as something.
But the problem is that when I do it (tried like all of the code archive export codes in Blitz3D) they just save one of the textures and it's very important that it saves all of the textures.
Do you know what I mean?
I guess I should make an example of this...
I'll upload it soon!

Last edited 2011

Warner

(Posted 2011) [#4]

I'd like to merge those 300 into one file,

O_o really? That sounds like quite erm .. much.
You might use your own mesh format, maybe. If it is a single mesh, without hierarchy, use something like this:

SuperStrict

Import sidesign.minib3d

Graphics3D 800, 600, 0, 2

CreateLight()

Local cam:TCamera = CreateCamera()
MoveEntity cam, 0, 0, -15

'build a mesh
Local tex1:TBrush = LoadBrush("..\data\4922.png")
Local tex2:TBrush = LoadBrush("..\data\checker.png")

Local mesh:TMesh = CreateCube()
Local mesh2:TMesh = CreateSphere()

PaintSurface GetSurface(mesh, 1), tex1
PaintSurface GetSurface(mesh2, 1), tex2

PositionMesh mesh2, 0, 2, 0
AddMesh mesh2, mesh
FreeEntity mesh2

'save it
SaveMesh(mesh, "mesh.dat")

'free it
FreeEntity mesh

'load it back
Local test:TMesh = ReadMesh("mesh.dat")

Repeat

	TurnEntity test, 1, 2, 3
	RenderWorld
	Flip

Until KeyHit(27)

End


Function SaveMesh(mesh:TMesh, fname$)

	Local ff:TStream = WriteFile(fname$)
	WriteInt ff, CountSurfaces(mesh)
	For Local i% = 1 To CountSurfaces(mesh)
	
		Local surf:TSurface = GetSurface(mesh, i)
			
		Local brush:TBrush = GetSurfaceBrush(surf)
		For Local d% = 0 To 7
			Local tex:TTexture = GetBrushTexture(brush, d)
			If tex <> Null Then WriteLine ff, TextureName(tex) Else WriteLine ff, ""
		Next
	
		WriteInt ff, CountVertices(surf) 
		For Local v% = 0 To CountVertices(surf) - 1
			WriteFloat ff, VertexX(surf, v)
			WriteFloat ff, VertexY(surf, v)
			WriteFloat ff, VertexZ(surf, v)				
			WriteFloat ff, VertexU(surf, v, 0)
			WriteFloat ff, VertexV(surf, v, 0)
			WriteFloat ff, VertexU(surf, v, 1)
			WriteFloat ff, VertexV(surf, v, 1)
			WriteFloat ff, VertexNX(surf, v)
			WriteFloat ff, VertexNY(surf, v)
			WriteFloat ff, VertexNZ(surf, v)				
		Next
		
		WriteInt ff, CountTriangles(surf)
		For Local t% = 0 To CountTriangles(surf) - 1
			WriteInt ff, TriangleVertex(surf, t, 0)
			WriteInt ff, TriangleVertex(surf, t, 1)
			WriteInt ff, TriangleVertex(surf, t, 2)
		Next
		
	Next
	CloseFile ff

End Function

Function ReadMesh:TMesh(fname$)

	If FileType(fname$) <> 1 Return Null
	Local ff:TStream = ReadFile(fname$)
	
	Local mesh:TMesh = CreateMesh()
		
	Local countsurf% = ReadInt(ff)
	For Local i% = 1 To countsurf
	
		Local surf:TSurface = CreateSurface(mesh)

		Local brush:TBrush = CreateBrush(255, 255, 255)
		
		For Local d% = 0 To 7
			Local texname$ = ReadLine(ff)
			If texname$ <> Null Then 
				Local tex:TTexture = LoadTexture(texname$)
				If tex <> Null Then BrushTexture brush, tex, 0, d
			End If
		Next
		PaintSurface surf, brush
		
		Local countv% = ReadInt(ff)
		For Local v% = 0 To countv - 1
			Local vx# = ReadFloat(ff)
			Local vy# = ReadFloat(ff)
			Local vz# = ReadFloat(ff)
			Local vu# = ReadFloat(ff)
			Local vv# = ReadFloat(ff)
			Local vertex% = AddVertex (surf, vx,vy,vz,vu,vv)
			Local vu2# = ReadFloat(ff)
			Local vv2# = ReadFloat(ff)			
			VertexTexCoords surf, vertex, vu2, vv2, 0.0, 1
			Local nx# = ReadFloat(ff)
			Local ny# = ReadFloat(ff)
			Local nz# = ReadFloat(ff)
			VertexNormal surf, vertex, nx, ny, nz
		Next

		Local countt% = ReadInt(ff)
		For Local t% = 0 To countt - 1
			Local a% = ReadInt(ff)
			Local b% = ReadInt(ff)
			Local c% = ReadInt(ff)
			AddTriangle surf, a, b, c
		Next
	Next

	CloseFile ff
	
	Return mesh
	
End Function

Hezkore

(Posted 2011) [#5]

Yeah heh it's quite much, but there are a LOOOOOT of objects and the problem is that I don't really control it, cause the editor I'm using (and am forced to use) is not made by me.
And that's the reason I'd like to merge them into one single file.

When I did AddMesh() in Blitz3D... well let's just say it had some odd results when it came to using GetSurfaceBrush()

But yeah, thanks a lot, I'll give this a try! :)

AdamRedwoods

(Posted 2011) [#6]

AddMesh() compares brushes and if they're the same then it combines the surfaces.

Sometimes what I do is add a switch to disable odd behaviors that miniB3D does:
AddMesh(mesh, true) '' to skip compare brushes routine, and add in your own if/then to check, etc...

That way the original code works, but adds your own special routines.

Hezkore

(Posted 2011) [#7]

Thanks for the tip AdamRedwoods!
And thanks Warner for all the help.
Everything's been solved! :)