Detect if mouse is over a treeview node?

BlitzMax Forums/MaxGUI Module/Detect if mouse is over a treeview node?

Snixx

(Posted 2010) [#1]

I have a preview window and I would need to know if the mouse cursor is over a node (not clicking on a node) in the treeview so that I can then load the file to display in the preview window.... any ideas?

SebHoll

(Posted 2010) [#2]

It's not possible using only the official MaxGUI commandset, however, it can be achieved with a bit of Win32 voodoo magic:

' createtreeview.bmx

Import MaxGui.Drivers

Strict 

Local window:TGadget=CreateWindow("My Window",50,50,240,240,Null,WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS)
Local treeview:TGadget=CreateTreeView(5,5,ClientWidth(window)-10,ClientHeight(window)-10,window)

SetGadgetLayout treeview, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED
SetGadgetSensitivity treeview, SENSITIZE_MOUSE

Local root:TGadget=TreeViewRoot(treeview)

Local help:TGadget=AddTreeViewNode("Help",root)
AddTreeViewNode "Topic 1",help
AddTreeViewNode "Topic 2",help
AddTreeViewNode "Topic 3",help

Local projects:TGadget=AddTreeViewNode("Projects",root)
AddTreeViewNode("Sub Project",AddTreeViewNode("Project 1",projects))
AddTreeViewNode("Project 2",projects)
AddTreeViewNode("Project 3",projects)

While WaitEvent()
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_MOUSEMOVE
			Select EventSource()
				Case treeview
					Local tmpNode:TGadget = GetNodeUnderMouse( treeview, EventX(), EventY())
					If tmpNode Then SetGadgetText window, GadgetText(tmpNode)
			EndSelect
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			End
	End Select
Wend

Function GetNodeUnderMouse:TGadget( treeview:TGadget, pX, pY ) "win32"
	
	?Win32
	Local hwnd:Int = QueryGadget(treeview, QUERY_HWND)
	Local item:Int[10], hittestinfo:Int[] = [pX, pY, 0, 0]
	If SendMessageW( hwnd, TVM_HITTEST, 0, Int Byte Ptr hittestinfo )
		item[0] = TVIF_PARAM
		item[1] = hittestinfo[3]
		SendMessageW hwnd, TVM_GETITEMW, 0, Int Byte Ptr item 
		Return TWindowsTreeNode(HandleToObject(item[9]))
	EndIf
	?

EndFunction