Store tons of small pixmaps in ram for later use?

BlitzMax Forums/MaxGUI Module/Store tons of small pixmaps in ram for later use?

Grisu

(Posted 2011) [#1]

Hi!

I'm looking for a decent way to store lots of pixmaps into ram so I don't need to access the hdd when they are drawn on a panel.

1. Currently, I extract the image data from a zip to a TRamStream:
-> logo:TRamstream=zrObject.ExtractFile("station_ico.png",False)
(I could transform the data into pixmaps directly but this will raise memory usage by far too much.)

2. When the image is needed I put it on a panel via:
-> SetGadgetPixmap(Canvas,LoadPixmap(logo),PANELPIXMAP_STRETCH)

The issue I have is that image is not displayed on the panel the second time the same pixmap is called?

I might be missing something. - Any alternatives welcome.

Grisu

skn3	(Posted 2011) [#2]

What if you had a cache and disk combo... So set a limit for number of images that can be loaded in ram... and then keep the rest on disk. So the most popular/used ones will remain in cache and the unused ones are loaded on demand.

Apart from that I'm not sure why your method wouldn't work???

Grisu

(Posted 2011) [#3]

It should, but it doesn't! - I did code a simple example last night. You need GMan's Zip module for this and the included test.zip. See download link at bottom.

Code:

SuperStrict 
Import MaxGui.Drivers
Import Brl.Pixmap  
Import Brl.Pngloader
Import Gman.Zipengine

Const MAINWINDOW_W:Int = 278 
Const MAINWINDOW_H:Int = 154
Global window:TGadget=CreateWindow("My Canvas BUG EXAMPLE",30,20,MAINWINDOW_W,MAINWINDOW_H+100,Null,WINDOW_TITLEBAR|WINDOW_CENTER)
Global Button1:TGadget=CreateButton("Get Logo from RAM",2,MAINWINDOW_H+2,MAINWINDOW_W-6,20,window,BUTTON_OK)
Global Button2:TGadget=CreateButton("Get Logo from Pixmap",2,MAINWINDOW_H+2+20,MAINWINDOW_W-6,20,window,BUTTON_OK)
Global Label:TGadget=CreateLabel("Press Butt1, Press Butt2 and Press Butt1 again....                    => No Logo!",2,MAINWINDOW_H+2+40,MAINWINDOW_W-3,32,window,BUTTON_OK)


Global RadioStationCanvas:TGadget = CreatePanel(2, 2, 274, 87, window, PANEL_ACTIVE) '110
Global station_logo:TPixmap 
Global _Logo:TRamStream
Global _logo2:TPixmap
Global fullzipdir:String="_test.prp"  

Load_Logo_to_RAM()

While WaitEvent()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
		Case EVENT_GADGETACTION
   	 	      Select EventSource() 
                 Case BUTTON1
			          Add_Logo_From_RAM()
                 Case BUTTON2
			          Add_Logo
                 End Select 
	End Select
Wend


Function Load_Logo_to_RAM()
    Local zrObject:ZipReader = New ZipReader  
	If ( zrObject.OpenZip(fullzipdir) ) Then
       _logo:TRamstream=zrObject.ExtractFile("station_ico.png",False)
       _Logo2:TPixmap=LoadPixmap(zrObject.ExtractFile("station_ico.png",False))
       DebugLog "logo loaded into RAM"  
       Print "logo loaded into RAM"  
 	   zrObject.CloseZip()
	End If
End Function

Function Add_Logo_From_RAM()
	SetGadgetPixmap(RadioStationCanvas, Null)
	SetGadgetPixmap(RadioStationCanvas, LoadPixmap(_logo), PANELPIXMAP_FIT)
End Function 

Function Add_Logo()
SetGadgetPixmap(RadioStationCanvas, Null)
	SetGadgetPixmap(RadioStationCanvas, _logo2, PANELPIXMAP_FIT)
End Function

Example source with test zip.file:
-

The second time one tries to put the data from RAM to the panel, it fails. Each time!

OS: Win7 64 Bit

Last edited 2011

jsp	(Posted 2011) [#4]

Hi,
you forgot to reset the pointer of the RamStream.

Function Add_Logo_From_RAM()
	SetGadgetPixmap(RadioStationCanvas, Null)
	_logo.seek 0
	If _logo Print "logo" Else Print "Nothing"
	SetGadgetPixmap(RadioStationCanvas, LoadPixmap(_logo), PANELPIXMAP_FIT)
End Function

Grisu

(Posted 2011) [#5]

Didn't know one had to do this. Blame the docs! ;)

With this issue solved the next version of PRP isn't too far away

skn3	(Posted 2011) [#6]

ohhhhhhhhhhhhhhhhhhhhhh *slaps head* :D