Blend modes Extended

BlitzMax Forums/MiniB3D Module/Blend modes Extended

SLotman

(Posted 2010) [#1]

I just did this out of fun - I took the "new" blend modes implemented on FastExt for Blitz3D, and added them to miniB3D. To do this you just need to:

Open miniB3D.inc and add at the end of the file:

' Fast Extension "hack"
Const FE_INVALPHA% = $010605
Const FE_INVCOLOR% = $010406
Const FE_INVCOLORADD% = $010402
Const FE_NOALPHA% = $000101

Then, open TMesh.bmx and on Update function you replace the whole "Select blend" part with this:

			' blend modes
			Select blend
				Case 0
					glBlendFunc(GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) ' alpha
				Case 1
					glBlendFunc(GL_SRC_ALPHA,GL_ONE_MINUS_SRC_ALPHA) ' alpha
				Case 2
					glBlendFunc(GL_DST_COLOR,GL_ZERO) ' multiply
				Case 3
					glBlendFunc(GL_SRC_ALPHA,GL_ONE) ' additive and alpha

			    ' fast extension ;)					
				Case FE_INVALPHA
					glBlendFunc(GL_ONE_MINUS_SRC_ALPHA, GL_SRC_ALPHA)
					
				Case FE_INVCOLOR
					glBlendFunc(GL_ONE_MINUS_SRC_COLOR, GL_ONE_MINUS_SRC_ALPHA)

				Case FE_INVCOLORADD
					glBlendFunc(GL_ONE_MINUS_SRC_COLOR, GL_ONE)
				
				Case FE_NOALPHA
					glBlendFunc(GL_SRC_COLOR, GL_ZERO)
				
			End Select

and that's it! Recompile and run the program below - the same from FastExt samples to see it working :)

Import sidesign.minib3d

'; Example of use FastExt library
'; (c) 2006-2010 created by MixailV aka Monster^Sage  <a href="http://www.fastlibs.com" target="_blank">http://www.fastlibs.com</a>


' not needed ;)
'Include "include\FastExt.bb"

Graphics3D 800,600,0,2

Local tex:TTexture=LoadTexture ("Devil.png",1+2)

Local cub0:TMesh=CreateCube()
PositionEntity cub0,-2,1.5,0
EntityTexture cub0,tex

Local cub1:TMesh=CreateCube()
PositionEntity cub1,2,1.5,0
EntityTexture cub1,tex
EntityBlend cub1, FE_INVALPHA			'; <<<< инвертируем только альфа-канал (invert alpha-channel)

Local cub2:TMesh=CreateCube()
PositionEntity cub2,-3,-1.5,0
EntityBlend cub2, FE_INVCOLOR			'; <<<< инвертируем только цвет (invert color only)
EntityTexture cub2,tex

Local cub3:TMesh=CreateCube()
PositionEntity cub3,0,-1.5,0
EntityBlend cub3, FE_INVCOLORADD		'; <<<< инвертируем цвет и используем сложение (invert And add color)
EntityTexture cub3,tex

Local cub4:TMesh=CreateCube()
PositionEntity cub4,3,-1.5,0
EntityBlend cub4, FE_NOALPHA			'; <<<< принудительно отключаем использование альфа-канала для альфа-текстур! (manual disable alpha-cannel)
EntityTexture cub4,tex


CreateLight  
Local c:TCamera=CreateCamera()  
CameraClsColor c,128,128,128  
PositionEntity c,0,0,-5

While Not KeyHit(KEY_ESCAPE)
	TurnEntity cub0,0.1,0.2,0.3
	TurnEntity cub1,0.1,0.2,0.3
	TurnEntity cub2,0.1,0.2,0.3
	TurnEntity cub3,0.1,0.2,0.3
	TurnEntity cub4,0.1,0.2,0.3
	RenderWorld  
	Flip
Wend

You'll also need this image:

(which can also be found on the FastExt trial)

And this is the result:

Too bad I have no clue how to do the bump, reflection/refraction stuff - it would be great on miniB3D :)

Last edited 2010

Last edited 2010