Texture projection example for miniB3D

BlitzMax Forums/MiniB3D Module/Texture projection example for miniB3D

AdamRedwoods

(Posted 2011) [#1]

Originally taken from code archives, big shout out to Fredborg for writing this. I took it and condensed it. It's not perfect, has some odd triangle problems, but works pretty well aside from that.

You could also use some other entity than the camera entity and get a fixed projection.

I used this technique to create a second texture layer (texcoords 0 or 1) which was going to be a lightmap, but couldn't fade the light texture (oh well). The advantage would've been you could run it once in the beginning and then the vertexcoords are setup, so as long as it wasn't dynamic, there's little overhead.

THEORY:
Yes, you could do this faster by using OpenGL's eye plane texture coordinate system (glTexGeni(GL_S,GL_TEXTURE_GEN_MODE,GL_EYE_LINEAR)) , and hack it into miniB3D. Surprised this was never an option in miniB3D.

Here's the code, it's setup to take a second texture as a base layer (dl_tex2), and I've left some commented code from the original work.
NOTE: you'll need a "silly.png" image to get it to work.

''
'
' Textured spotlight thingy
'
' Created by Mikkel Fredborg
' Use as you please!
' 
' to blitzmax by adam redwoods
'

Strict
Import "../minib3d/minib3d.bmx"

Type dl_light
	Field mesh:TMesh ''receiver
	Field entity:TEntity ''projector
	Field range#
	Field scale#
	Field intensity#
	Field flicker#
	Field flickerrange#
	Field r#,g#,b#
	Field camera:TCamera
End Type

Global dl_brush:TBrush
Global dl_tex:TTexture
Global dll:dl_light
Global dl_tex2:TTexture

Function DL_Init()

	'ClearTextureFilters
	dl_tex = LoadTexture("silly.png",1+16+32) '(1+16+32) )
	'dl_tex2 = LoadTexture("bricks.png",(1+16+32) )
	dl_tex2 = CreateTexture(64,64)
	
	dl_brush = CreateBrush()
	BrushTexture dl_brush,dl_tex,0,1
	'BrushTexture dl_brush,dl_tex2,0,0
	TextureCoords dl_tex,1
	'TextureCoords dl_tex2,0
	
	BrushFX dl_brush,2
	TextureBlend dl_tex, 2
	brushcolor dl_brush,150,160,170

End Function


Function DL_SetReceiver(mesh:TMesh)
	If dll = Null
		dll = New dl_light
	End If
	
	dll.mesh = mesh
	For Local i:Int = 1 To CountChildren(dll.mesh)
		If(dll.mesh.getChild(i)) PaintMesh TMesh(dll.mesh.getChild(i)), dl_brush
	Next
End Function

Function DL_SetLight(entity:TEntity, camera:TCamera, range#=150.0,scale#=1.00,intensity#=2.0,flicker#=0.05,flickerrange#=0.5,r#=200,g#=220,b#=255)

	If dll = Null
		dll = New dl_light
	End If
	
	dll.entity 	 = entity
	dll.range  	 = range
	dll.scale		= scale
	dll.intensity = intensity
	dll.flicker	 = flicker
	dll.flickerrange = flickerrange
	
	dll.r		= r
	dll.g		= g
	dll.b		= b
	dll.camera = camera
	
End Function

Function DL_Update()

	'dll.dl_light = First dl_light
	If dll = Null Then Return

	'Local intensity:Float
	
	'If Rnd(0.0,1.0)<dll.flicker
		'intensity = dll.intensity * Rnd(dll.flickerrange,1.0)
	'Else
		'intensity = dll.intensity
	'End If
	'intensity = dll.intensity

	Local mesh:TMesh	= dll.mesh
	Local index:Int =0
'Print CountChildren(dlr.mesh)
	While index <= CountChildren(dll.mesh)+1
		If mesh And EntityInView(mesh, dll.camera)
		
		Local n_surfs:Int = CountSurfaces(mesh)

		For Local s:Int = 1 To n_surfs
			Local surf:TSurface = GetSurface(mesh,s)
			Local n_verts:Int = CountVertices(surf)-1
			For Local v% = 0 To n_verts

				TFormPoint VertexX(surf,v),VertexY(surf,v),VertexZ(surf,v),mesh,dll.entity
				Local x# = TFormedX()
				Local y# = TFormedY()
				Local z# = TFormedZ()
				

				Local dist# = Sqr(x*x + y*y + z*z)*dll.scale
				Local tu# = (x/dist)+0.5
				Local tv# = 1.0-((y/dist)+0.5)
				
				VertexTexCoords surf,v,tu,tv,0.0,1

				'If z>dll.range Then z = dll.range
				'Local falloff# = 1.0-(z/dll.range)
				'If falloff<0.0 Then falloff = 0.0
				'If falloff>1.0 Then falloff = 1.0
				
				'TFormNormal VertexNX(surf,v),VertexNY(surf,v),VertexNZ(surf,v),mesh,dll.entity
				'Local dot# = -TFormedZ()*falloff*intensity

				'If dot>0.0
					
					'VertexTexCoords surf,v,tu,tv
					'VertexColor surf,v,dot*dll.r,dot*dll.g,dot*dll.b
				'Else
					'VertexColor surf,v,0,0,0

				'End If
			Next
		Next	
		EndIf	

		mesh = TMesh(GetChild (dll.mesh,index))
		index:+1
		
	Wend

End Function


''Example Program____________________

SetGraphicsDriver GLGraphicsDriver()

Global width=640
Global height=480

Graphics3d width,height,0,2
Cleartexturefilters

AmbientLight 12,24,50
SeedRnd MilliSecs()

Local light:TLight = CreateLight(2)
RotateEntity light,0,-90,0
LightColor light,150,150,150
LightRange light,100

Local camera:TCamera = CreateCamera()
Local scene:TMesh = CreateMesh()

DL_Init()
For Local i:Int = 0 To 100

	Local cube:TMesh = CreateCube()
	ScaleMesh cube,Rnd(1,10),Rnd(1,10),Rnd(1,10)
	RotateMesh cube,Rnd(-90,90),Rnd(-180,180),Rnd(-180,180)
	PositionMesh cube,Rnd(-100,100),Rnd(-100,100),Rnd(-100,100)
	Local b:TBrush = CreateBrush()
	b.Brushcolor(40,50,60)
	paintmesh cube,dl_brush
	'AddMesh cube,scene
	'CopyEntity cube,scene
	CopyMesh cube,scene
	
	FreeEntity cube
	
Next

Local bigcube:TMesh = CreateSphere(24,scene)
ScaleMesh bigcube,150,150,150
FlipMesh bigcube

DL_SetLight(camera, camera) ''the first camera can be any entity
DL_SetReceiver(scene)


Local spd# = 2.0, renders%, fps%, old_ms%
old_ms=MilliSecs()

Repeat

	MoveEntity camera,(KeyDown(205)-KeyDown(203))*spd,0,(KeyDown(200)-KeyDown(208))*spd
	TurnEntity camera,-MouseYSpeed()*0.5,MouseXSpeed()*0.5,0
	RotateEntity camera,EntityPitch(camera,True),EntityYaw(camera,True),0

	DL_Update()

	RenderWorld
	
	renders=renders+1
	
	' calculate fps
	If MilliSecs()-old_ms>=1000
		old_ms=MilliSecs()
		fps=renders
		renders=0
	EndIf
	
	Text 0,0,"FPS: "+fps
	
	Flip 0

Until (AppTerminate() Or KeyDown(KEY_ESCAPE))

End

Last edited 2011