Gadgets in statusbar

BlitzMax Forums/MaxGUI Module/Gadgets in statusbar

Ghost Dancer

(Posted 2010) [#1]

Is there anyway of doing this? It would be nice to add labels & progress bars in the statusbar for the app I'm writing.

I've tried simply adding gadgets parented to the main window but no joy.

skn3	(Posted 2010) [#2]

You can do it by making a fake status bar using panels but I think that is all that is available to you with maxgui

jsp	(Posted 2010) [#3]

Here you go:

Extern "win32"
	Function SetParent( Child:Int,Parent:Int)
End Extern

Window:TGadget=CreateWindow("MyWindow", 10, 10, 400, 300 )
Label:TGadget=CreateLabel("This is a very long label may resize your window to see all the text",50,2,80,14,Window)	
		
Local LabelHWND:Int = QueryGadget(Label,QUERY_HWND)
Local StatusHWND:Int = TWindowsWindow(window)._status			

setParent(LabelHWND,StatusHWND)

SetGadgetLayout(Label,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_CENTERED)

Repeat
	WaitEvent()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			Select EventSource()
				Case Window		End
			End Select
	End Select

Forever

Ghost Dancer

(Posted 2010) [#4]

Nice one. Thanks jsp :) Is there a way of doing this on a Mac too?

Zeke	(Posted 2010) [#5]

SuperStrict

Import MaxGui.Drivers

AppTitle = "CreateWindow() Example"

Global FLAGS:Int

' Comment/uncomment any of the following lines to experiment with the different styles.

FLAGS:| WINDOW_TITLEBAR
FLAGS:| WINDOW_RESIZABLE
FLAGS:| WINDOW_MENU
'FLAGS:| WINDOW_STATUS
FLAGS:| WINDOW_CLIENTCOORDS
'FLAGS:| WINDOW_HIDDEN
FLAGS:| WINDOW_ACCEPTFILES
'FLAGS:| WINDOW_TOOL
'FLAGS:| WINDOW_CENTER

Global statbar:TGadget

Global Window:TGadget = CreateWindow(AppTitle, 100, 100, 320, 240, Null, FLAGS)

Const StatusHeight:Int = 20

statbar = CreatePanel(0, ClientHeight(Window) - StatusHeight, ClientWidth(Window), StatusHeight, Window, PANEL_BORDER)

Global progbar:TGadget = CreateProgBar(0, 0, ClientWidth(statbar) / 3, statusheight, statbar)

Global label:TGadget = CreateLabel("Ticks: ", ClientWidth(progbar), 0, 50, statusheight, statbar)

CreateTimer(1)

Repeat
	WaitEvent()
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_APPTERMINATE, EVENT_WINDOWCLOSE
			End
		Case EVENT_TIMERTICK
			Local Tick:Int = EventData() Mod 20
			UpdateProgBar progbar, Tick / 20.0
			SetGadgetText(label, "Ticks: " + Tick)
	End Select
Forever

this is also one solution. (forgot to use SetLayout) but this show how to use panel as statusbar.

Ghost Dancer

(Posted 2010) [#6]

Thanks Zeke, thats an good workaround, but by manually coding the status bar there is no resize handle.

I'm leaning more towards jps's method but there is a good chance I will need to do a Mac version so need to work out how to do that.