Enable\Disable Multiselect Listbox

BlitzMax Forums/MaxGUI Module/Enable\Disable Multiselect Listbox

BLaBZ

(Posted 2012) [#1]

Is it possible to Enable\Disable Multiselect Listbox?

Thanks

col	(Posted 2012) [#2]

Hiya,

You can use LISTBOX_MULTISELECT in the flag parameter in the CreateListBox([...]) function, then use SelectedGadgetItems to get an array of the currently selected indices.

Henri

(Posted 2012) [#3]

Is it possible to do the same with treeview ?

-Henri

jsp	(Posted 2012) [#4]

Is it possible to Enable\Disable Multiselect Listbox?

If you need only one selection, you could remember the last selection and deselect it by code when a new selection has been detected. Thus one item is the maximum.

Is it possible to do the same with treeview ?

There is no MaxGUI command for it, but it can be done via an icon in front of the nodes.
If selected show a certain meaningful icon for that node. Remember internally with a flag the state. Do so for all selected treeview nodes and you have a multiselect treeview.

Henri

(Posted 2012) [#5]

Can you perhaps provide an example of this ?

-Henri

jsp	(Posted 2012) [#6]

Here is an example you may can adapt for your use:
Please load your own icons at LoadPixmap( "CheckMarks.png" ) before running.

SuperStrict

Import MaxGui.Drivers

Global	TreeView1:TGadget
Global	TextArea1:TGadget

Local Window1:TGadget = CreateWindow("Window1",488,243,501,210,Null,WINDOW_TITLEBAR|WINDOW_RESIZABLE |WINDOW_STATUS |WINDOW_CLIENTCOORDS )
	Local btnAddItem:TGadget = CreateButton("Add Item",194,20,75,23,Window1,BUTTON_PUSH)
	Local btnQuit:TGadget = CreateButton("Quit",194,178,75,23,Window1,BUTTON_PUSH)
	TreeView1 = CreateTreeView(9,10,175,191,Window1,Null)
		Local TreeView1_Icons:TPixmap = LoadPixmap( "CheckMarks.png" )
		Local TreeView1_Strip:TIconStrip = LoadIconStrip( TreeView1_Icons )
		SetGadgetIconStrip( TreeView1 , TreeView1_Strip )
		AddTreeViewNode( "Item1",TreeViewRoot(TreeView1) )
		AddTreeViewNode( "Item2",TreeViewRoot(TreeView1) )
		AddTreeViewNode( "Item3",TreeViewRoot(TreeView1) )
	Local btnShow:TGadget = CreateButton("> Show >",194,97,75,23,Window1,BUTTON_PUSH)
	TextArea1 = CreateTextArea(281,10,212,191,Window1,Null)
		SetTextAreaText( TextArea1 , "" )

Repeat
	WaitEvent()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			Select EventSource()
				Case Window1	Window1_WC( Window1 )
			End Select

		Case EVENT_GADGETACTION
			Select EventSource()
				Case btnAddItem	btnAddItem_GA( btnAddItem )
				Case btnQuit	btnQuit_GA( btnQuit )
				Case TreeView1	TreeView1_GA( TreeView1, EventExtra() )
				Case btnShow	btnShow_GA( btnShow )
			End Select

		Case EVENT_GADGETSELECT
			Select EventSource()
				Case TreeView1	TreeView1_GS( TreeView1, EventExtra() )
			End Select

	End Select
Forever

Function Window1_WC( Window:TGadget )
	DebugLog "Window Window1 wants to be closed"
	End
End Function

Function btnAddItem_GA( Button:TGadget )
	DebugLog "Button btnAddItem was pressed"
	Global Counter:Int 
	
	Counter:+1
	Local SelectedGadget:TGadget = SelectedTreeViewNode( Treeview1 )
	AddTreeViewNode( "Node"+Counter,SelectedGadget, 0, "NotSelected" )
	ExpandTreeViewNode( SelectedGadget )
End Function

Function btnQuit_GA( Button:TGadget )
	DebugLog "Button btnQuit was pressed"
	End
End Function

Function TreeView1_GA( TreeView:TGadget , Node:Object )
	DebugLog "TreeView TreeView1 double clicked a Node"
	Local SelectedGadget:TGadget = TGadget( Node )
	Local Extra:Object = GadgetExtra( SelectedGadget )
	Local TextFlag:String = String( Extra )
	
	If Extra="Selected" Then
		SetGadgetExtra( SelectedGadget, "NotSelected" )
		ModifyTreeViewNode( SelectedGadget, GadgetText( SelectedGadget), 0 )
	Else
		SetGadgetExtra( SelectedGadget, "Selected" )
		ModifyTreeViewNode( SelectedGadget, GadgetText( SelectedGadget), 1 )
	End If
End Function

Function btnShow_GA( Button:TGadget )
	DebugLog "Button btnShow was pressed"
	SetGadgetText( TextArea1, "" )
	ShowSelectedNodes( TreeViewRoot( Treeview1 ) )
	
	Function ShowSelectedNodes( Node:TGadget )
		For Local i:TGadget = EachIn Node.Kids
			If String(GadgetExtra(i)) = "Selected" Then AddTextAreaText( TextArea1, i.GetText()+"~n" )
			If i.Kids Then ShowSelectedNodes( i )
		Next
	End Function
End Function

Function TreeView1_GS( TreeView:TGadget , Node:Object )
	DebugLog "TreeView TreeView1 single clicked a Node"
	Local SelectedGadget:TGadget = TGadget( Node )
	Local Extra:Object = GadgetExtra( SelectedGadget )
	Local TextFlag:String = String( Extra )
	
	If Extra="Selected" Then
		SetGadgetExtra( SelectedGadget, "NotSelected" )
		ModifyTreeViewNode( SelectedGadget, GadgetText( SelectedGadget), 0 )
	Else
		SetGadgetExtra( SelectedGadget, "Selected" )
		ModifyTreeViewNode( SelectedGadget, GadgetText( SelectedGadget), 1 )
	End If
End Function

Henri

(Posted 2012) [#7]

Thank you for your very nice example. Now all I have to do is figure out how select multiple nodes at the same time.

-Henri

jsp	(Posted 2012) [#8]

That should be doable. Maybe with shift click and then calculate start and stop item and select all in between.