Tweak for slider/scrollbar step amount for arrows

BlitzMax Forums/MaxGUI Module/Tweak for slider/scrollbar step amount for arrows

skn3	(Posted 2011) [#1]

Ok well a long standing "bug" of maxgui has been the 1 pixel/unit scrolling for sliders when pressing the arrow buttons. I have made a tweak to allow the user to specify how much the scrollbar/slider should scroll when arrows are pressed:

Maxgui
maxgui.bmx
Around line 2310 add a new function:

Rem
bbdoc: Set the range step of a slider
about: For the default SLIDER_SCROLLBAR style the step is the amount added when the user clicks the arrow buttons. By default this is 1.

See Also: #CreateSlider, #SliderValue and #SetSliderValue
EndRem
Function SetSliderStep( slider:TGadget,amount:Int )
	slider.SetStep(amount)
End Function

gadget.bmx
Around line 189 add a new field "stepAmount=1":

' slider vars
	Field	visible,total=1,stepAmount=1

gadget.bmx
Around line 773 add a new method to TGadget class:

Method SetStep(amount:Int)
End Method

gadget.bmx
Around line 1018 add a new method to TProxyGadget class:

Method SetStep(amount:Int)
	Return proxy.SetStep(amount)
End Method

windows
win32maxguiex.bmx
Around line 4144 add a new method to the TWindowsSlider class

Method SetStep(amount:Int)
	stepAmount = amount
	If stepAmount < 1 stepAmount = 1
End Method

win32maxguiex.bmx
Around line 4200 change the Case SB_LINEUP and Case SB_LINEDOWN code to:

Case SB_LINEUP
	If stepAmount = 1
		Pos:-stepAmount
	Else
		Pos = ((Pos / stepAmount)-1) * stepAmount
	EndIf
	
Case SB_LINEDOWN
	If stepAmount = 1
		Pos:+stepAmount
	Else
		Pos = ((Pos / stepAmount)+1) * stepAmount
	EndIf

mac osx
cocoagui.bmx
Around line 888 add a new method:

Method SetStep(amount)
	stepAmount = amount
	If stepAmount < 1 stepAmount = 1
End Method

cocoagui.bmx
Around line 304 add a new ElseIf condition so it looks like:

Select (gadget.style&(SLIDER_SCROLLBAR|SLIDER_TRACKBAR|SLIDER_STEPPER))
	Case SLIDER_SCROLLBAR
		If data > 1 Then
			data = gadget.small
		ElseIf data < -1 Then
			data = -gadget.small
		ElseIf stepAmount > -1 And data = -1 Or data = 1
			data = (((oldValue / stepAmount)+data) * stepAmount) - oldValue
		EndIf
EndSelect

linux
fltkgui.bmx
Around line 2195 add a new method:

Method SetStep(amount:Int)
	stepAmount = amount
	If stepAmount < 1 stepAmount = 1
End Method

fltkgui.bmx
Around line 2221 in the OnSpin method change it so the Select pSource is like:

Select pSource
	Case up
		If (Style&SLIDER_SCROLLBAR) = SLIDER_SCROLLBAR And stepAmount > 1
			tmpNewVal = ((tmpNewVal / stepAmount)+1) * stepAmount
		Else
			tmpNewVal:+1
		EndIf
	Case down
		If (Style&SLIDER_SCROLLBAR) = SLIDER_SCROLLBAR And stepAmount > 1
			tmpNewVal = ((tmpNewVal / stepAmount)-1) * stepAmount
		Else
			tmpNewVal:-1
		EndIf
EndSelect

PHEW! that was a mission ... the macos and linux versions are untested but they should be correct...

Last edited 2011

Last edited 2011

Last edited 2011

Last edited 2011

Last edited 2011