I think I trashed my vid mem with two canvases

BlitzMax Forums/MaxGUI Module/I think I trashed my vid mem with two canvases

matibee

(Posted 2009) [#1]

Hi all,

I wrote a simple tile editor on my windows box (which has loads of vram) but it fails on my Mac that only has 64mb shared Intel GMA 950. It uses two canvases and once a tile has been drawn on one, it refuses to appear on the other.

1) Could a Mac owner with some proper VRAM tell me this works for them? :)
2) If clicking in the main window only gives you white squares, comment out the drawimage for the mini-view (line 125)
3) Should I be taking specific steps to share images across canvases, along the lines of the glShareContexts? In which case, why the different behaviour across platforms/drivers?

I'm aware of the horror stories with GMA950 with things like DirectX drivers, and actually chose this chipset because if the code's gonna fail, I want it to fail for me :)

I've kinda 'solved' the issue by having two sets of images; one for each canvas.

Cheers
Matt

SuperStrict
Import MaxGui.Drivers

'==================================================================================================================
'
'	Init controls
'
Global window:TGadget = CreateWindow:TGadget("Editor",60,60,1010,640,Null,WINDOW_TITLEBAR| WINDOW_CLIENTCOORDS )
	
Global Label9:TGadget = CreateLabel:TGadget("Tiles",11,20,150,14,window:TGadget,Null)
Global Tiles_ListBox:TGadget = CreateListBox:TGadget(10,42,90,110,window:TGadget,Null)
	For Local i:Int = 1 To 50
		AddGadgetItem( Tiles_ListBox:TGadget, i,GADGETITEM_NORMAL )
	Next 
	Tiles_ListBox.SelectItem( 0 )
	
Global tileCanvas:TGadget = CreateCanvas( 110, 42, 70, 50 , window:TGadget )
Global gameCanvas:TGadget = CreateCanvas( 200, 20, 800, 576, window:TGadget )

'==================================================================================================================
'
'	Global variables
'
Global mx:Int 				' mouse position
Global my:Int 
Global tileID:Int 			' current drawing tile
Global tiles:TImage[50]		' tile images
Global data:Int[25,12]

'==================================================================================================================
'
'	Create the images
'
For Local t:Int = 0 To 49
	tiles[t] = CreateImage( 32, 48, 1, DYNAMICIMAGE|MASKEDIMAGE )
	Local pm:TPixmap = LockImage( tiles[t] )
	Local g:Int = t * 5
	Local r:Int = (t * 30 ) Mod 255
	Local col:Int = (255 Shl 24) + (r Shl 16) + (g Shl 8) + 255
	For Local x:Int = 0 To 31
		For Local y:Int = 0 To 47
			Local color:Int = col
			If ( y <= t ) color = (255 Shl 24)
			WritePixel( pm, x, y, color )
		Next 
	Next 
	UnlockImage( tiles[t] )
Next 


PaintWindow( gameCanvas )
PaintWindow( tileCanvas )

'==================================================================================================================
'
'	Application loop
'
Repeat
	WaitEvent()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			Select EventSource()
				Case window 
					End 
			End Select
		Case EVENT_GADGETACTION
			Select EventSource()
				Case Tiles_ListBox
					tileID = EventData()
					PaintWindow( tileCanvas )
			End Select
		Case EVENT_GADGETSELECT
			Select EventSource()
				Case Tiles_ListBox
					tileID = EventData()
					PaintWindow( tileCanvas )
			End Select
		Case EVENT_GADGETPAINT
			Select EventSource()
				Case gameCanvas
					'
					' Draw the main canvas
					'
		              SetGraphics CanvasGraphics( gameCanvas )
					SetClsColor ( 40,40,0 )
					Cls 
		               Local wid% = gameCanvas.ClientWidth()
		               Local hgt% = gameCanvas.ClientHeight()
					SetColor ( 255,255,255 )
					SetBlend( ALPHABLEND )
					For Local x% = 0 To 24
						For Local y% = 0 To 11
							DrawImage( tiles[ data[x,y] ], x * 32, y * 48 )
						Next 
					Next 
		
					If ( tileID > 0 )
						SetColor( 255,0,0 )
						SetLineWidth(2)
						For Local x% = 0 To 24
							For Local y% = 0 To 11
								If ( data[x,y] = tileID )
									Local xFrom:Int = x * 32
									Local yFrom:Int = y * 48
									Local xTo:Int = xFrom + 32
									Local yTo:Int = yFrom + 48
									DrawLine( xFrom, yFrom, xTo, yFrom )
									DrawLine( xTo, yFrom, xTo, yTo )
									DrawLine( xTo, yTo, xFrom, yTo )
									DrawLine( xFrom, yFrom, xFrom, yTo )
								End If 
							Next 
						Next 
						SetLineWidth(1)
						SetColor(255,255,255)
					End If 
					Flip 
				Case tileCanvas
					'
					'-- draw the mini canvas
					'
					SetGraphics CanvasGraphics( tileCanvas )
					SetClsColor ( 40, 40, 0 )
					Cls 
					DrawImage( tiles[ tileID ], 19, 1 )
					Flip 			
				End Select 
		Case EVENT_MOUSEMOVE
			mx = EventX()
			my = EventY()
		Case EVENT_MOUSEDOWN
			Local x% = mx / 32
			Local y% = my / 48
			If ( x >= 0 And x < 25 And y >= 0 And y < 12 )
				data[x,y] = tileID
				PaintWindow( gameCanvas )
			End If 
		Case EVENT_MOUSEENTER
			Select EventSource()
				Case gameCanvas 
					ActivateGadget( gameCanvas )
			End Select 
		End Select
Forever

Function PaintWindow( source:TGadget )
	Local e:TEvent = New TEvent
	e.source = source
	e.id = EVENT_GADGETPAINT
	PostEvent( e )
End Function

klepto2

(Posted 2009) [#2]

Try adding this right after the import part in your code:

?Not win32
GLShareContexts()
?

The inconsistant behaviour is due the fact that win32 will use DX as a standard gfx driver where linux or mac use OpenGL.

matibee

(Posted 2009) [#3]

Perfect Kelpto thanks.