Texture bug?

BlitzMax Forums/MiniB3D Module/Texture bug?

SLotman

(Posted 2010) [#1]

I tried something simple, creating a cube and texturing it... but the same code, the results are different on miniB3D and Blitz3D:

miniB3D code:

Import "minib3d.bmx"

Global tex:TTexture
Global camera:TCamera
Global t:TTimer

Graphics3D 800,600,32,2

AmbientLight 128,128,128

camera = CreateCamera()
CameraRange camera, 0.01,5000
MoveEntity camera, 0,1,0

Local light:TLight=CreateLight(2,camera)

MakeTexture()

Local c:TMesh=CreateCube()
MoveEntity c,0,0,10
EntityTexture c, tex

PointEntity light,c

t=CreateTimer(60)
While Not KeyHit(KEY_ESCAPE)
	Cls
	
	If KeyDown(KEY_1) Then Wireframe True Else Wireframe False
	
	UpdateWorld
	RenderWorld

	text 10,10, "Arrows: move - A/D: strafe - ESC Exit"
	
	Flip
	WaitTimer(t)	
Wend

ClearWorld
EndGraphics
End


' Create Texture For ground
Function MakeTexture()
	tex=CreateTexture(16,16,1)
	
	BeginMax2D()
	Cls
	SetColor 255,255,255
	DrawRect 0,0,16,16
	SetColor 255,0,0
	DrawRect 0,0,8,8
	DrawRect 8,8,8,8
	SetColor 255,255,255
	EndMax2D()

	BackBufferToTex(tex,0)
	
End Function

Now, same code, for Blitz3D:

Graphics3D 800,600,32,2

Global tex

AmbientLight 128,128,128

camera = CreateCamera()
CameraRange camera, 0.01,5000
MoveEntity camera, 0,1,0

Local light=CreateLight(2,camera)

MakeTexture()
;tex = LoadTexture("C:\Apps\Linguagens\blitz3d\commands\3d_examples\media\b3dlogo.jpg")

;Local plane=CreatePlane(16)
;EntityTexture plane, tex


Local c=CreateCube()
MoveEntity c,0,0,10
EntityTexture c, tex

PointEntity light,c

t=CreateTimer(60)
While Not KeyHit(1)
	Cls
	
	If KeyDown(17) Then Wireframe True Else Wireframe False
	
	UpdateWorld
	RenderWorld

	Text 10,10, "Arrows: move - A/D: strafe - ESC Exit"
	
	Flip
	WaitTimer(t)
	
Wend

ClearWorld
EndGraphics
End


;' Create Texture For ground
Function MakeTexture()
	tex=CreateTexture(16,16,1)
	
	Cls
	Color 255,255,255
	Rect 0,0,16,16
	Color 255,0,0
	Rect 0,0,8,8
	Rect 8,8,8,8
	Color 255,255,255
	CopyRect 0,0,16,16,0,0,BackBuffer(),TextureBuffer(tex)

	
End Function

What could be the problem????

slenkar

(Posted 2010) [#2]

just a crap guess

directx has the opposite co-ordinate systems so maybe the texture matrix is also opposite

Warner

(Posted 2010) [#3]

Also guessing, since I have no BMax here: maybe it is the combination of BackBufferToTex and Begin/EndMax2D? Try using BackBufferToTex before EndMax2D.