TextArea underline style and colour

BlitzMax Forums/MaxGUI Module/TextArea underline style and colour

col	(Posted 2012) [#1]

Hiya all,

Sorry but this is Windows only. For Mac and Linux versions feel free to add the necessary code to support it.

The TextArea underlining in the standard MaxGUI is rather limited with the style of underline and the colour so I made a simple little function to change the underline style and colour.

Feel free to use and abuse.

You can have a normal, wavy or dotted underline style and red,blue or green colours. It's easy to expand and add more styles and colours if you wanted to.

EDIT:- Edited for Windows8 compatibility

Strict

Import MaxGUI.Drivers

Extern"Win32"
	Function GetVersionEx(lpVersionInfo:Byte Ptr) = "GetVersionExW@4"
EndExtern

Global OSVersionInfoEx[71]
OSVersionInfoEx[0] = SizeOf(OsVersionInfoEx)
GetVersionEx(OSVersionInfoEx)

Global OS_WIN8 = ( OSVersionInfoEx[1] = 6 ) And ( OSVersionInfoEx[2] = 2 )

Global TEXTAREA_UNDERLINE_RED = $05 + OS_WIN8
Global TEXTAREA_UNDERLINE_BLUE = $01 + OS_WIN8
Global TEXTAREA_UNDERLINE_GREEN = $03 + OS_WIN8

Global TEXTAREA_UNDERLINE_NONE = $0
Global TEXTAREA_UNDERLINE_NORMAL = $01
Global TEXTAREA_UNDERLINE_DOTTED = $04
Global TEXTAREA_UNDERLINE_WAVY = $08

Global TEXTAREA_UNDERLINE_ERROR = (TEXTAREA_UNDERLINE_RED Shl 8) | TEXTAREA_UNDERLINE_WAVY
Global TEXTAREA_UNDERLINE_BADGRAMMAR = (TEXTAREA_UNDERLINE_GREEN Shl 8) | TEXTAREA_UNDERLINE_WAVY
Global TEXTAREA_UNDERLINE_BADSYNTAX = (TEXTAREA_UNDERLINE_BLUE Shl 8) | TEXTAREA_UNDERLINE_WAVY

Function UnderlineTextAreaText(TextArea:TGadget,Style,Pos=0,Length=0)
?Win32
	Local iirange:ITextRange
	Local iifont:ITextFont
	TWindowsTextArea(TextArea).idoc.Range(pos,pos+length,iirange)
	iirange.GetFont(iiFont)
	iiFont.SetUnderline(Style)
		
	iifont.release_()
	iirange.release_()
?
EndFunction



' Example
Global Window:TGadget = CreateWindow("Underline Example",0,0,400,400,Null,WINDOW_DEFAULT|WINDOW_CENTER)
Global TextArea:TGadget = CreateTextArea(0,0,ClientWidth(Window),ClientHeight(Window),Window,TEXTAREA_READONLY)

AddTextAreaText(TextArea,"This could be an ERROR notification~nOr use green for a bad grammar or maybe blue for a syntax error")

'Use STRING.Find as an example
Local Error$ = "ERROR"
Local ABadGrammar$ = "a bad grammar"
Local SyntaxError$ = "syntax error"
UnderLineTextAreaText(TextArea,TEXTAREA_UNDERLINE_ERROR,GadgetText(TextArea).Find(Error),Error.Length)
UnderLineTextAreaText(TextArea,TEXTAREA_UNDERLINE_BADGRAMMAR,GadgetText(TextArea).Find(ABadGrammar),ABadGrammar.Length)
UnderLineTextAreaText(TextArea,TEXTAREA_UNDERLINE_BADSYNTAX,GadgetText(TextArea).Find(SyntaxError),SyntaxError.Length)

Repeat
	WaitEvent()
	
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	EndSelect
Forever

Last edited 2012