Trouble picking modified mesh

BlitzMax Forums/MiniB3D Module/Trouble picking modified mesh

TomToad

(Posted 2013) [#1]

Seems that when I use EntityPickMode Entity,2 and then pick a polygon that has been moved by modifying a mesh, PickedX(),PickedY(), and PickedZ() report the old position of the polygon instead of the new position.

Try out the example here, Press the spacebar to print the value of PickedZ() on the entity. It will print -4.0000 as expected. Press 'M' to modify the mesh by moving the Z component of all the vertices to -2. You can see that the quad moves by lining up with the blue spheres. Now press space again. You would expect the Z component to now be -2, but instead it is still -4. The example here doesn't show it, but the bug affects proper collisions as well.

SuperStrict
Import sidesign.minib3d

Graphics3D 800,600

'create the quad and give it EntityPickMode of 2 (polygon)
Local Quad:TEntity = CreateMesh()
Local Surface:TSurface = CreateSurface(TMesh(Quad))

Local v0:Int = Surface.AddVertex(-4,4,-4)
Local v1:Int = Surface.AddVertex(4,4,-4)
Local v2:Int = Surface.AddVertex(-4,-4,-4)
Local v3:Int = Surface.AddVertex(4,-4,-4)

Surface.AddTriangle(v0,v1,v2)
Surface.AddTriangle(v1,v3,v2)

UpdateNormals(TMesh(Quad))

EntityPickMode Quad,2

'These 8 spheres mark the corners of the quad.  green for the original position and blue for the new position
Local GreenSphere1:TEntity = CreateSphere()
ScaleEntity GreenSphere1,.25,.25,.25
EntityColor GreenSphere1,0,255,0
PositionEntity GreenSphere1,-4,-4,-4
Local GreenSphere2:TEntity = CopyEntity(GreenSphere1)
PositionEntity GreenSphere2,4,-4,-4
Local GreenSphere3:TEntity = CopyEntity(GreenSphere1)
PositionEntity GreenSphere3,-4,4,-4
Local GreenSphere4:TEntity = CopyEntity(GreenSphere1)
PositionEntity GreenSphere4,4,4,-4
Local BlueSphere1:TEntity = CreateSphere()
ScaleEntity BlueSphere1,.25,.25,.25
EntityColor BlueSphere1,0,0,255
PositionEntity BlueSphere1,-4,-4,-2
Local BlueSphere2:TEntity = CopyEntity(BlueSphere1)
PositionEntity BlueSphere2,4,-4,-2
Local BlueSphere3:TEntity = CopyEntity(BlueSphere1)
PositionEntity BlueSphere3,-4,4,-2
Local BlueSphere4:TEntity = CopyEntity(BlueSphere1)
PositionEntity BlueSphere4,4,4,-2

Local Camera:TCamera = CreateCamera()
PositionEntity Camera,0,0,-12
CreateLight()

While Not KeyHit(KEY_ESCAPE)
	UpdateWorld()
	RenderWorld()
	BeginMax2d()
		SetColor 255,0,0
		DrawLine 390,300,410,300
		DrawLine 400,290,400,310
	EndMax2d()
	Flip()
	If KeyHit(KEY_SPACE) 'space to do a camera pick and print the z coordinates of the polygon
		Local Entity:TEntity = CameraPick(Camera,400,300)
		If Entity
			Print PickedZ()
		End If
	End If
	If KeyHit(KEY_M) 'm to move the quad to the new position
		Surface.VertexCoords(v0,-4,4,-2)
		Surface.VertexCoords(v1,4,4,-2)
		Surface.VertexCoords(v2,-4,-4,-2)
		Surface.VertexCoords(v3,4,-4,-2)
	End If
Wend

ETA: Just tried the sample in Blitz3D and it works as expected. Definitely a bug in MiniB3D.

TomToad

(Posted 2013) [#2]

I found a workaround. If I add TMesh(Quad).col_tree.reset_col_tree = True after modifying the mesh, it will work.

Should be added to the TSurface AddVertex() and Vertexcoords() methods.