Event woes in custom dialogue

BlitzMax Forums/MaxGUI Module/Event woes in custom dialogue

Ghost Dancer

(Posted 2010) [#1]

I have been trying to make a stand-alone dialog function that works much like the Confirm command but also has a text field to get data from the user.

This is the code for the function:

Function RequestInput$(title$, labelText$, defaultText$ = "", group:TGadget = Null)
	Local closeWindow:Int, text$
	
	Local window:TGadget = CreateWindow("",406,235,294,99,group,WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS |WINDOW_CENTER)
	Local label:TGadget = CreateLabel("",7,12,280,14,window,Null)
	Local textField:TGadget = CreateTextField(7,32,280,18,window,Null)
	Local okBut:TGadget = CreateButton("OK",7,69,75,23,window,BUTTON_OK)
	Local cancelBut:TGadget = CreateButton("Cancel",212,69,75,23,window,BUTTON_CANCEL)
	
	SetGadgetText window, title$
	SetGadgetText label, labelText$
	SetGadgetText textField, defaultText$
	ActivateGadget textField
	
	If group Then DisableGadget group
	
	Repeat
		WaitEvent()
		
		Select EventID()
		Case EVENT_WINDOWCLOSE
			Select EventSource()
			Case window
				closeWindow = True
			End Select

		Case EVENT_GADGETACTION
			Select EventSource()
			Case okBut
				closeWindow = True
				text$ = GadgetText(textField)
			Case cancelBut
				closeWindow = True
			End Select
	
		End Select
	Until closeWindow
	
	If group Then EnableGadget group
	
	FreeGadget window
	
	Return text$
End Function

This works fine when the main program uses a simple event loop, for example:

Import MaxGui.Drivers
Import BRL.EventQueue

Local window:TGadget = CreateWindow("Test", 1, 1, 400, 200, Null, WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS |WINDOW_CENTER)
Local button:TGadget = CreateButton("Click for input dialogue", 10, 10, 140, 20, window)
Local label:TGadget = CreateLabel("Data:", 10, 40, 140, 20, window)

While window
	WaitEvent
	
	Select EventID()
	Case EVENT_WINDOWCLOSE
		Select EventSource()
		Case window
			End
		End Select
	
		Case EVENT_GADGETACTION
			Select EventSource()
			Case button
				SetGadgetText label, "Data: " + RequestInput$("RequestInput Test", "Enter Text:", "Some text", window)
			End Select
	End Select
Wend

However, if the main program uses event hooks to manage the events it hangs the program as in the following example:

Import MaxGui.Drivers
Import BRL.EventQueue

AddHook EmitEventHook, mainhook

Global window:TGadget = CreateWindow("Test", 1, 1, 400, 200, Null, WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS |WINDOW_CENTER)
Global button:TGadget = CreateButton("Click for input dialogue", 10, 10, 140, 20, window)
Global label:TGadget = CreateLabel("Data:", 10, 40, 140, 20, window)

While window
	WaitSystem
Wend

End


Function mainhook:Object(id:Int,data:Object,context:Object)
	Local Event:TEvent = TEvent(data)
	
	Select Event.ID
	Case EVENT_WINDOWCLOSE
		Select Event.Source
		Case window
			End
		End Select
	
		Case EVENT_GADGETACTION
			Select Event.Source
			Case button
				SetGadgetText label, "Data: " + RequestInput$("RequestInput Test", "Enter Text:", "Some text", window)
			End Select
	End Select
End Function

I've been working on this for hours but I can't work out how to solve the problem. I have tried making the RequestInput use hooks as well but that didn't work either (I can post the code if it helps).

Any suggestions how to get this working?

degac

(Posted 2010) [#2]

Hi,
Have you seen this?

On that base I made this 'about gadget' using proxygadgets, and it seems to work very well

Rem
	new about window
	based on Ked works
End Rem

Import maxgui.drivers

' ----------- test
Local window:TGadget=CreateWindow("Dialog",50,50,640,480,Desktop(),1+2)
Local button:TGadget=CreateButton("Dialog",10,10,80,24,window)
Local image:TPixmap=LoadPixmap("C:\BlitzMax133rc5\docs\html\bmax120.png")

Local ab:taboutGadget=About("Hallo world","Hey!~nThis is to remind you that this "+..
					"magnificent piece of work is fantastic and that you should "+..
					"always use it.~n~nThank you for your time.",window,image)

Repeat
	WaitEvent()
	Select EventID()
	
			Case event_gadgetAction
				If EventSource()=button 
					ab=About("Hello world","Hey!~nThis is to remind you that this "+..
					"magnificent piece of work is fantastic and that you should "+..
					"always use it.~n~nThank you for your time.",window)
				End If
				
			
			Case event_windowclose
			Select EventSource()
				Case window
					End
			EndSelect


	End Select
Until False


Function About:taboutgadget(txt$,comment$,windowp:tgadget=Null,image:TPixmap=Null)

	Local na:taboutgadget=New taboutgadget.Create(txt,100,100,300,400,windowp,,comment,image)
	
	Return NA
End Function

Type taboutgadget Extends tproxygadget
	Field _window:tgadget
	Field _button:tgadget
	Field _image:TPixmap
	Field _parent:tgadget
	Field _panel:tgadget
	Field _label:tgadget
	Field _title:tgadget

	
	Global currentAbout:taboutgadget

	Method New()
		Initialize()
	EndMethod
	
	Method Create:taboutgadget(text$,x:Int,y:Int,w:Int,h:Int,group:TGadget=Null,style:Int=0,customtext$="",image:TPixmap=Null)
		
		Local ipos:Int=5
		
		If image ipos=image.height
		
		_window=CreateWindow(text,x,y,w,h,,WINDOW_CENTER|WINDOW_TITLEBAR)
		_button=CreateButton("Ok",w-100,h-60,80,24,_window,button_ok)
		If image
			_panel =CreatePanel(0,0,w,image.height,_window)
			SetGadgetPixmap _panel,image,PANELPIXMAP_STRETCH
		End If
		
		_parent=group

		_title = CreateLabel(text,10,ipos+2,w-26,34,_window)
		SetGadgetFont(_title,LookupGuiFont(GUIFONT_SERIF,24))
		SetGadgetColor _title,255,0,0,False
		_label = CreateLabel(customtext,13,ipos+45,w-26,h-ipos-120,_window)
		SetGadgetFont(_label,LookupGuiFont(GUIFONT_SANSSERIF,10))
		CreateLabel("",0,h-70,w,0,_window,label_separator)
		DisableGadget _parent
		ActivateWindow _window
		CurrentAbout=Self
		
	'	SetGadgetAlpha _window,.8
		
		Return Self
	EndMethod
	
		
	Function Initialize()
		AddHook EmitEventHook, eventHandler, Null, 1
	EndFunction
	
	Function eventHandler:Object( pID%, pData:Object, pContext:Object )
		Local pEvent:TEvent = TEvent(pData)
		
		
		If pEvent 
		
			Select pevent.id
				Case event_windowclose
					If pevent.source=CurrentAbout._window
						FreeGadget CurrentAbout._window
						
						If currentabout.parent 
							EnableGadget currentabout._parent
							ActivateWindow currentAbout._parent
						End If
						
						Return Null
					End If
				Case event_gadgetaction
					If pevent.source=CurrentAbout._button
			
						FreeGadget CurrentAbout._window
						If currentabout._parent 
							EnableGadget currentabout._parent
							ActivateWindow currentAbout._parent
						End If
						
						Return Null
					End If
			End Select
			
		EndIf

		
		Return pData
	EndFunction

End Type

Maybe you can find inspiration to resolve your implementation.

Cheers

JoshK

(Posted 2010) [#3]

You can't make a nice neat self-contained function like that. You have to add an event hook, and detect when the button is closed.

Ghost Dancer

(Posted 2010) [#4]

Thanks, I did do a search but somehow missed that one. The main thing I need to do that differs from those examples is to halt the main program flow whilst my dialog is running, as it is requesting user input partway through an operation (much like how RequestFile works), and the problem I'm getting is related to this.

I already tried a hooked version but it resulted in the same problem. Full code below:

Import MaxGui.Drivers
Import BRL.EventQueue

AddHook EmitEventHook, mainhook

Global window:TGadget = CreateWindow("Test", 1, 1, 400, 200, Null, WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS |WINDOW_CENTER)
Global button:TGadget = CreateButton("Click for input dialog", 10, 10, 140, 20, window)
Global label:TGadget = CreateLabel("Data:", 10, 40, 140, 20, window)

While window
	WaitSystem
Wend

End


Function mainhook:Object(id:Int,data:Object,context:Object)
	Local Event:TEvent = TEvent(data)
	
	Select Event.ID
	Case EVENT_WINDOWCLOSE
		Select Event.Source
		Case window
			End
		End Select
	
		Case EVENT_GADGETACTION
			Select Event.Source
			Case button
				SetGadgetText label, "Data: " + RequestInput$("RequestInput Test", "Enter Text:", "Some text", window)
			End Select
	End Select
End Function



Function RequestInput$(title$, labelText$, defaultText$ = "", group:TGadget = Null)
	Local dialog:TRequestDialog = TRequestDialog.create(title$, labelText$, defaultText$, group)

	If group Then DisableGadget group
	
	Repeat
		WaitSystem
	Until dialog.closeWindow
	
	If group Then EnableGadget group
	
	Local text$ = dialog.text$
	
	FreeGadget dialog.window
	dialog = Null
	
	Return text$
	
End Function


Type TRequestDialog
	Global current:TRequestDialog
	
	Field closeWindow:Int, text$
	
	Field window:TGadget
	Field label:TGadget
	Field textField:TGadget
	Field okBut:TGadget
	Field cancelBut:TGadget
	
	
	Function eventhook:Object(id:Int, data:Object, context:Object)
		Local Event:TEvent = TEvent(data)
		
		If Event Then
			Select Event.ID
			Case EVENT_WINDOWCLOSE
				Select Event.Source
				Case current.window
					current.closeWindow = True
				End Select
		
			Case EVENT_GADGETACTION
				Select Event.Source
				Case current.okBut
					current.closeWindow = True
					current.text$ = GadgetText(current.textField)
				Case current.cancelBut
					current.closeWindow = True
				End Select
		
			End Select
		End If
		
		Return data	
	End Function
	
	
	Function create:TRequestDialog(title$, labelText$, defaultText$, group:TGadget)
		Local dialog:TRequestDialog = New TRequestDialog
		
		dialog.window = CreateWindow("", 406, 235, 294, 99, group, WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS |WINDOW_CENTER)
		dialog.label = CreateLabel("", 7, 12, 280, 14, dialog.window, Null)
		dialog.textField = CreateTextField(7, 32, 280, 18, dialog.window, Null)
		dialog.okBut = CreateButton("OK", 7, 69, 75, 23, dialog.window, BUTTON_OK)
		dialog.cancelBut = CreateButton("Cancel", 212, 69, 75, 23, dialog.window, BUTTON_CANCEL)
		
		SetGadgetText dialog.window, title$
		SetGadgetText dialog.label, labelText$
		SetGadgetText dialog.textField, defaultText$
		ActivateGadget dialog.textField
		
		Return dialog
	End Function
	
	
	Method New()
		AddHook EmitEventHook, eventhook, Null, 1
		current = Self
	End Method
End Type

The problem seems to be the Repeat/WaitSystem loop, but I need something like this to halt the main program flow until the dialog is closed.

Ghost Dancer

(Posted 2010) [#5]

Any other suggestions to solve this? I really need it to behave like a Confirm dialog (or similar) so program flow only continues once the dialog is closed.

TAS	(Posted 2012) [#6]

What about deleting the event hook at start and re-installing upon exit?

skn3	(Posted 2012) [#7]

Create a window stack so when you open a window a new entry is added to the stack. All previous windows are disabled. When you close the dialogue, remove it from the stack and enable the top most window on stack.

This is ripped from my dialogue class so no idea how well it is working but hopefully it will help.

You will need the maxguiex module for some functions for bringing the window to the top n stuff.
https://github.com/skn3/maxguiex

you could probably remove the two lines

				BringWindowToTop(dialogue)
				FocusWindow(dialogue)

and then you wouldn't need maxguiex and find an alternative?

[bbcode]Import maxgui.drivers
Import maxgui.proxygadgets
Import skn3.maxguiex

Type Skn3Dialogue Extends TProxyGadget
Global hooked:Int
Global stack:TList = CreateList()
Global classes:TMap = CreateMap()

Field Window:TGadget

Field IsActive:Int = False
Field isOpen:Int = False
Field isModal:Int = True

Field hasOpened:Int = False

Field stackLink:TLink
Field stackActiveGadget:TGadget

'function api
Function OpenDialogue:Skn3Dialogue(dialogue:Skn3Dialogue,parent:Skn3Dialogue)
' --- open a dialogue spawned from this dialogue ---
If dialogue = Null Return Null

'open this dialogue
dialogue.Open()

'return it
Return dialogue
End Function

Function GetTopMostDialogue:Skn3Dialogue()
' --- return teh top most dialogue in the applet ---
Return Skn3Dialogue(stack.Last())
End Function

'hooks
Function EventHook:Object(id:Int,data:Object,context:Object)
Local event:TEvent = TEvent(data)

'check valid event
If event
'process all dialogues from top of dialogue stack to bottom
Local link:TLink = stack.LastLink()
Local dialogue:Skn3Dialogue

While link
'get dialogue
dialogue = Skn3Dialogue(link.value())

'see if the dialogue is handling the event
If dialogue.isOpen And dialogue.OnFilterEvent(event)
event = dialogue.OnEvent(event)
If event = Null Return Null
EndIf

'previous link
link = link.PrevLink()
Wend
EndIf

'return
Return event
EndFunction

'constructor/destructor
Method New()
If hooked = False
hooked = True
AddHook(EmitEventHook,Skn3Dialogue.EventHook,Null)
EndIf
End Method

'events
Method OnCreate:Skn3Dialogue() Abstract

Method OnFilterEvent:Int(event:TEvent)
Return True
End Method

Method OnEvent:TEvent(event:TEvent)
Select event.id
Case EVENT_WINDOWCLOSE
' --- window is closed ---
If event.source = Self
close()

'return event used
Return Null
End If
End Select

Return event
End Method

Method OnClose()
If Window FreeGadget(Window)
End Method

'api
Method OpenChildDialogue:Skn3Dialogue(dialogue:skn3Dialogue)
Return Skn3Dialogue.OpenDialogue(dialogue,Self)
End Method

Method Open()
' --- open the dialogue ---
If Window And isOpen = False
'flag this dialogue open
isOpen = True

Local link:TLink
Local dialogue:Skn3Dialogue

'for the top most dialogue remember the active gadget
dialogue = Skn3Dialogue(stack.Last())
If dialogue
'get active gadget
dialogue.stackActiveGadget = ActiveGadget()

'make sure the gadget is not the dialogue window
If dialogue.stackActiveGadget = dialogue.Window dialogue.stackActiveGadget = Null
EndIf

'lock all other dialogues if this new dialogue is modal!
If isModal
link = stack.FirstLink()
While link
'get dialogue
dialogue = Skn3Dialogue(link.value())

'disable dialogue
If dialogue.isModal DisableGadget(dialogue)

'next dialogue
link = link.NextLink()
Wend
EndIf

'add this dialogue to the stack if it is a modal
stackLink = stack.AddLast(Self)

'setup the dialogue window
If hasOpened = False ShowGadget(Window)

'reset first open flag
hasOpened = True
EndIf
End Method

Method close()
' --- close the dialogue and remove it from the stack ---
'ok indicated whether we are just closing or if we are returning
Local link:TLink
Local dialogue:Skn3Dialogue

'first activate the what will be new top most dialogue
link = stackLink.PrevLink()
If link
While link
dialogue = Skn3Dialogue(link.value())
if dialogue.isModal Exit
link = link.PrevLink()
dialogue = Null
Wend

If dialogue And dialogue.Window
'activate the dialogue window
EnableGadget(dialogue)
BringWindowToTop(dialogue)
FocusWindow(dialogue)

'activate a gadget if there was one
If dialogue.stackActiveGadget <> Null
ActivateGadget(dialogue.stackActiveGadget)
dialogue.stackActiveGadget = Null
EndIf
EndIf
EndIf

'now pop dead dialogues starting from this off the stack
link = stackLink
While link
'get dialogue
dialogue = Skn3Dialogue(link.value())

dialogue.OnClose()

'next link
link = link.NextLink()

'remove the dialogue from the stack
If dialogue.isModal
dialogue.stackLink.remove()
dialogue.stackLink = Null
EndIf
Wend

'return successful close
Return Null
End Method
End Type

Type Skn3DialogueParent Extends Skn3Dialogue
Field button:TGadget

Method OnCreate:Skn3Dialogue()
Window = CreateWindow("parent window",50,50,300,300,Null,WINDOW_TITLEBAR)
SetProxy(Window)

button = CreateButton("press",5,5,Window.ClientWidth()-10,Window.ClientHeight()-10,Window)

Return Self
End Method

Method OnFilterEvent:Int(event:TEvent)
Return event.source = button
End Method

Method OnEvent:TEvent(event:TEvent)
Select event.id
Case EVENT_GADGETACTION
Select event.source
Case button
OpenChildDialogue(New Skn3DialogueChild.OnCreate())
Return Null
End Select
End Select

Return Super.OnEvent(event)
End Method
End Type

Type Skn3DialogueChild Extends Skn3Dialogue
Method OnCreate:Skn3Dialogue()
Window = CreateWindow("child window",50,50,150,150,Null,WINDOW_TOOL | WINDOW_TITLEBAR)
SetProxy(Window)

Return Self
End Method
End Type

Local parentDialogue:Skn3Dialogue = New Skn3DialogueParent.OnCreate()
parentDialogue.Open()

Repeat
WaitEvent()
Forever[/bbcode]

Last edited 2012

Last edited 2012

Last edited 2012