Rotation passes a point

BlitzMax Forums/MiniB3D Module/Rotation passes a point

ima747

(Posted 2010) [#1]

I have a sprite that's a circle, think wheel of fortune wheel, and when a given point goes past a certain angle I need to do things, the point is attached to the wheel. I can't get my head around a good way to detect that if the wheel turns a certain amount, will that cause the point to cross the target...

Anyone got an idea so my brain can stop exploding?

Sledge

(Posted 2010) [#2]

The angle the point is at in relation to the angle of the wheel will be constant if it is attached. To see if it falls within a certain range, mod it and see!

EDIT: Oh, I see there are a couple of gotchas, namely that positive roll rotations seem to turn entities negatively and that EntityRoll() can actually be a negative. Here's a (long-winded!) solution...

SuperStrict
Import sidesign.minib3d

Graphics3D 800,600,32,2,60
Local cam:TCamera = CreateCamera()
PositionEntity cam,0,0,-5

Local wheel:TEntity = CreateSphere()
ScaleEntity wheel,1,1,.1

Local myPoint:TPoint = TPoint.Make(wheel,90.0,0.5)

While Not ( KeyHit(KEY_ESCAPE) Or AppTerminate() )
	TurnEntity wheel,0,0,0.5

	RenderWorld()
	BeginMax2D()
		DrawText "Point's angle in relation to wheel: "+myPoint.GetAngle(False),10,10
		DrawText "Point's angle in relation to world: "+myPoint.GetAngle(True),10,20
		
		If myPoint.IsWithinClockwiseRange(0,45) Then DrawText "0 to 45 degrees!",10,50
		If myPoint.IsWithinClockwiseRange(270,45) Then DrawText "270 to 45 degrees!",10,70
	EndMax2D()
	Flip -1
Wend


Type TPoint
	Field angle:Float
	Field radius:Float
	Field geom:TEntity
	Field parent:TEntity
	
	Function Make:TPoint(parent_arg:TEntity,angle_arg:Float,radius_arg:Float)
		Local newPoint:TPoint = New TPoint
		newPoint.geom = CreateSphere()
		ScaleEntity newPoint.geom,.1,.1,.1
		EntityColor newPoint.geom,255,100,100
		EntityOrder newPoint.geom,-1
		EntityParent newPoint.geom,parent_arg
		PositionEntity newPoint.geom, Sin(angle_arg)*radius_arg, Cos(angle_arg)*radius_arg,0,False
		
		newPoint.radius = radius_arg
		newPoint.angle = angle_arg
		newPoint.parent = parent_arg
	
		Return newPoint
	End Function
	
	Method GetAngle:Float(global_arg:Int)
		If Not global_arg Return Self.angle
		Local parentAngle:Float = (-EntityRoll(Self.parent) Mod 360)
		parentAngle = 360.0+parentAngle 
		
		Return (parentAngle+Self.angle) Mod 360
	End Method
	
	Method IsWithinClockwiseRange:Int(first_arg:Float, second_arg:Float)
		Local currentAngle:Float = Self.GetAngle(True)
		
		If first_arg>second_arg
			If (currentAngle > first_arg) Or (currentAngle < second_arg) Return True
			Return False
		Else
			If (currentAngle > first_arg) And (currentAngle < second_arg) Return True
			Return False
		EndIf
	End Method
End Type

The trick is to get the point's global angle within the normal 0-359 degree range and then specify that you are checking it against values supplied in a clockwise direction (although, of course, you could just as easily go with anticlockwise as long as you pick one and stick to it, but that's more typing!) That way you can tell which portion to check and whether it transcends zero.

ima747

(Posted 2010) [#3]

Thanks sledge! I think I figured out what i need, your code will come in quite handy when I get a little further.