Using a text area gadget to create a simple editor

BlitzMax Forums/MaxGUI Module/Using a text area gadget to create a simple editor

TomToad

(Posted 2010) [#1]

I am trying to create a simple code editor using a text area gadget. I don't need many features, but two I would like to have are syntax highlighting and auto indenting.

For syntax highlighting, I figured I could just get the current line being edited and parse it, then format the line according to the code there.

But I'm having problems with the auto indenting. I figured I could just detect when the enter key is pressed and check the previous line for tab characters, then insert that many into the current line. Unfortunately, it seems the text area gadget won't pass EVENT_KEYDOWN or EVENT_KEYUP events.

Any ideas how I can accomplish this? I tried looking at the MaxIDE code, but I am clueless how things are set up there.

BLaBZ

(Posted 2010) [#2]

I believe you need to SetGadgetFilter

TomToad

(Posted 2010) [#3]

Thanks BLaBZ, that seems to do what I want.

Another question, after inserting the tabs, the cursor remains at the spot before the tabs. How can I move the cursor so it is after the tabs? I cant see any SetAreaTextCursor command.

TomToad

(Posted 2010) [#4]

Seems that making a simple editor is not so simple after all. Here is what I have so far. Only the keyword "print" is highlighted at the moment, but it works.
Unfortunately, I cannot get auto-indenting to work. I tried using TextAreaText() to get the text, insert the tabs, then using SetTextAreaText() to write the text back. The tabs were inserted, but the cursor was not updated, and it messed up the formatting.
I then tried EmitEvent() to emit a fake keypress, but it seems to not work either.
Anyone have any idea how I can insert tabs before the cursor or fake the keypresses, and not mess up the formatting?

current code:

SuperStrict
Import maxgui.drivers

Global MainWindow:TGadget = CreateWindow("Minimal Editor",10,10,640,480)
Global EditWindow:TGadget = CreateTextArea(0,0,ClientWidth(MainWindow),ClientHeight(MainWindow),MainWindow)
SetGadgetFilter(EditWindow,EditFilter)

Global EnterKeyPressed:Int = False 'Set when the enter key is pressed
Global CheckTabs:Int = False

AddHook EmitEventHook,Hook

'main loop
Repeat
	WaitEvent() 'wait for and process events
	If Checktabs 'we need to check the previous line for tabs
		Local Line:Int = TextAreaCursor(EditWindow,TEXTAREA_LINES) 'The line the cursor is on
		Local Text:String = TextAreaText(EditWindow,Line-1,1,TEXTAREA_LINES) 'copy the previous line
		Local Index:Int = 0 'point Index to the beginning of the line
		While Text[Index] = Asc("~t") 'If character is a tab then add one to current line
			DebugLog "Tab "+Index
			Index :+ 1 'Increase the index
			EmitEvent(CreateEvent(EVENT_KEYDOWN,MainWindow,KEY_TAB)) 'trying to fake a keypress
			EmitEvent(CreateEvent(EVENT_KEYUP,MainWindow,KEY_TAB)) 'but it doesn't work
		Wend
		CheckTabs = False 'clear the flag
	End If
Forever

Function Hook:Object(id:Int,data:Object,Context:Object)
	Local Event:TEvent = TEvent(data)
	
	Select Event.id
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE 'close program
			End
		Case EVENT_GADGETACTION
			Select Event.Source
				Case EditWindow 'Something has been altered in the text area
					Local Line:Int = TextAreaCursor(EditWindow,TEXTAREA_LINES) 'Find the current line
					If EnterKeyPressed 'if the enter key was pressed, we will want to parse the previous line
						Line :- 1
						EnterKeyPressed = False
					End If
					Local Character:Int = TextAreaChar(EditWindow,Line) 'The character position of this line
					Local Text:String = TextAreaText(EditWindow,Line,1,TEXTAREA_LINES)' copy text
					Local Index:Int = 0 'point the Index to the beginning of the line
					Local Low:Int, High:Int 'Will point to the current 'word' being checked
					While Index < Text.Length - 1 'Loop to the end
						Low:Int = Index
						High:Int = Low
						While High < text.Length - 1 And Text[High] <> Asc(" ") And Text[High] <> Asc("~n")
							High :+ 1
						Wend
						If Text[Low..High+1].ToLower() = "print " Or Text[Low..High+1].ToLower() = "print~n"
							FormatTextAreaText(EditWindow,255,0,0,0,Character+Low,High-Low) 'format the text being parsed
						End If
						Index = High+1
					Wend
			End Select
	End Select
	Return data
End Function

'Checks for the enter key to be pressed and sets flags if it is.
Function EditFilter:Int(Event:TEvent,context:Object)
	Select Event.id
		Case EVENT_KEYDOWN
			If Event.Data = KEY_ENTER
				EnterKeyPressed = True
				Checktabs = True
			End If
	End Select
	Return True
End Function

Dabhand

(Posted 2010) [#5]

http://www.blitzmonkeys.com/index.php?topic=4.0

May help!

Dabz