get label text width/height

BlitzMax Forums/MaxGUI Module/get label text width/height

skn3	(Posted 2011) [#1]

[updated 10/11/2011]
I have made a small piece of code to allow exact sizing of gadgets based on the string dimensions. For example if you needed to figure out the proper dimensions for a label gadget width and height then the code below would let you determine what dimensions you should use.

Here is a screenshot of it working in the app Objecty I am writing ( http://www.skn3.com/apps/objecty ). The two label gadgets you see are dynamically created. You will notice that the labels/gadgets are all neatly centred in the dialogue window. HOORAH!

Just to point out, the function does not return the exact size of just the text. It will return the size it thinks the gadget itself should be.

[update - 10/11/2011]
Fixed issue jsp reported that the dimensions produced were a bit funky on his copy of winxp. This is resolved, and have also added in a special case dimension checking for buttons (windows only). It should take into account the buttons picture as well.

Here is the code you will need:
mods/skn3.mod/gadgetstringdimensions.mod/gadgetstringdimensions.bmx

Module skn3.gadgetstringdimensions

SuperStrict

Import maxgui.drivers

'do platform speciffic imports and constants
?Win32
Const BCM_GETIDEALSIZE:Int = BCM_FIRST + 1
?MacOs
Import "gadgetstringdimensions.m"
Extern "macos"
	Function skn3_stringDimensions:Int[](gadget:Int,text:String,Width:Float)
EndExtern
?

Function GadgetSizeForString:Int[](gadget:TGadget,text:String,maxWidth:Int=0)
	' --- get dimensions of a string using the gadget as a context ---
	?Win32
		'get device context to the gadget
		Local hwnd:Int = QueryGadget(gadget,QUERY_HWND)
				
		'do stuff based on gadget class
		Select GadgetClass(gadget)
			Case GADGET_BUTTON
				'button, we can use the windows ideal button size message which incorporates images as well!
				Local size:Int[] = [maxWidth,0]
				
				'disable redraw on gadget
				SendMessageW(hwnd,WM_SETREDRAW,False,0)
				
				'change text of gadget
				Local oldText:String = GadgetText(gadget)
				SetGadgetText(gadget,text)
				
				'test for ideal size
				SendMessageW(hwnd,BCM_GETIDEALSIZE,0,Int Byte Ptr(size))
				
				'restore teh gadget
				SetGadgetText(gadget,text)
				SendMessageW(hwnd,WM_SETREDRAW,True,0)
				
				'return the result
				Return size
			Default
				'default action is to use teh DrawText operation to figure out size
				Local dc :Int = GetDC(hwnd)
				
				'get and set font used by the control
				Local font:Int = SendMessageW(hwnd,WM_GETFONT,0,0)
				SelectObject(dc,font)
				
				'get the client rect (doing this just because its worth it)
				Local rect:Int[] = [0,0,maxWidth,0]
				'text rect flags
				Local flags:Int = DT_CALCRECT | DT_NOCLIP
				If maxWidth > 0 flags :| DT_WORDBREAK
				
				'calculate the bounding
				DrawTextW(dc,text,-1,rect,flags)
				
				'release device context
				ReleaseDC(hwnd,dc)
				
				'return the result
				Return [rect[2],rect[3]]
		End Select
		
	?MacOs
		Local result:Int[] = skn3_stringDimensions(QueryGadget(gadget,QUERY_NSVIEW_CLIENT),text,maxWidth)
		Return result
	?
End Function

mods/skn3.mod/gadgetstringdimensions.mod/gadgetstringdimensions.h (mac)

BBArray * skn3_stringDimensions(NSView *gadget,BBString *theText,float maxWidth);

mods/skn3.mod/gadgetstringdimensions.mod/gadgetstringdimensions.m (mac)

#include <pub.mod/macos.mod/macos.h>
#include "gadgetstringdimensions.h"

BBArray * skn3_stringDimensions(NSView *gadget,BBString *theText,float maxWidth) {
	NSDictionary *textAttributes = [NSDictionary dictionaryWithObjectsAndKeys:[NSColor whiteColor], NSForegroundColorAttributeName,[gadget font], NSFontAttributeName,nil];
	
	// Setup size constraint. A 0.0 means: no constraint.
	NSSize maxSize = NSMakeSize(maxWidth, 0.0);
	
	// NSStringDrawingUsesLineFragmentOrigin is the ONLY way to make lines break!
    NSRect rect = [[NSString stringWithCString:bbStringToCString(theText)] boundingRectWithSize:maxSize options:NSStringDrawingUsesLineFragmentOrigin | NSStringDrawingDisableScreenFontSubstitution attributes:textAttributes];
    
	//now return it...
	BBArray *result = bbArrayNew1D("i",2);
	int *p = (int*)BBARRAYDATA(result,1);
	p[0] = (int)rect.size.width;
	p[1] = (int)rect.size.height;
	return result;
}

Here is an example of the code working

Import maxgui.drivers
Import skn3.gadgetstringdimensions

Global text:String = "This is a long piece of text that will grow bigger and bigger and push teh button down. Isn't that totally amazing? I think so, now go make some awesome maxgui apps!"
Global textLength:Int = 0

Global Window:TGadget = CreateWindow("Sandbox!",0,0,140,280,Null,WINDOW_CENTER | WINDOW_TITLEBAR)
Global label:TGadget = CreateLabel("",5,5,100,0,Window)
Global button:TGadget = CreateButton("testing below label...",GadgetX(label),GadgetY(label)+GadgetHeight(label),GadgetWidth(label),60,Window)

Global timer:TTimer = CreateTimer(10)

AddHook(EmitEventHook,EventHook,Null,1)
Function EventHook:Object(id:Int,data:Object,context:Object)
	Local event:TEvent = TEvent(data)
	
	'check valid event
	If event
		Select event.id
			Case EVENT_TIMERTICK
				'little effect to reveal the text and dynamically resize/position gadgets
				textLength :+ 1
				If textLength > text.length textLength = 0
				Local sliced:String = text[..textLength]
				Local size:Int[] = GadgetSizeForString(label,sliced,label.ClientWidth())
				SetGadgetShape(label,GadgetX(label),GadgetY(label),GadgetWidth(label),size[1])
				SetGadgetText(label,sliced)
				SetGadgetShape(button,GadgetX(button),GadgetY(label)+GadgetHeight(label),GadgetWidth(button),GadgetHeight(button))
				
			Case EVENT_WINDOWCLOSE
				End
		End Select
	EndIf
	
	'return
	Return data
EndFunction

Repeat
	WaitEvent()
Forever

Last edited 2011

skn3	(Posted 2011) [#2]

update, see first post

Last edited 2011

shinkiro1

(Posted 2011) [#3]

Hey thanks, that's a feature I often wanted to use. Would be great if it has a mac version too.

skn3	(Posted 2011) [#4]

Having a look at this today for mac. Fingers crossed it goes well!

skn3	(Posted 2011) [#5]

Well I got a mac version running :D (See first post for the files needed)

This was my first blitz -> osx module, an exciting little project.

Last edited 2011

jsp	(Posted 2011) [#6]

Tested this on XP and the space between the Label and the Button is growing the longer the string displayed gets. Somehow the offset seems a bit too big.
Nevertheless this is really useful, didn't know it exist!
Thanks.

skn3	(Posted 2011) [#7]

I'll get XP installed on a vm and fix it tomorrow :D thanks for testing!

skn3	(Posted 2011) [#8]

Hey jsp, I got xp installed today (thanks btw I had been meaning to do it) and tested the example from the first post. I wasn't able to get any size issues with the label gadget. They seemed to fit the exact size in normal and xpmanifest modes!

Is there anything special with your xp installation? Would it be possible to take a screenshot? Thanks

jsp	(Posted 2011) [#9]

See below what I mean. The more lines the bigger the distance between the label and the button.
It looks a bit like a wrong fontsize calculation, but I saw you retrieve the font from the control. Not sure what goes wrong here.
My XP is quite standard, but is running in a VMWare to be more flexible, never had a problem with that. The biggest difference is that it uses GL instead of DX, but that should have no effect for the GUI.

skn3	(Posted 2011) [#10]

Hey Jsp,

Thats really weird. I tried again on my XP (also running on vmware) and it doesn't exhibit the same behaviour.

Could you try this new version for me please?
Changed:
- I renamed the function as it didnt really make sense.
- I added in more code for correctly determining button dimensions (including images) in windows.
- I added a DT_NOCLIP flag to the text calc for "other" gadgets
- I changed the hwnd to be QUERY_HWND instead of QUERY_HWND_CLIENT

Const BCM_GETIDEALSIZE:Int = BCM_FIRST + 1

Function GadgetSizeForString:Int[](gadget:TGadget,text:String,maxWidth:Int=0)
	' --- get dimensions of a string using the gadget as a context ---
	?Win32
		'get device context to the gadget
		Local hwnd:Int = QueryGadget(gadget,QUERY_HWND)
				
		'do stuff based on gadget class
		Select GadgetClass(gadget)
			Case GADGET_BUTTON
				'button, we can use the windows ideal button size message which incorporates images as well!
				Local size:Int[] = [maxWidth,0]
				
				'disable redraw on gadget
				SendMessageW(hwnd,WM_SETREDRAW,False,0)
				
				'change text of gadget
				Local oldText:String = GadgetText(gadget)
				SetGadgetText(gadget,text)
				
				'test for ideal size
				SendMessageW(hwnd,BCM_GETIDEALSIZE,0,Int Byte Ptr(size))
				
				'restore teh gadget
				SetGadgetText(gadget,text)
				SendMessageW(hwnd,WM_SETREDRAW,True,0)
				
				'return the result
				Return size
			Default
				'default action is to use teh DrawText operation to figure out size
				Local dc :Int = GetDC(hwnd)
				
				'get and set font used by the control
				Local font:Int = SendMessageW(hwnd,WM_GETFONT,0,0)
				SelectObject(dc,font)
				
				'get the client rect (doing this just because its worth it)
				Local rect:Int[] = [0,0,maxWidth,0]
				'text rect flags
				Local flags:Int = DT_CALCRECT | DT_NOCLIP
				If maxWidth > 0 flags :| DT_WORDBREAK
				
				'calculate the bounding
				DrawTextW(dc,text,-1,rect,flags)
				
				'release device context
				ReleaseDC(hwnd,dc)
				
				'return the result
				Return [rect[2],rect[3]]
		End Select
		
	?MacOs
		Local result:Int[] = skn3_stringDimensions(QueryGadget(gadget,QUERY_NSVIEW_CLIENT),text,maxWidth)
		Return result
	?
End Function

Last edited 2011

jsp	(Posted 2011) [#11]

Cool, that did the trick, works perfect now!
Thanks

skn3	(Posted 2011) [#12]

W00t! thanks for the help in testing. I have now updated the topic.