TreeView bold text

BlitzMax Forums/MaxGUI Module/TreeView bold text

col	(Posted 2012) [#1]

Windows only -

I'm not sure if anyone will find this useful or not but I found a use for it so thought I'd share it.

You can set a TreeViewNode text to a bold style and retrieve its bold style status with these 2 functions :-

SetTreeViewNodeBoldText(TreeNode:TGadget,Flag) Change the Flag parameter to True or False as wanted
TreeViewNodeBoldText(TreeNode:TGadget) The return value will be True or False accordingly

Strict

Import MaxGUI.Win32MaxGUIEx
Import MaxGUI.XPManifest

Global Window:TGadget = CreateWindow("TreeView bold text",0,0,300,200,,WINDOW_TITLEBAR |WINDOW_CENTER|WINDOW_TOOL)
Global TreeView:TGadget = CreateTreeView(0,0,ClientWidth(Window),ClientHeight(Window)-25,Window)
Global ToggleButton:TGadget = CreateButton("Toggle BOLD",0,ClientHeight(Window)-25,ClientWidth(Window),25,Window)
Global Something:TGadget = AddTreeViewNode("Something",TreeViewRoot(TreeView))
AddTreeViewNode("Random text",Something)
AddTreeViewNode("More random text",Something)
AddTreeViewNode("And some more",Something)
 
ExpandTreeViewNode(Something)

Repeat
	WaitEvent()

	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
		
		Case EVENT_GADGETACTION
			If EventSource() = ToggleButton
				Local Bold = TreeViewNodeBoldText(SelectedTreeViewNode(TreeView))
				SetTreeViewNodeBoldText(SelectedTreeViewNode(TreeView),1-Bold)
			EndIf
	
	EndSelect
Forever

'Sets/Unsets a TreeViewNode text to bold
Function SetTreeViewNodeBoldText(TreeNode:TGadget,Flag)
	If Not TreeNode Or Not TWindowsTreeNode(TreeNode) Return

	Local Item[10]
	Item[0] = TVIF_STATE
	Item[1] = TWindowsTreeNode(TreeNode)._item
	Item[2] = (TVIS_BOLD*Flag)
	Item[3] = TVIS_BOLD
	SendMessageW(TWindowsTreeNode(TreeNode)._tree,TVM_SETITEMW,0,Int Byte Ptr(Item))
EndFunction

'Gets a TreeViewNode text bold status
Function TreeViewNodeBoldText(TreeNode:TGadget)
	If Not TreeNode Or Not TWindowsTreeNode(TreeNode) Return

	Local Item[10]
	Item[0] = TVIF_STATE
	Item[1] = TWindowsTreeNode(TreeNode)._item
	Item[3] = TVIS_BOLD
	SendMessageW(TWindowsTreeNode(TreeNode)._tree,TVM_GETITEMW,0,Int Byte Ptr(Item))
	Return (Item[2]&TVIS_BOLD)=TVIS_BOLD
EndFunction

Last edited 2012