Multi status fields

BlitzMax Forums/MaxGUI Module/Multi status fields

Zeke	(Posted 2010) [#1]

Hi, this is my test to get more than one statusfield. i dont know it this is possible in linux or maxos but in windows this works.

superstrict

Import MaxGui.Drivers

Const WM_USER:Int = $400

Const SB_SETTEXT:Int = $401
Const SB_GETTEXT:Int = $402
Const SB_GETTEXTLENGTH:Int = $403
Const SB_SETPARTS:Int = $404
Const SB_GETPARTS:Int = $406

'added a new const
Const LHND:Int = $0042

AppTitle = "CreateWindow() Example"

Global FLAGS:Int

' Comment/uncomment any of the following lines to experiment with the different styles.

FLAGS:| WINDOW_TITLEBAR
'FLAGS:| WINDOW_RESIZABLE
'FLAGS:| WINDOW_MENU
'FLAGS:| WINDOW_STATUS
FLAGS:| WINDOW_CLIENTCOORDS
'FLAGS:| WINDOW_HIDDEN
FLAGS:| WINDOW_ACCEPTFILES
'FLAGS:| WINDOW_TOOL
'FLAGS:| WINDOW_CENTER

Global window:TGadget = CreateWindow( AppTitle, 100, 100, 800, 240, Null, FLAGS )

Createstatus(5) 'insert statusfields count

Repeat
	WaitEvent()
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_APPTERMINATE, EVENT_WINDOWCLOSE
			End
	End Select
Forever


Function CreateStatus(parts:Int)
	Local hwnd:Int=QueryGadget(window,QUERY_HWND)
	Local status:Int = CreateWindowExW(0 , "msctls_statusbar32" , "" , WS_CHILD | WS_VISIBLE , 0 , 0 , 0 , 0 , hwnd , 0 , GetModuleHandleW(Null) , Null)

	Local rcrect:Int[4]
	getclientrect(hwnd , rcrect)

	Local nwidth:Int = rcrect[2] / parts
	Local widths:Int[parts]
	
	Local totalwidth:Int = nwidth
	
	For Local i:Int = 0 Until parts
		widths[i] = totalwidth
		totalwidth:+ nwidth
	Next

	SendMessagew(status , SB_SETPARTS , Parts ,Int(Int Ptr Varptr widths[0]))
	
	Local text$[parts]
	For Local i:Int = 0 Until parts
		text[i] = "Field " + i
		Local t:Byte Ptr = text[i].tocstring()
		SendMessageW(status , SB_SETTEXT , i ,Int(t) )
		MemFree t
	Next

End Function

and i know this is not working.. because if you move window then statusbar disappear

Zeke	(Posted 2010) [#2]

this is not complete code.. just for testing.. and if you move window then statusbar disappear. but i want this to be added maxgui.. this just need some addstatusfield methods and redraw functions..

FBEpyon

(Posted 2010) [#3]

Hello Zeke,

So I seem to have gotten a Win32 only version of the MaxGUI module to allow for status bar splitting... There is a few more things I need to fix, but all in all it works great.

I need to put in the Docs for the new addition to the module, and then I will release my own Win32 only MaxGUI module to the public.

here is a screen:

Also you can resize it with no problem, because its within the main TWindowGadget under the windows section of the module, so all the part controls are working fine... also I'm working on a MDI client window next if you are in interested in that as well.

Last edited 2010

Zeke	(Posted 2011) [#4]

maxgui.mod/maxgui.bmx: (added)

Rem
	bbdoc: Add status field
endrem
Function AddStatusField(window:TGadget,txt:String , width:Int)
	window.AddStatusField(txt,width)
End Function

maxgui.mod/gadget.bmx: (modified)
(TGadget type)

' window commands
	Method GetStatusText$(index:Int=0)
	End Method
	Method SetStatusText(text$,index:Int=0)
	End Method
'statusbar
	Method AddStatusField(txt:String , width:Int)
	End Method

win32maxguiex.mod/winimports.bmx: (added)

'Status
Const SB_SETTEXTW:Int = $40B
Const SB_GETTEXTW:Int = $40D
Const SB_GETTEXTLENGTHW:Int = $40C
Const SB_SETPARTS:Int = $404
Const SB_GETPARTS:Int = $406

win32maxguiex.mod/win32maxguiex.bmx: (added+modified)

(type TWindowsWindow extends TWindowGadget)

'added
Field _status_widths:Int[]
Field _statustext:String[]

Method GetStatusText:String(index:Int = 0)
	If _status
		If index < 0 Or index >= _statustext.Length Then Return
		Return _statustext[index]
	EndIf
EndMethod

Method SetStatusText(Text:String, index:Int = 0)
	If _status
		If _status_widths.Length = 0 Then Self.AddStatusField(Text, -1)
		If index < 0 Or index >= _statustext.Length Then Return
		_statustext[index] = Text
		If (Style & WINDOW_RESIZABLE) Then Text:+"      "	'Cludge for size handle obfuscation
		Local tmpWString:Short Ptr = Text.ToWString()
		SendMessageW _status, SB_SETTEXTW, index, Int(tmpWString)
		MemFree tmpWString
	EndIf
EndMethod

Method AddStatusField(txt:String, _width:Int)
	If Not _status Return

	Local totalwidth:Int = _status_widths[_status_widths.Length - 1] 'take total width
	
	_status_widths = _status_widths[.._status_widths.length + 1] 'add field
	_statustext = _statustext[.._statustext.length + 1] 'increase text storage
	
	If _width >= 0 Then _width = _width + totalwidth
	
	_status_widths[_status_widths.Length - 1] = _width
	
	SendMessageW(_status, SB_SETPARTS, _status_widths.Length, Int(Int Ptr Varptr _status_widths[0]))
	
	Self.SetStatusText(txt, _status_widths.Length - 1)
End Method

Method ResizeStatus()
	For Local i:Int = 0 Until _status_widths.Length
		SendMessageW(_status, SB_SETPARTS, _status_widths.Length, Int(Int Ptr Varptr _status_widths[0]))
	Next
End Method

also edit wndproc method:


Case WM_SIZE
	
	If (hwnd = _hwnd) And (wp <> SIZE_MINIMIZED) Then
	
		If _status Then
			ResizeStatus
			SendMessageW _status, WM_SIZE, 0, 0
		EndIf

Last edited 2011

Last edited 2011