Particles...?

BlitzMax Forums/MiniB3D Module/Particles...?

SLotman

(Posted 2009) [#1]

I just start experimenting with MiniB3d, trying to find a replacement for the dying Blitz3D :(

I've got everything up and running, added all "fixes" I could find in this forum, and even changed everything so it would compile as superstrict.

Then, I tried to port the EPS Particle System from B3D to miniB3D (since I'm used to it on B3D, and also, it has a pretty good editor)... but after coding all night, I failed :(

At one time, I even saw the particles running... but it got slower and slower in a short period of time, to a point where the engine was running at 0 FPS. So I tough it was some kind of mistake I made, and started re-writing it from scratch... and this time, not only it slows down, but nothing appears on screen :(

So... have anyone tried porting the EPS to miniB3D? Or do you guys know a better system, with an particle editor already available?

slenkar

(Posted 2009) [#2]

I made my own particle system by learning from JFK's in the code archives

Type particle
Field alpha#
Field ID
Field lifespan#
Field start_lifespan#
Field x_vel#
Field y_vel#
Field z_vel#

Field mesh
Field rand_rot
Field start_lift#
Field speed#
Field end_lift#

End Type

Type emitter
Field alpha#
Field blend
Field nof_sprite
Field dispersion
Field interval
Field lifespan#
Field texture
Field pivot
Field rand_rot
Field start_lift#
Field speed#
Field sprite_scale#
Field end_lift#
Field emitter_timer
Field emitter_lifespan#
End Type

Function initiate_particles()
load_particle_media()
For x=1 To 400
e.particle=New particle
e\ID=x
Next
End Function

Function delete_particles()
Delete Each particle
Delete Each emitter
End Function

Const explosion=-1
Const dimension_effect=1
Const spark=-2
Const dust=-3
Global fire_tex
Global nebula_tex
Global spark_tex
Global smoke_tex



Function load_particle_media()
g.global_Type=First global_Type
 fire_tex=LoadTexture("data/"+chosen_game+"/pics\particles\fire3.png",4)
nebula_tex=LoadTexture("data/"+chosen_game+"/pics\particles\nebulasprite.png",4)
 spark_tex=LoadTexture("data/"+chosen_game+"/pics\particles\flare4.png",4)
smoke_tex=LoadTexture("data/"+chosen_game+"/pics\particles\smoke2.png",4)

End Function

Function launch_emitter( texture,nof_sprite,lifespan#,blend,rand_rot,start_lift#,end_lift#,alpha#,dispersion,speed#,emitter_lifespan,emitter_interval,sprite_scale )
g.global_type=First global_type
e.emitter=New emitter
e\texture=texture
e\nof_sprite=nof_sprite
e\lifespan=lifespan
e\blend=blend
e\rand_rot=rand_rot
e\start_lift=start_lift
e\end_lift=end_lift
e\alpha=alpha
e\dispersion=dispersion
e\speed=speed
e\emitter_lifespan=emitter_lifespan
e\interval=emitter_interval
e\sprite_scale=sprite_scale
e\pivot=CreatePivot()
PositionEntity e\pivot,EntityX(g\particle_pivot,1),EntityY(g\particle_pivot,1),EntityZ(g\particle_pivot,1)
End Function

Function number_of_emitters()
For e.emitter=Each emitter
returner=returner+1
Next
Return returner
End Function

Function number_of_particles()
For e.particle=Each particle
If e\lifespan>0
f=f+1
EndIf
Next
Return f
End Function

Function Launch_effect(effect$)
For p.particle_info=Each particle_info
If p\name=effect
For t.texture_info=Each texture_info
If t\name=p\texture
launch_emitter(t\texture_handle,p\nof_sprite,p\lifespan,p\blend,p\rand_rot,p\start_lift,p\end_lift,p\alpha,p\dispersion,p\speed,p\emitter_lifespan,p\emitter_interval,p\sprite_scale)
EndIf
Next
EndIf
Next
End Function

Function stop_particles()
Delete Each emitter
For p.particle=Each particle
If p\mesh>0
HideEntity p\mesh
EndIf
Next
End Function

Function launch_particle(texture, lifespan#=3,blend=3,rand_rot=1,start_lift#=0,end_lift#=0,alpha#=1.0,dispersion=1,speed#=1,pivot,scale)


g.global_type=First global_type
sprites_launched=0
For e.particle =Each particle
;RuntimeError "particle"
If e\lifespan=0
;RuntimeError "lifespan"
If sprites_launched=0
sprites_launched=sprites_launched+1


;If dispersion=1
e\x_vel=Rnd(-speed,speed)
e\y_vel=Rnd(-speed,speed)
e\z_vel=Rnd(-speed,speed)
;EndIf


sprites_launched=sprites_launched+1
;
If e\mesh=0
e\mesh=CreateSprite()
EntityTexture e\mesh,texture,0,0
Else
;FreeEntity e\mesh
;e\mesh=CreateSprite()
EntityTexture e\mesh,texture,0,0
ShowEntity e\mesh
EndIf


ScaleSprite e\mesh,scale,scale
PositionEntity e\mesh,EntityX(pivot,1),EntityY(pivot,1),EntityZ(pivot,1),1
;RuntimeError e\mesh+"mesh"+EntityX(pivot,1)+" x "+EntityY(pivot,1)+" y "+EntityZ(pivot,1)+" z "
;MoveEntity e\mesh,Rnd(-0.1,0.1),Rnd(-0.1,0.1),Rnd(-0.1,0.1)

If rand_rot<>0
e\rand_rot=Rnd(1,359)
Else
e\rand_rot=0
EndIf
;
EntityBlend e\mesh,blend
RotateSprite e\mesh,e\rand_rot
   EntityAlpha e\mesh,alpha
e\speed=speed
e\lifespan=lifespan
e\start_lifespan=lifespan
e\alpha=alpha
e\start_lift=start_lift
e\end_lift=end_lift
EndIf
EndIf
Next
;
;
End Function


Function updateemitters()
For e.emitter=Each emitter
If e\emitter_lifespan>0
If time>e\emitter_timer+e\interval
e\emitter_timer=time
For x=1 To e\nof_sprite
launch_particle(e\texture, e\lifespan,e\blend,e\rand_rot,e\start_lift#,e\end_lift#,e\alpha#,e\dispersion,e\speed#,e\pivot,e\sprite_scale)
Next
e\emitter_lifespan=e\emitter_lifespan-e\interval
EndIf
Else
FreeEntity e\pivot
Delete e
EndIf
Next
End Function

Function UpdateParticles()

 For e.particle=Each particle
  If e\lifespan>0
e\lifespan=e\lifespan-.1


alpha#=(1/e\start_lifespan)*e\lifespan
    

EntityAlpha e\mesh,alpha

MoveEntity e\mesh,e\x_vel,e\y_vel,e\z_vel

If e\start_lift<>0
MoveEntity e\mesh,0,e\start_lift,0
If e\start_lift>0
e\start_lift=e\start_lift-0.1
EndIf
If e\start_lift<0
e\start_lift=e\start_lift+0.1
EndIf
If Abs(e\start_lift)<0.6
e\start_lift=0
EndIf
EndIf


If e\end_lift<>0
MoveEntity e\mesh,0,e\end_lift,0
EndIf



  Else
e\lifespan=0
If e\mesh>0
       HideEntity  e\mesh
EndIf
   EndIf
 Next
End Function

its very simple and shouldnt be difficult to convert

heres the XML file that describes different effects

<particle>
   <particles>
      <explosion texture="fire" nofsprite="8" lifespan="2" blend="3" randrot="1" startlift="0" endlift="0" alpha=".5" dispersion="1" speed=".15" emitterlifespan="500" emitterinterval="500" spritescale="6" name="explosion"/>
      <spark texture="spark" nofsprite="1" lifespan="8" blend="3" randrot="1" startlift="2.5" endlift="-2" alpha="1" dispersion="1" speed=".3" emitterlifespan="1000" emitterinterval="100" spritescale="2" name="spark"/>
      <dust texture="smoke" nofsprite="2" lifespan=".5" blend="3" randrot="1" startlift="1" endlift="0" alpha=".3" dispersion="1" speed="0.04" emitterlifespan="500" emitterinterval="500" spritescale="3" name="dust"/>
      <dimension texture="nebula" nofsprite="3" lifespan="2" blend="3" randrot="1" startlift="0" endlift="0" alpha=".5" dispersion="1" speed=".15" emitterlifespan="500" emitterinterval="500" spritescale="6" name="dimension"/>
   </particles>
</particle>

EXAMPLE


Global time
Type global_type
Field particle_pivot
End Type


Graphics3D 640,480,16,1
SetBuffer BackBuffer()
g.global_type=New Global_type

g\particle_pivot=CreatePivot()

Include "particle system.bb"
initiate_particles()
; create a scene for the demo...
camera=CreateCamera()
MoveEntity camera,0,5,-50
RotateEntity camera,25,0,0

ter=CreateCube()
TurnEntity ter,0,45,0
ScaleEntity ter,100,1,100
tertex=CreateTexture(128,128,9)
Color 0,255,0
SetBuffer TextureBuffer(tertex)
For j=0 To 15 
 For i=0 To 15 
  Color 0,100,0
  Line i*16,0,i*16,128
  Line 0,j*16,128,j*16
 Next
Next
SetBuffer BackBuffer()
PositionEntity ter,0,-5,0
ScaleTexture tertex,.15,.15
EntityTexture ter,tertex
EntityPickMode ter,2

timer=CreateTimer(30)
; test Program
While KeyDown(1)=0
WaitTimer (timer)

time=MilliSecs()
 If MouseHit(2) Then demo=(demo+1)Mod 6
 If MouseHit(1) 
  target=CameraPick(camera,MouseX(),MouseY())
  If target<>0 
   x=PickedX()
   y=PickedY()
   z=PickedZ()
PositionEntity g\particle_pivot,x,y,z,1
   ; Examples of usage

   If demo=0 Then Launch_effect(explosion) 
If demo=1 Then launch_effect(spark)
If demo=2 Then launch_effect(dimension_effect)
If demo=3 Then launch_effect(dust)
EndIf
 EndIf

 RenderWorld()
 Updateemitters()
updateparticles()
 Rect MouseX()-5,MouseY()-5,10,10,0
life=0
For f.emitter=Each emitter
life=f\emitter_lifespan
Exit
Next

 Text 0,0,life
 Text 0,16,"Current Demo: "+demo
Text 0,32,TrisRendered()
 Flip
Wend
End

Kryzon

(Posted 2009) [#3]

Does MiniB3D have the same surface "problem" that Blitz3D has (meaning, for every sprite created a new surface is also created, which slows everything down considerably)?

Or it is optimized automatically by the engine?

SLotman

(Posted 2009) [#4]

I made my own particle system by learning from JFK's in the code archives

Thanks, but that's not what I'm looking for :(

I can write a particle engine from scratch... I even did a 2D one on "pure" Blitzmax some months ago.

My point is that the EPS particle from B3D already have a pretty good editor, which helps a lot when making a game. I even altered it to load models, so I can see exactly how the particle will look like when implemented in game.

Does MiniB3D have the same surface "problem" that Blitz3D has (meaning, for every sprite created, a new surface is also created)?

Or it is optimized automatically by the engine?

I have no idea. It shouldn't. Even on Blitz3D, the EPS system uses quads, instead of sprites, so no problems there.

SLotman

(Posted 2009) [#5]

Here, I ported it AGAIN, and you guys can test it out.
Why the frame rate keeps dropping, I have no clue. On B3D the same emitter runs without any problem :(

Edit: it looks like particles are not being released? I'm completely lost...

Success! I wasn't removing the particles from particles list :)

simonh

(Posted 2009) [#6]

Yes, BlitzMax MiniB3D works the same as Blitz3D - one surface per sprite.

In iMiniB3D (iPhone version), I've added a batching system to improve sprite performance, but I've yet to add this to the BlitzMax version.