Calendar Gadget (WIP)

BlitzMax Forums/MaxGUI Module/Calendar Gadget (WIP)

degac

(Posted 2009) [#1]

Hi,
I'm working on a 'calendar' gadget (at the moment is tested only on Win32...).

Rem
		Calendar gadget
		
		degac 
		07 jun 2009
End Rem

Import maxgui.drivers

Local window:tgadget=CreateWindow("Test window",100,100,300,300,,window_titlebar|window_center|WINDOW_RESIZABLE)

Local data:tcalendar=CreateCalendar(10,40,,,window)

Local label:tgadget=CreateLabel("Label",10,5,200,25,window)

'this method to set an Appointment-reminder on the calendar
'I need to find an official MaxGUI command to implement this
'probably AddGadgetItem calendar,"day-month:description"

data.SetAppointment("10-06","Test application!")
data.SetAppointment("12-06","World launch!")
RedrawGadget data 'you need to 'redraw' the gadget to see the appointments set for the current month


While True
	WaitEvent
	Print CurrentEvent.ToString()

		Select EventID()
						
			Case event_windowclose
				If EventSource()=window End
		End Select


Wend

End

'------------------------
Rem
	
	the calendar has a MINIMUM wide and height

End Rem
Function CreateCalendar:tcalendar(x:Int,y:Int,w:Int=152,h:Int=191,group:tgadget=Null)
	If group=Null Return Null
	
	Local min_w:Int=152,min_h:Int=191
	
	If w<min_w w=min_w
	If h<min_h Or h>min_h h=min_h
	
	Return tcalendar.Create(x,y,w,h,group)
End Function

Type tcalendar Extends Tproxygadget

	Global day_name$[]=["Mo","Tu","We","Th","Fr","Sa","Su"]'["Lu","Ma","Me","Gi","Ve","Sa","Do"]
	Global month_name$[]=["January","February","March","April","May","June","July","August","September","October","November","December"]
	Global month_days:Int[]=[31,28,31,30,31,30,31,31,30,31,30,31]

	Global map_dayfest:tmap=CreateMap()
	Global map_appointment:tmap=CreateMap()
	Global _fest_data$[]=["01-01","25-04","01-05","02-06","15-08","01-11","08-12","25-12"]
	Global _fest_Desc$[]=["New year","Liberation day","Worker day","Republic Day","Ferragosto","All saints","Immaculate conception","Nativity"]
	Global _app_data$[]
	Global _app_desc$[]
	

	Field panel:tgadget
	Field style:Int
	Field year_dec:tgadget,year_inc:tgadget,year:tgadget
	Field month_dec:tgadget,month_inc:tgadget,month:tgadget
	Field days:tgadget[],label:tgadget[7]
	Field current_year:Int,current_month:Int,current_day:Int
	Field day_wide:Int=21,day_height:Int=21
	Field max_wide:Int=146,max_heigth:Int=191
	Field data$
	
	
		

	Method SetEnabled(sta:Int=True)

		Local k:tgadget
		
		If sta=False
			DisableGadget panel
			DisableGadget year_dec
			DisableGadget year_inc
			DisableGadget year
			DisableGadget month_dec
			DisableGadget month_inc
			DisableGadget month
			
			For k=EachIn days
				DisableGadget k
			Next
			
			For k=EachIn label
				DisableGadget k
			Next

			
		Else
			EnableGadget panel
			EnableGadget year_dec
			EnableGadget year_inc
			EnableGadget year
			EnableGadget month_dec
			EnableGadget month_inc
			EnableGadget month
			
			For k=EachIn days
				EnableGadget k
			Next
			For k=EachIn label
				EnableGadget k
			Next


		End If
		
	End Method
	
	Method Free()
		RemoveHook EmitEventHook,EventHandler,Self
		If panel FreeGadget panel
	
		If year_dec FreeGadget year_dec
		If year_inc FreeGadget year_inc
		If year	FreeGadget year
		If month_dec FreeGadget month_dec
		If month_inc FreeGadget month_inc
		If month FreeGadget month
		
		Local gg:tgadget
		If days
			For gg=EachIn days
				FreeGadget gg
				gg=Null
			Next
			days=Null
		End If
		
		If label
			For gg=EachIn label
				FreeGadget gg
				gg=Null
			Next
			label=Null
		End If
			
		panel=Null
		Super.Free
	End Method


	
	Function Create:tcalendar(x:Int,y:Int,w:Int,h:Int,group:tgadget,style:Int=0)
		Local sp:tcalendar=New tcalendar
		
		sp.panel =		CreatePanel(x,y,w,h,group,PANEL_BORDER)
		
		sp.year_dec=	CreateButton("<",0,0,20,20,sp.panel )
		sp.year_inc=	CreateButton(">",w-24,0,20,20,sp.panel )
		sp.year	=	CreateLabel ("year",20,0,W-44,20,sp.panel,LABEL_SUNKENFRAME|LABEL_CENTER )
		
		sp.month_dec=	CreateButton("<",0,20,20,20,sp.panel )
		sp.month_inc=	CreateButton(">",w-24,20,20,20,sp.panel )
		sp.month=		CreateLabel ("month",20,20,W-44,20,sp.panel,LABEL_SUNKENFRAME|LABEL_CENTER )
	
		Local XX:Int,YY:Int=62
		Local nam$,k:Int,lbl:tgadget,counter:Int
		
		sp.day_wide=w/7
		sp.max_wide=w-sp.day_wide
		
		Local dyear:Int,dmonth:Int,dday:Int,ddate:String
		Local dinfo:String[]
		
		ddate=Lower(CurrentDate())'"%d %m %Y"))
		'with my CurrentDate() hack everything will be faster...
		'so at the moment I need to convert the months in an index...
		dinfo=ddate.split(" ")
	
		Local mcounter:Int=0
		For Local ch$=EachIn month_name$
			mcounter:+1
			'If dinfo[1]=Lower(ch) dinfo[1]=String(mcounter)
	If Left(dinfo[1],3)=Left(Lower(ch),3) dinfo[1]=String(mcounter)'for linux compatibility
		Next
			
		ddate=dinfo[0]+" "+dinfo[1]+" "+dinfo[2]

		sp.current_day=	Int(dinfo[0])
		sp.current_month=Int(dinfo[1])
		sp.current_year=	Int(dinfo[2])
		
		SetGadgetText sp.year,dinfo[2]
		SetGadgetText sp.month,month_name[Int(dinfo[1])-1]
	
		For counter=0 Until 7
			lbl=CreateLabel(day_name[counter],xx,yy-20,sp.day_wide,18,sp.panel,LABEL_CENTER)
			xx:+sp.day_wide
			If counter=6 SetGadgetColor lbl,128,128,128
			sp.label[counter]=lbl
	
		Next
		
		Local julian_time:Int=Conv_Date2Julian(ddate)
		Local day_week:Int=DayOfTheWeek(julian_time) ' 0 : Sunday, 1 : Monday...
		
		xx=day_week*day_wide
		sp.DrawCalendar(xx,dinfo) ' it reports the CURRENT DATA
		AddHook EmitEventHook,EventHandler,sp
		sp.data=ddate
		sp.style=style
		sp.SetProxy sp.panel
		
		'add festivity
		
		
		For Local s:Int=0 Until _Fest_data.length
				MapInsert(map_dayfest,_fest_data[s],_fest_desc[s])
		Next
		
		Return sp
	End Function
	
	Method DrawCalendar(xx:Int=0,info:String[])
		Local yy:Int=62,nam$,k:Int
		Local max_days:Int=month_days[Int(info[1])-1]
		If AnnoBisesto(Int(info[2]))=1 And Int(info[1])=2 Then max_days=29

		If days<>Null
			For Local sj:tgadget=EachIn days
				If sj<>Null 
					FreeGadget sj
					sj=Null
				End If

			Next
			days=Null
			GCCollect()
		End If

		K=0
		
		days=days[..max_days]
		
		Local festday$[]
		
		While k<max_days
			nam=String(k+1)
					
			days[k]=CreateButton(nam$,XX,yy,day_wide,day_height,panel)
			SetGadgetColor days[k],200,200,200
			If k=Int(info[0])-1 SetGadgetColor days[k],125,125,230
	
			'check for fest day
			
			For Local fd:String=EachIn MapKeys(map_dayfest)
				festday=fd.split("-")
				If k=Int(festday[0])-1 And Int(info[1])=Int(festday[1])
					SetGadgetColor days[k],200,20,20
					SetGadgetToolTip days[k],String(MapValueForKey(map_dayfest,fd))
				End If
			Next
	
			'check for appointment day
			
			For fd:String=EachIn MapKeys(map_appointment)
				festday=fd.split("-")
				If k=Int(festday[0])-1 And Int(info[1])=Int(festday[1])
					SetGadgetColor days[k],200,220,20
					SetGadgetToolTip days[k],String(MapValueForKey(map_appointment,fd))
				End If
			Next

	
			xx:+day_wide
			If xx>max_wide xx=0;yy:+day_height
			
			k:+1
			
		Wend	
	End Method
	
	Method SetAppointment(_dat$="",_des$="")
		If _dat="" Or _des="" Return
		MapInsert(map_Appointment,_dat,_des)
	End Method
	
	Method Activate(command)
		SetDate()

	End Method

	
	Method SetDate()
	
		If current_month>12 current_month=1
		If current_month<1 current_month=12
	
		Local newdate$=Right("00"+String(current_day),2)+" "+Right("00"+String(current_month),2)+" "+String(current_year)
		
		SetGadgetText year,String(current_year)
		SetGadgetText month,month_name[current_month-1]
		
		Local xx:Int,dinfo:String[]=[String(current_Day),String(current_month),String(current_year)]
	
		Local julian_time:Int=Conv_Date2Julian("01 "+dinfo[1]+" "+dinfo[2])'the first day of the month
		Local day_week:Int=DayOfTheWeek(julian_time)
		
		
		xx=day_week*day_wide
		
		DrawCalendar(xx,dinfo)
		data=newdate
		SetGadgetExtra Super,data
		'Print "Gadget extra : "+String(GadgetExtra(Super))
	End Method
	
	
	Function eventHandler:Object( pID%, pData:Object, pContext:Object )
		Local pEvent:TEvent = TEvent(pData)
		Local obj:tcalendar=tcalendar(pContext)
		
		If pEvent
		
				
			Select pEvent.Source
				Case obj.year_Inc
				'	Print "Anno +"
					obj.current_year:+1
					obj.SetDate()
						
				Case obj.year_dec
				'	Print "Anno -"
					obj.current_year:-1
					obj.SetDate()
				Case obj.month_Inc
				'	Print "Mese +"
					obj.current_month:+1
					obj.SetDate()
					
			

				Case obj.month_dec
					'Print "Mese -"
					obj.current_month:-1
					obj.SetDate()
			
			End Select			

			For Local dgad:tgadget=EachIn obj.days
				If pevent.Source=dgad
					'Print "Pressed DAY: "+GadgetText(dgad)
					obj.current_day=Int(GadgetText(dgad))
					obj.SetDate()
					

				End If
			Next
			
			
		End If
		
		Return pData
	EndFunction

	
End Type

Function AnnoBisesto:Int(anno:Int=0)
If anno=0 Return 0
Local bisesto:Int=0
	If (anno Mod 4)=0 bisesto=1
	If (anno Mod 100)=0
		If (anno Mod 400)=0
			bisesto=1
		Else
			bisesto=0
		End If
	End If
	Return bisesto
End Function

Function Conv_Date2Julian:Int(_data$="")
	If _data$="" Return 0

	Local year:Int,month:Int,day:Int
	Local _din$[]=_Data.split(" ")
	year=Int(_din[2])
	month=Int(_din[1])
	day=Int(_din[0])
	
	Local JulianDate:Int
	' conversion taken from a website (lost link)
	JulianDate = 367 * Year - ((7 * (Year + 5001 + ((Month - 9) / 7))) / 4) + ((275 * Month) / 9) + Day + 1729777
	
	Return JulianDate
End Function

Function DayOfTheWeek:Int(pjulian:Int)
	
	Local Jt:Float=Float(pjulian)+1.5
	Return (jt Mod 7)

End Function

There are some little functions to retrieve the 'leap year' (Anno Bisestile), the Day of the week (0: Sunday, 1: Monday...) and the JulianTime conversion (I found on the Code archives)

I need some help to retrieve the fundamental information: the data choosen by the user!!!

Any suggestions, critics and comments are welcome!

Edited: added a Linux version image

If anyone can test under Linux (FLTK) I found that button 'colored' are 'decoloured' when I move the mouse on them...

Mark Tiffany

(Posted 2009) [#2]

Nice...in theory, as I get an error on line 201 (array index issue).

Some thoughts on knowing the date chosen:
- use toggle buttons so they stay down when the day is clicked
- return the date in eventdata on GadgetAction event (string="YYYY-MM-DD" format?) Or a new "date" type might be better?
- return a gadgetitem for selectedgadgetitem (less keen, but might work well with addgadgetitem for setting coloured dates?)

degac

(Posted 2009) [#3]

Edited for handling Linux incompatbility

@Mark

Thank for the suggestions; 1 & 2 are interesting solutions

Mark Tiffany

(Posted 2009) [#4]

Works here now. A few suggestions:

- to ensure macos and gtk compatibility, you probably need slightly bigger buttons. I find compiling with Brucey gtkmaxgui tends to give an idea of what it will be like on mac
- suggest that you don't let the selected day hang over when you change month / year. i.e. if I pick 13th July 2009 (my birthday), then change month or year, 13 shouldn't be selected, unless I return to July 2009
- suggest you show today in a slightly different style, and maybe consider a "go to today" button
- you have greyed out Sunday...some people might want Sat & Sun greyed out.
- some people might want the calendar to start on a different day of the week (some countries have different conventions)

Obviously, most of those are nice to haves! In terms of how you make these things available to the user, I don't think there's any harm in creating Calendar specific commands if needed...

d-bug

(Posted 2009) [#5]

oops, to slow...

just to confirm Marks post :/

degac

(Posted 2009) [#6]

Thanks for the suggestions!
As I said in my initial post I'm developing on win32 at the moment (and on Linux just to find out some possible errors - like the one on the returned date...)

- suggest that you don't let the selected day hang over when you change month / year. i.e. if I pick 13th July 2009 (my birthday), then change month or year, 13 shouldn't be selected, unless I return to July 2009

...well I've tried to imitate the same behaviour of the calendar gadget under WindowXP and Ubuntu when you click on the clock/date icon in the desktopbar: the day stays selected while you change month or year.
Maybe I can setup 2 different behaviours

SebHoll

(Posted 2009) [#7]

Argh - this CocoaMaxGUI driver could really do with being cleaned up... The offset for the gadgets in the sunken panel is completely wrong and the label text isn't center aligned. Not nice... :-/ I'll post a bug report to remind me to look at this...

Edit: I've been a bit naughty and hot-linked to your images, degac/d-bug. Hope you don't mind...

d-bug

(Posted 2009) [#8]

Hey Seb,

if you really plan to clean up the Cocoa driver, please give us button-style-flags instead of size dependency. Or better, make it possible to get access to the BezelStyle flags with an extra method or something.

degac

(Posted 2009) [#9]

This is a little update, no changes on the visual aspect and only tested on win32 (for the moment):
+ fixed some minor bugs
+ added some proper function for Set, Get and Remove Appointments
+ on a same date you can have more appointments (they will displayed in a tooltips)
+ EventExtra() will return in string form (at the moment DD MM YYYY) the selected date

Rem
		Calendar gadget
		
		degac 
		07 jun 2009		first release, some basic fixes
		08 jun 2009		the Calendar Gadget returns (every time you click/change the date) the new date
					in the EventExtra field
					you can have multiple appointments in the same date (dd-mm)
					you can have 'fixed' appointment for a specific year (dd-mm-yyyy)
End Rem
SuperStrict
Import maxgui.drivers
Local window:tgadget=CreateWindow("Calendar v. 1.1",100,100,500,300,,window_titlebar|window_center|WINDOW_RESIZABLE)
Local data:tcalendar=CreateCalendar(10,40,,,window)
Local label:tgadget=CreateLabel("Label",10,5,200,25,window)

'this method to set an Appointment-reminder on the calendar
'I need to find an official MaxGUI command to implement this
'probably AddGadgetItem calendar,"day-month:description"

SetCalendarAppointment(data,"10-06","1. Test application!")
SetCalendarAppointment(data,"10-06","2. Second appointment...~nRemember to conquer the world!")
SetCalendarAppointment(data,"10-06","3. Buy the milk")
SetCalendarAppointment(data,"12-06","World launch!")
SetCalendarAppointment(data,"09-06-2009","This is a fixed date")

'RemoveAppointments(data,"12-06")

RedrawGadget data 'you need to 'redraw' the gadget to see the appointments set for the current month

While True
	WaitEvent
		Select EventID()
		
		Case event_gadgetaction
	
			If EventSource()=data
					SetGadgetText label,String(EventExtra())
			End If
			
						
		Case event_windowclose
			If EventSource()=window End
		End Select
Wend

End

Rem
bbdoc: Crate a basic Calendar
about: it shows a simple calendar for year/month reporting the (eventual) appointments or festivity<br>
it returns the new date in the @EventExtra field.<br>
@x, @y are the initial position, while @w and @h (if specified) are the width and the height of the 
calendar.<br>
Remember that there are @minimum size dimensions for wide and height.<br>
@style: if 1 will no shown the day selected.

End Rem
Function CreateCalendar:tcalendar(x:Int,y:Int,w:Int=152,h:Int=191,group:tgadget=Null,_style:Int=0)
	If group=Null Return Null	
	Local min_w:Int=152,min_h:Int=191
	If w<min_w w=min_w
	If h<min_h Or h>min_h h=min_h
	Return tcalendar.Create(x,y,w,h,group,_style)
End Function
Rem
bbdoc: Set an appointment for the date (DD-MM) or (DD-MM-YYYY)
about: you can specify a simple date (Day-Month) and the appointment will be repeated every year.<br>
Or you can specify a complete date (day-month-year) in the form of DD-MM-YYYY, and in this case the appointment<br>
will be displayed only in the year YYYY.<br>
For the same date you can specify more appointments, they will be queued.
End Rem	
Function SetCalendarAppointment(calendar:tcalendar,date$="",app$="")
	If calendar=Null Return
	If date="" Return
	calendar.SetAppointment(date,app)
End Function
Rem
	bbdoc: Get the appointment(s) for a determinated date (DD-MM) or (DD-MM-YYYY)
	about: it returns an array of string of the appointment(s) of that @date.
End Rem
Function GetCalendarAppointment:String[](Calendar:tcalendar,date$="")
If date="" Or calendar=Null Return [""]
	Return calendar.GetAppointment(date)
End Function

Rem
bbdoc: remove all appointments
about: this function will remove all the appointments from a calendar<br>
if a @date is specified only the appointment(s) on that @date will be removed
End Rem
Function RemoveAppointments(calendar:tcalendar,date$="")
If date=""
	ClearMap(calendar.map_appointment)
Else
	MapRemove calendar.map_appointment,date
End If
End Function

Type tcalendar Extends Tproxygadget

	Global day_name$[]=["Mo","Tu","We","Th","Fr","Sa","Su"]'["Lu","Ma","Me","Gi","Ve","Sa","Do"]
	Global month_name$[]=["January","February","March","April","May","June","July","August","September","October","November","December"]
	Global month_days:Int[]=[31,28,31,30,31,30,31,31,30,31,30,31]

	Field map_dayfest:tmap=CreateMap()
	Field map_appointment:tmap=CreateMap()
	Global _fest_data$[]=["01-01","25-04","01-05","02-06","15-08","01-11","08-12","25-12","26-12"]
	Global _fest_Desc$[]=["New year","Liberation day","Worker day","Republic Day","Ferragosto","All saints","Immaculate conception","Nativity","S.Steven"]
	Global _app_data$[]
	Global _app_desc$[]
	
	Field _keepfixed:Int
	Field panel:tgadget
	Field style:Int
	Field year_dec:tgadget,year_inc:tgadget,year:tgadget
	Field month_dec:tgadget,month_inc:tgadget,month:tgadget
	Field days:tgadget[],label:tgadget[7]
	Field current_year:Int,current_month:Int,current_day:Int
	Field day_wide:Int=21,day_height:Int=21
	Field max_wide:Int=146,max_heigth:Int=191
	Field data$
	

	Method SetEnabled(sta:Int=True)

		Local k:tgadget
		
		If sta=False
			DisableGadget panel
			DisableGadget year_dec
			DisableGadget year_inc
			DisableGadget year
			DisableGadget month_dec
			DisableGadget month_inc
			DisableGadget month
			
			For k=EachIn days
				DisableGadget k
			Next
			
			For k=EachIn label
				DisableGadget k
			Next
		Else
			EnableGadget panel
			EnableGadget year_dec
			EnableGadget year_inc
			EnableGadget year
			EnableGadget month_dec
			EnableGadget month_inc
			EnableGadget month
			
			For k=EachIn days
				EnableGadget k
			Next
			For k=EachIn label
				EnableGadget k
			Next


		End If
		
	End Method
	
	Method Free()
		RemoveHook EmitEventHook,EventHandler,Self
		If panel FreeGadget panel
	
		If year_dec FreeGadget year_dec
		If year_inc FreeGadget year_inc
		If year	FreeGadget year
		If month_dec FreeGadget month_dec
		If month_inc FreeGadget month_inc
		If month FreeGadget month
		
		Local gg:tgadget
		If days
			For gg=EachIn days
				FreeGadget gg
				gg=Null
			Next
			days=Null
		End If
		
		If label
			For gg=EachIn label
				FreeGadget gg
				gg=Null
			Next
			label=Null
		End If
			
		panel=Null
		Super.Free
	End Method


	
	Function Create:tcalendar(x:Int,y:Int,w:Int,h:Int,group:tgadget,style:Int=0)
		Local sp:tcalendar=New tcalendar
		
		sp.panel =		CreatePanel(x,y,w,h,group,PANEL_BORDER)
		
		sp.year_dec=	CreateButton("<",0,0,20,20,sp.panel )
		sp.year_inc=	CreateButton(">",w-24,0,20,20,sp.panel )
		sp.year	=	CreateLabel ("year",20,0,W-44,20,sp.panel,LABEL_SUNKENFRAME|LABEL_CENTER )
		
		sp.month_dec=	CreateButton("<",0,20,20,20,sp.panel )
		sp.month_inc=	CreateButton(">",w-24,20,20,20,sp.panel )
		sp.month=		CreateLabel ("month",20,20,W-44,20,sp.panel,LABEL_SUNKENFRAME|LABEL_CENTER )
	
		Local XX:Int,YY:Int=62
		Local nam$,k:Int,lbl:tgadget,counter:Int
		
		sp._keepfixed=style ' for the moment it manages only this 'style'
		
		sp.day_wide=w/7
		sp.max_wide=w-sp.day_wide
		
		Local dyear:Int,dmonth:Int,dday:Int,ddate:String
		Local dinfo:String[]
		
		ddate=Lower(CurrentDate())'"%d %m %Y"))
		'with my CurrentDate() hack everything will be faster...
		'so at the moment I need to convert the months in an index...
		dinfo=ddate.split(" ")
	
		Local mcounter:Int=0
		For Local ch$=EachIn month_name$
			mcounter:+1
	'		If dinfo[1]=Lower(ch) dinfo[1]=String(mcounter)
			If Left(dinfo[1],3)=Left(Lower(ch),3) dinfo[1]=String(mcounter)'for linux compatibility
		Next
			
		ddate=dinfo[0]+" "+dinfo[1]+" "+dinfo[2]

		sp.current_day=	Int(dinfo[0])
		sp.current_month=Int(dinfo[1])
		sp.current_year=	Int(dinfo[2])
		
		SetGadgetText sp.year,dinfo[2]
		SetGadgetText sp.month,month_name[Int(dinfo[1])-1]
	
		For counter=0 Until 7
			lbl=CreateLabel(day_name[counter],xx,yy-20,sp.day_wide,18,sp.panel,LABEL_CENTER)
			xx:+sp.day_wide
			If counter=6 SetGadgetColor lbl,128,128,128
			sp.label[counter]=lbl
	
		Next
		
		Local julian_time:Int=Conv_Date2Julian(ddate)
		Local day_week:Int=DayOfTheWeek(julian_time) ' 0 : Sunday, 1 : Monday...
		
		xx=0'day_week*sp.day_wide
		sp.DrawCalendar(xx,dinfo) ' it reports the CURRENT DATA
		AddHook EmitEventHook,EventHandler,sp
		sp.data=ddate
		sp.SetProxy sp.panel
		
		'add festivity
		'change the global array for your purposes
		
		For Local s:Int=0 Until _Fest_data.length
				MapInsert(sp.map_dayfest,_fest_data[s],_fest_desc[s])
		Next
		
		Return sp
	End Function
	
	Method DrawCalendar(xx:Int=0,info:String[])
		Local yy:Int=62,nam$,k:Int
		Local max_days:Int=month_days[Int(info[1])-1]
		If AnnoBisesto(Int(info[2]))=1 And Int(info[1])=2 Then max_days=29

		If days<>Null
			For Local sj:tgadget=EachIn days
				If sj<>Null 
					FreeGadget sj
					sj=Null
				End If

			Next
			days=Null
			GCCollect()
		End If

		K=0
		
		days=days[..max_days]
		
		Local festday$[],_array_des$[],_tool$
		
		While k<max_days
			nam=String(k+1)
			
			_tool=""
					
			days[k]=CreateButton(nam$,XX,yy,day_wide,day_height,panel)
			SetGadgetColor days[k],200,200,200
			
			If k=Int(info[0])-1 And _keepfixed=0 
				SetGadgetColor days[k],125,125,230
				SetGadgetColor days[k],255,255,255,False
			End If
	
			'check for fest day
						
			For Local fd:String=EachIn MapKeys(map_dayfest)
				festday=fd.split("-")
				
				If k=Int(festday[0])-1 And Int(info[1])=Int(festday[1]) 	
						SetGadgetColor days[k],128,128,128
						SetGadgetToolTip days[k],String(MapValueForKey(map_dayfest,fd))
				End If
				
			Next
	
				
			'check for appointment day 
			
			For Local fd:String=EachIn MapKeys(map_appointment)
				festday=fd.split("-")
			
				If festday.length=2

					If k=Int(festday[0])-1 And Int(info[1])=Int(festday[1])
						SetGadgetColor days[k],0,200,20
						_array_des=String[](MapValueForKey(map_appointment,fd))
						For Local sas$=EachIn _array_des
							If sas<>"" _tool=_tool+sas+"~n"
						Next
						_tool=_tool[..Len(_tool)-1]
						SetGadgetToolTip days[k],_tool
					End If
				ElseIf festday.length=3
					'Print "This is a FIXED appointment DD-MM-YYYY"
					If k=Int(festday[0])-1 And Int(info[1])=Int(festday[1]) And Int(info[2])=Int(festday[2])
						SetGadgetColor days[k],0,200,20
						_array_des=String[](MapValueForKey(map_appointment,fd))
						For Local sas$=EachIn _array_des
							If sas<>"" _tool=_tool+sas+"~n"
						Next
						_tool=_tool[..Len(_tool)-1]
						SetGadgetToolTip days[k],_tool
					End If


				End If

					
				
			Next

	
			xx:+day_wide
			If xx>max_wide xx=0;yy:+day_height
			
			k:+1
			
		Wend	
	End Method
	
	Method GetAppointment$[](_Dat$="")
		If _dat="" Return ["Nothing"]
		Return String[](MapValueForKey(map_appointment,_dat))
	End Method
	
	Method SetAppointment(_dat$="",_des$="")
		If _dat="" Or _des="" Return
		'check if any appointments is already present and add it to a string array
		Local _array_des$[]
		_array_des=String[](MapValueForKey(map_appointment,_dat))
		_array_des=_array_des[.._array_des.length+1]
		_array_des[_array_des.length-1]=_des

		MapInsert(map_appointment,_dat,_array_des)
	End Method
	
	Method Activate(command:Int)
		SetDate()

	End Method

	
	Method SetDate()
	
		If current_month>12 current_month=1
		If current_month<1 current_month=12
	
		Local newdate$=Right("00"+String(current_day),2)+" "+Right("00"+String(current_month),2)+" "+String(current_year)
		
		SetGadgetText year,String(current_year)
		SetGadgetText month,month_name[current_month-1]
		
		Local xx:Int,dinfo:String[]=[String(current_Day),String(current_month),String(current_year)]
	
		Local julian_time:Int=Conv_Date2Julian("01 "+dinfo[1]+" "+dinfo[2])'the first day of the month
		Local day_week:Int=DayOfTheWeek(julian_time)
		
		
		xx=day_week*day_wide
		
		DrawCalendar(xx,dinfo)
		data=newdate
				
		'SetGadgetExtra Self,data
		'Print "Gadget extra : "+String(GadgetExtra(Super))
	End Method
	
	
	Function eventHandler:Object( pID%, pData:Object, pContext:Object )
		Local pEvent:TEvent = TEvent(pData)
		Local obj:tcalendar=tcalendar(pContext)
		
		If pEvent
		
				
			Select pEvent.Source
				Case obj.year_Inc
				'	Print "Anno +"
					obj.current_year:+1
					obj.SetDate()
					pevent.extra=obj.data
					pevent.source=obj
					Return pevent

						
				Case obj.year_dec
				'	Print "Anno -"
					obj.current_year:-1
					obj.SetDate()
					pevent.extra=obj.data
					pevent.source=obj
					Return pevent

				Case obj.month_Inc
				'	Print "Mese +"
					obj.current_month:+1
					obj.SetDate()
					pevent.extra=obj.data
					pevent.source=obj					
					Return pevent

				Case obj.month_dec
					'Print "Mese -"
					obj.current_month:-1
					obj.SetDate()
					pevent.extra=obj.data
					pevent.source=obj
					Return pevent

			End Select			

			For Local dgad:tgadget=EachIn obj.days
				If pevent.Source=dgad
					'Print "Pressed DAY: "+GadgetText(dgad)
					obj.current_day=Int(GadgetText(dgad))
					obj.SetDate()
					pevent.extra=obj.data
					pevent.source=obj
					Return pevent
				End If
			Next
			
			
		End If
		
		Return pData
	EndFunction

	
End Type

Function AnnoBisesto:Int(anno:Int=0)
If anno=0 Return 0
Local bisesto:Int=0
	If (anno Mod 4)=0 bisesto=1
	If (anno Mod 100)=0
		If (anno Mod 400)=0
			bisesto=1
		Else
			bisesto=0
		End If
	End If
	Return bisesto
End Function

Function Conv_Date2Julian:Int(_data$="")
	If _data$="" Return 0

	Local year:Int,month:Int,day:Int
	Local _din$[]=_Data.split(" ")
	year=Int(_din[2])
	month=Int(_din[1])
	day=Int(_din[0])
	
	Local JulianDate:Int
	' conversion taken from a website (lost link)
	JulianDate = 367 * Year - ((7 * (Year + 5001 + ((Month - 9) / 7))) / 4) + ((275 * Month) / 9) + Day + 1729777
	
	Return JulianDate
End Function

Function DayOfTheWeek:Int(pjulian:Int)
	
	Local Jt:Float=Float(pjulian)+1.5
	Return (jt Mod 7)

End Function

PS: after reading the SebHoll post I just realized how many 'bugs' I've discovered (not really all bugs only visual incoherency...the really bug is on Linux the 'decolouring' effect on buttons and label...these are very annoying, while the remain can be fixed via ?mac / ?linux directives). Sorry! :P

SebHoll

(Posted 2009) [#10]

the really bug is on Linux the 'decolouring' effect on buttons and label...these are very annoying

Just letting you know that I've already spotted this one...

degac

(Posted 2009) [#11]

Yes, I've read your post about the decolouring effect. I didnt' mean to make pression on you to fix it - initially I was thinking I'm made some mess with events handling on my system!
I've you tried to use FLTK under windows to see if the bug is the same or not? (I've made some 'really-messy-things' on my Windows machine, so every time I try to use FLTK I've got a list of bugs....I must 'reinstall' FLTK module)
As I have your attention (:-D) there are some 'fixes'
http://www.blitzbasic.com/Community/posts.php?topic=84981#960607 (about events of labels)
http://www.blitzbasic.com/Community/posts.php?topic=84527#955108 (about Requester)

For the latter I would know if possible to create a command (like SetFolder()) to setup the real desktop name without changing manually the .c source code & rebuild it*...my C skills are not so high (and this is the reason of the mess on my machines of FLTK module!)

* = This of course requires user manually changes it, but unless there is a way to determine the 'user, desktop, documents' folder in secure way (sorry but Brucey's Volume solution doesnt' work correctly on localized linux distribution) is better than nothing.

Thanks!

SebHoll

(Posted 2009) [#12]

Hi degac,

Yep - the bug is the same as on Windows, but I've managed to track it down and fix it now... :P

Had a closer look at the calendar code, though, today and thought I'd tidy a few things up. The constant freeing and creation of the button is not very nice for the memory manager (and leaky MaxGUI drivers :P), so I've attempted to implement a system which reuses a grid of already created icons.

Also, I've attempted to improve the positioning of the gadgets when the calendar is resized. Everything appears to be working as it did, but please let me know if it isn't.

Rem
		Calendar gadget
		
		degac 
		07 jun 2009		first release, some basic fixes
		08 jun 2009		the Calendar Gadget returns (every time you click/change the date) the new date
					in the EventExtra field
					you can have multiple appointments in the same date (dd-mm)
					you can have 'fixed' appointment for a specific year (dd-mm-yyyy)
End Rem

SuperStrict
Import MaxGUI.Drivers

Local window:TGadget = CreateWindow("Calendar v. 1.1",100,100,500,300,,window_titlebar|window_center|WINDOW_RESIZABLE)
Local data:TCalendar = CreateCalendar(10,40,,,window)
SetGadgetLayout data, EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED
Local label:TGadget = CreateLabel("Label",10,5,200,25,window)

'this method to set an Appointment-reminder on the calendar
'I need to find an official MaxGUI command to implement this
'probably AddGadgetItem calendar,"day-month:description"

SeTCalendarAppointment(data,"10-06","1. Test application!")
SeTCalendarAppointment(data,"10-06","2. Second appointment...~nRemember to conquer the world!")
SeTCalendarAppointment(data,"10-06","3. Buy the milk")
SeTCalendarAppointment(data,"12-06","World launch!")
SeTCalendarAppointment(data,"09-06-2009","This is a fixed date")

'RemoveAppointments(data,"12-06")

RedrawGadget data 'you need to 'redraw' the gadget to see the appointments set for the current month

While True
	WaitEvent
		Select EventID()
		
		Case event_gadgetaction
	
			If EventSource() = data
					SetGadgetText label,String(EventExtra())
			End If
			
						
		Case event_windowclose
			If EventSource() = window End
		End Select
Wend

End

Rem
bbdoc: Create a basic calendar.
about: Displays a simple calendar for year/month reporting the (eventual) appointments or festivity<br>
it returns the new date in the @{TEvent.Extra} field.

@x, @y are the initial position, while @w and @h (if specified) are the width and the height of the 
calendar.

Remember that there are @minimum size dimensions for wide and height.

@style: if 1 will no shown the day selected.

End Rem
Function CreateCalendar:TCalendar(x:Int,y:Int,w:Int = 152,h:Int = 191,group:TGadget = Null,_style:Int = 0)
	If group = Null Return Null	
	Local min_w:Int = 152,min_h:Int = 191
	If w<min_w w = min_w
	If h<min_h Or h>min_h h = min_h
	Return TCalendar.Create(x,y,w,h,group,_style)
End Function
Rem
bbdoc: Set an appointment for the date (DD-MM) or (DD-MM-YYYY)
about: you can specify a simple date (Day-Month) and the appointment will be repeated every year.<br>
Or you can specify a complete date (day-month-year) in the form of DD-MM-YYYY, and in this case the appointment<br>
will be displayed only in the year YYYY.<br>
For the same date you can specify more appointments, they will be queued.
End Rem	
Function SeTCalendarAppointment(calendar:TCalendar,date$ = "",app$ = "")
	If calendar = Null Return
	If date = "" Return
	calendar.SetAppointment(date,app)
End Function
Rem
	bbdoc: Get the appointment(s) for a determinated date (DD-MM) or (DD-MM-YYYY)
	about: it returns an array of string of the appointment(s) of that @date.
End Rem
Function GeTCalendarAppointment:String[](Calendar:TCalendar,date$ = "")
If date = "" Or calendar = Null Return [""]
	Return calendar.GetAppointment(date)
End Function

Rem
bbdoc: remove all appointments
about: this function will remove all the appointments from a calendar<br>
if a @date is specified only the appointment(s) on that @date will be removed
End Rem
Function RemoveAppointments(calendar:TCalendar,date$ = "")
If date = ""
	ClearMap(calendar.map_appointment)
Else
	MapRemove calendar.map_appointment,date
End If
End Function

Type TCalendar Extends Tproxygadget

	Global day_name$[] = ["Mo","Tu","We","Th","Fr","Sa","Su"]'["Lu","Ma","Me","Gi","Ve","Sa","Do"]
	Global month_name$[] = ["January","February","March","April","May","June","July","August","September","October","November","December"]
	Global month_days:Int[] = [31,28,31,30,31,30,31,31,30,31,30,31]

	Field map_dayfest:tmap = CreateMap()
	Field map_appointment:tmap = CreateMap()
	Global _fest_data$[] = ["01-01","25-04","01-05","02-06","15-08","01-11","08-12","25-12","26-12"]
	Global _fest_Desc$[] = ["New year","Liberation day","Worker day","Republic Day","Ferragosto","All saints","Immaculate conception","Nativity","S.Steven"]
	Global _app_data$[]
	Global _app_desc$[]
	
	Field _keepfixed:Int
	Field panel:TGadget
	Field style:Int
	Field year_dec:TGadget,year_inc:TGadget,year:TGadget
	Field month_dec:TGadget,month_inc:TGadget,month:TGadget
	Field day_panel:TGadget
	Field days:TGadget[42],label:TGadget[7]
	Field current_year:Int,current_month:Int,current_day:Int
	Field day_wide:Int = 21,day_height:Int = 21
	Field max_wide:Int = 146,max_heigth:Int = 191
	Field data$
	

	Method SetEnabled(sta:Int = True)

		Local k:TGadget
		
		If sta = False
			DisableGadget panel
			DisableGadget year_dec
			DisableGadget year_inc
			DisableGadget year
			DisableGadget month_dec
			DisableGadget month_inc
			DisableGadget month
			
			For k = EachIn days
				DisableGadget k
			Next
			
			For k = EachIn label
				DisableGadget k
			Next
		Else
			EnableGadget panel
			EnableGadget year_dec
			EnableGadget year_inc
			EnableGadget year
			EnableGadget month_dec
			EnableGadget month_inc
			EnableGadget month
			
			For k = EachIn days
				EnableGadget k
			Next
			For k = EachIn label
				EnableGadget k
			Next


		End If
		
	End Method
	
	Method Free()
		RemoveHook EmitEventHook,EventHandler,Self
		If panel FreeGadget panel
	
		If year_dec FreeGadget year_dec
		If year_inc FreeGadget year_inc
		If year	FreeGadget year
		If month_dec FreeGadget month_dec
		If month_inc FreeGadget month_inc
		If month FreeGadget month
		
		Local gg:TGadget
		If days
			For gg = EachIn days
				FreeGadget gg
				gg = Null
			Next
			days = Null
		End If
		
		If label
			For gg = EachIn label
				FreeGadget gg
				gg = Null
			Next
			label = Null
		End If
			
		panel = Null
		Super.Free
	End Method


	
	Function Create:TCalendar(x:Int,y:Int,w:Int,h:Int,group:TGadget,style:Int = 0)
		Local sp:TCalendar = New TCalendar
		
		sp.panel = 		CreatePanel(x,y,w,h,group,PANEL_BORDER)
		
		w =  sp.panel.ClientWidth()
		h =  sp.panel.ClientHeight()
		
		HideGadget sp.panel
		SetPanelColor sp.panel, 255, 255, 255
		
		sp.year_dec = 	CreateButton("<",0,0,20,20,sp.panel )
		SetGadgetLayout sp.year_dec, EDGE_ALIGNED, EDGE_CENTERED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.year_inc = 	CreateButton(">",w-20,0,20,20,sp.panel )
		SetGadgetLayout sp.year_inc, EDGE_CENTERED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.year	 = 	CreateLabel ("year",20,0,W-40,20,sp.panel,LABEL_CENTER )
		SetGadgetLayout sp.year, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.month_dec = 	CreateButton("<",0,20,20,20,sp.panel )
		SetGadgetLayout sp.month_dec, EDGE_ALIGNED, EDGE_CENTERED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.month_inc = 	CreateButton(">",w-20,20,20,20,sp.panel )
		SetGadgetLayout sp.month_inc, EDGE_CENTERED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.month = 		CreateLabel ("month",20,20,W-40,20,sp.panel,LABEL_CENTER )
		SetGadgetLayout sp.month, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
	
		SetGadgetLayout CreateLabel("",0,40,W,2,sp.panel,LABEL_SEPARATOR), EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
	
		Local XX:Int,YY:Int = 62
		Local nam$,k:Int,lbl:TGadget,counter:Int
		
		sp._keepfixed = style ' for the moment it manages only this 'style'
		
		sp.day_wide = w/7
		sp.max_wide = w-sp.day_wide
		
		Local dyear:Int,dmonth:Int,dday:Int,ddate:String
		Local dinfo:String[]
		
		ddate = CurrentDate().ToLower()'"%d %m %Y"))
		'with my CurrentDate() hack everything will be faster...
		'so at the moment I need to convert the months in an index...
		dinfo = ddate.split(" ")
	
		Local mcounter:Int = 0
		For Local ch$ = EachIn month_name$
			mcounter:+1
	'		If dinfo[1] = Lower(ch) dinfo[1] = String(mcounter)
			If Left(dinfo[1],3) = ch.ToLower()[..3] Then dinfo[1] = String(mcounter)'for linux compatibility
		Next
			
		ddate = dinfo[0]+" "+dinfo[1]+" "+dinfo[2]

		sp.current_day = 	Int(dinfo[0])
		sp.current_month = Int(dinfo[1])
		sp.current_year = 	Int(dinfo[2])
		
		SetGadgetText sp.year,dinfo[2]
		SetGadgetText sp.month,month_name[Int(dinfo[1])-1]
		
		Local tmpOffset:Int =  (w-(sp.day_wide*7))/2
		
		sp.day_panel =  CreatePanel( tmpOffset, yy-20, w-(tmpOffset*2), sp.day_height*6, sp.panel )
		SetGadgetLayout sp.day_panel, EDGE_ALIGNED, EDGE_RELATIVE, EDGE_ALIGNED, EDGE_ALIGNED
		
		For counter = 0 Until 7
			lbl = CreateLabel(day_name[counter],xx,0,sp.day_wide,18,sp.day_panel,LABEL_CENTER)
			SetGadgetLayout lbl,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_ALIGNED,EDGE_CENTERED
			xx:+sp.day_wide
			If counter = 6 SetGadgetColor lbl,128,128,128
			sp.label[counter] = lbl
	
		Next
		
		Local julian_time:Int = Conv_Date2Julian(ddate)
		Local day_week:Int = DayOfTheWeek(julian_time) ' 0 : Sunday, 1 : Monday...
		
		For Local i:Int =  0 Until 42
			sp.days[i] =  CreateButton("",(i Mod 7) * sp.day_wide,20+(i/7)*sp.day_height,sp.day_wide,sp.day_height,sp.day_panel)
			SetGadgetLayout sp.days[i],EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE
		Next
		
		sp.DrawCalendar(-1,dinfo) ' it reports the CURRENT DATA
		AddHook EmitEventHook,EventHandler,sp
		sp.data = ddate
		sp.SetProxy sp.panel
		
		'add festivity
		'change the global array for your purposes
		
		For Local s:Int = 0 Until _Fest_data.length
				MapInsert(sp.map_dayfest,_fest_data[s],_fest_desc[s])
		Next
		
		ShowGadget sp.panel
		Return sp
	End Function
	
	Method DrawCalendar(day_offset:Int = 0,info:String[])
		Local yy:Int = 62,nam$,k:Int
		Local max_days:Int = month_days[Int(info[1])-1]
		If AnnoBisesto(Int(info[2])) = 1 And Int(info[1]) = 2 Then max_days = 29
		
		Local festday$[],_array_des$[],_tool$
		
		For Local k:Int =  0 Until days.length
			If k> =  day_offset And k < (max_days+day_offset) Then
					
				nam = String((k-day_offset)+1)
				SetGadgetText days[k], nam
				
				_tool = ""
				
				SetGadgetColor days[k],200,200,200
				
				If k = Int(info[0])-1 And _keepfixed = 0 
					SetGadgetColor days[k],125,125,230
					SetGadgetColor days[k],255,255,255,False
				End If
		
				'check for fest day
							
				For Local fd:String = EachIn MapKeys(map_dayfest)
					festday = fd.split("-")
					
					If k = Int(festday[0])-1 And Int(info[1]) = Int(festday[1]) 	
							SetGadgetColor days[k],128,128,128
							SetGadgetToolTip days[k],String(MapValueForKey(map_dayfest,fd))
					End If
					
				Next
		
					
				'check for appointment day 
				
				For Local fd:String = EachIn MapKeys(map_appointment)
					festday = fd.split("-")
				
					If festday.length = 2
	
						If k = Int(festday[0])-1 And Int(info[1]) = Int(festday[1])
							SetGadgetColor days[k],0,200,20
							_array_des = String[](MapValueForKey(map_appointment,fd))
							For Local sas$ = EachIn _array_des
								If sas<>"" _tool = _tool+sas+"~n"
							Next
							_tool = _tool[..Len(_tool)-1]
							SetGadgetToolTip days[k],_tool
						End If
					ElseIf festday.length = 3
						'Print "This is a FIXED appointment DD-MM-YYYY"
						If k = Int(festday[0])-1 And Int(info[1]) = Int(festday[1]) And Int(info[2]) = Int(festday[2])
							SetGadgetColor days[k],0,200,20
							_array_des = String[](MapValueForKey(map_appointment,fd))
							For Local sas$ = EachIn _array_des
								If sas<>"" _tool = _tool+sas+"~n"
							Next
							_tool = _tool[..Len(_tool)-1]
							SetGadgetToolTip days[k],_tool
						End If
	
	
					End If
	
						
					
				Next
				
				If GadgetHidden(days[k]) Then ShowGadget(days[k])
				
			Else
				If Not GadgetHidden(days[k]) Then HideGadget(days[k])
			EndIf
			
		Next
	End Method
	
	Method GetAppointment$[](_Dat$ = "")
		If _dat = "" Return ["Nothing"]
		Return String[](MapValueForKey(map_appointment,_dat))
	End Method
	
	Method SetAppointment(_dat$ = "",_des$ = "")
		If _dat = "" Or _des = "" Return
		'check if any appointments is already present and add it to a string array
		Local _array_des$[]
		_array_des = String[](MapValueForKey(map_appointment,_dat))
		_array_des = _array_des[.._array_des.length+1]
		_array_des[_array_des.length-1] = _des

		MapInsert(map_appointment,_dat,_array_des)
	End Method
	
	Method Activate(command:Int)
		SetDate()

	End Method

	
	Method SetDate()
	
		If current_month>12 current_month = 1
		If current_month<1 current_month = 12
	
		Local newdate$ = Right("00"+String(current_day),2)+" "+Right("00"+String(current_month),2)+" "+String(current_year)
		
		SetGadgetText year,String(current_year)
		SetGadgetText month,month_name[current_month-1]
		
		Local xx:Int,dinfo:String[] = [String(current_Day),String(current_month),String(current_year)]
	
		Local julian_time:Int = Conv_Date2Julian("01 "+dinfo[1]+" "+dinfo[2])'the first day of the month
		Local day_week:Int = DayOfTheWeek(julian_time)
		
		DrawCalendar(day_week,dinfo)
		data = newdate
				
		'SeTGadgetExtra Self,data
		'Print "Gadget extra : "+String(GadgetExtra(Super))
	End Method
	
	
	Function eventHandler:Object( pID%, pData:Object, pContext:Object )
		Local pEvent:TEvent =  TEvent(pData)
		Local obj:TCalendar = TCalendar(pContext)
		
		If pEvent
		
				
			Select pEvent.Source
				Case obj.year_Inc
				'	Print "Anno +"
					obj.current_year:+1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent

						
				Case obj.year_dec
				'	Print "Anno -"
					obj.current_year:-1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent

				Case obj.month_Inc
				'	Print "Mese +"
					obj.current_month:+1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj					
					Return pevent

				Case obj.month_dec
					'Print "Mese -"
					obj.current_month:-1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent

			End Select			

			For Local dgad:TGadget = EachIn obj.days
				If pevent.Source = dgad
					'Print "Pressed DAY: "+GadgetText(dgad)
					obj.current_day = Int(GadgetText(dgad))
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent
				End If
			Next
			
			
		End If
		
		Return pData
	EndFunction

	
End Type

Function AnnoBisesto:Int(anno:Int = 0)
If anno = 0 Return 0
Local bisesto:Int = 0
	If (anno Mod 4) = 0 bisesto = 1
	If (anno Mod 100) = 0
		If (anno Mod 400) = 0
			bisesto = 1
		Else
			bisesto = 0
		End If
	End If
	Return bisesto
End Function

Function Conv_Date2Julian:Int(_data$ = "")
	If _data$ = "" Return 0

	Local year:Int,month:Int,day:Int
	Local _din$[] = _Data.split(" ")
	year = Int(_din[2])
	month = Int(_din[1])
	day = Int(_din[0])
	
	Local JulianDate:Int
	' conversion taken from a website (lost link)
	JulianDate =  367 * Year - ((7 * (Year + 5001 + ((Month - 9) / 7))) / 4) + ((275 * Month) / 9) + Day + 1729777
	
	Return JulianDate
End Function

Function DayOfTheWeek:Int(pjulian:Int)
	
	Local Jt:Float = Float(pjulian)+1.5
	Return (jt Mod 7)

End Function

degac

(Posted 2009) [#13]

Very clever solution!
Nice - simple and efficient, I like it!

degac

(Posted 2009) [#14]

I've just fixed some little bugs on displaying correctly all the days and changed GetAppointment/RemoveAppointments to handle a single appointment
Added also description to add it to module.

Rem
		Calendar gadget
		
		degac + sebholl gadget redraw improvements
		
		07 jun 2009		first release, some basic fixes
		08 jun 2009		the Calendar Gadget returns (every time you click/change the date) the new date
					in the EventExtra field
					you can have multiple appointments in the same date (dd-mm)
					you can have 'fixed' appointment for a specific year (dd-mm-yyyy)
					
		13 jun 2009		SetGadgetColor support
					Some bug fix with calendar length & panel
					CreateCalendar has 2 styles
					- WEEKEND (1) : the SUNDAY and SATURDAY label are both 'coloured'
					- HIDDEN  (2) : the selected day is not showed on the calendar	
					Changed GetCalendarAppointment & RemoveAppointments to get / remove a single appointment
					Appointments are 'numbered' and displayed automatically
		
End Rem

SuperStrict
Import MaxGUI.Drivers

Local window:TGadget = CreateWindow("Calendar v. 1.1",100,100,500,300,,window_titlebar|window_center|WINDOW_RESIZABLE)
Local data:TCalendar = CreateCalendar(10,40,,,window)
Local data2:TCalendar = CreateCalendar(210,40,,,window,WEEKEND|HIDDEN)
SetGadgetLayout data, EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE
Local label:TGadget = CreateLabel("Label",10,5,200,25,window)

SetGadgetColor data,200,200,200
SetGadgetLayout data2, EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE
Local label2:TGadget = CreateLabel("Label",210,5,200,25,window)

'this method to set an Appointment-reminder on the calendar

SetCalendarAppointment(data,"10-06","Test application!")
SetCalendarAppointment(data,"10-06","Second appointment...~nRemember to conquer the world!")
SetCalendarAppointment(data,"10-06","Buy the milk")

SetCalendarAppointment(data,"12-06","World launch!")

SetCalendarAppointment(data,"09-06-2009","This is a fixed date")

RemoveAppointments(data,"10-06",2)

'RemoveAppointments(data,"12-06")

RedrawGadget data 'you need to 'redraw' the gadget to see the appointments set for the current month
RedrawGadget data2

Local app$[]=GetCalendarAppointment(data,"10-06",1)

For Local ss$=EachIn app
	Print ss
Next


While True
	WaitEvent
		Select EventID()
		
		Case event_gadgetaction
	
			If EventSource() = data
					SetGadgetText label,String(EventExtra())
			End If
			
			If EventSource() = data2
					SetGadgetText label2,String(EventExtra())
			End If
			
						
		Case event_windowclose
			If EventSource() = window End
		End Select
Wend

End
'SuperStrict
'Import MaxGUI.MaxGUI
'Import brl.retro
Rem
bbdoc: Create a basic calendar.
about: Displays a simple calendar for year/month reporting the (eventual) appointments or festivity<br>
it returns the new date in the @{TEvent.Extra} field.

@x, @y are the initial position, while @w and @h (if specified) are the width and the height of the 
calendar.

Remember that there are @minimum size dimensions for wide and height.

[ @Style | @Description 
* WEEKEND | Saturday and Sunday are coloured
* HIDDEN | The day selected is not shown 
]
<br>
See also: #SetCalendarAppointment, #GetCalendarAppointment, #RemoveAppointments
End Rem
Function CreateCalendar:TCalendar(x:Int,y:Int,w:Int = 152,h:Int = 191,group:TGadget = Null,_style:Int = 0)
	If group = Null Return Null	
	Local min_w:Int = 152,min_h:Int = 191
	If w<min_w w = min_w
	If h<min_h Or h>min_h h = min_h
	Return TCalendar.Create(x,y,w,h,group,_style)
End Function
Rem
bbdoc: Set an appointment for the date (DD-MM) or (DD-MM-YYYY)
about: You can specify a simple date (Day-Month) and the appointment will be repeated every year.<br>
Or you can specify a complete date (day-month-year) in the form of DD-MM-YYYY, and in this case the appointment will be displayed only in the year YYYY.<br>
For the same date you can specify more appointments, they will be queued.<br>

See also: #CreateCalendar, #GetCalendarAppointment, #RemoveAppointments
End Rem	
Function SetCalendarAppointment(calendar:TCalendar,date$ = "",app$ = "")
	If calendar = Null Return
	If date = "" Return
	calendar.SetAppointment(date,app)
End Function
Rem
	bbdoc: Get the appointment(s) for a determinated date (DD-MM) or (DD-MM-YYYY)
	about: It returns an array of string of the appointment(s) of that @date.<br>
	If @index is specified ONLY the appointment number Index will be returned. Index is between 1 and number of appointments.<br>
	
	See also: #CreateCalendar, #SetCalendarAppointment, #RemoveAppointments
End Rem
Function GetCalendarAppointment:String[](Calendar:TCalendar,date$ = "",index:Int=-1)
If date = "" Or calendar = Null Return [""]
	Return calendar.GetAppointment(date,index-1)
End Function

Rem
bbdoc: Remove all appointments
about: This function will remove all the appointments from a calendar<br>
If a @date is specified only the appointment(s) on that @date will be removed<br>
If @index is specified ONLY the appointment number Index will be deleted. Index is between 1 and number of appointments.<br>

See also: #CreateCalendar, #SetCalendarAppointment, #GetCalendarAppointment
End Rem
Function RemoveAppointments(calendar:TCalendar,date$ = "",index:Int=-1)
If date = ""
	ClearMap(calendar.map_appointment)
Else
	If index=-1
		MapRemove calendar.map_appointment,date
	Else
		'remove the INDEX appointments (0..n)
		index:-1
		Local _array_des$[],_new_array$[]
		_array_des = String[](MapValueForKey(calendar.map_appointment,date))
		If index>=0 And index<_Array_des.length
		_array_des[index]=""
			Local coco:Int
			For Local co$=EachIn _Array_Des
				If co<>""
				_new_array=_new_array[..coco+1]
				_new_array[coco]=co
				coco:+1
				End If
			Next
			MapRemove calendar.map_appointment,date
			MapInsert calendar.map_appointment,date,_new_Array
		
		End If		
	End If
End If
End Function

	Const WEEKEND:Int=1
	Const HIDDEN:Int=2


Type TCalendar Extends Tproxygadget

	Global day_name$[] = ["Mo","Tu","We","Th","Fr","Sa","Su"]'["Lu","Ma","Me","Gi","Ve","Sa","Do"]
	Global month_name$[] = ["January","February","March","April","May","June","July","August","September","October","November","December"]
	Global month_days:Int[] = [31,28,31,30,31,30,31,31,30,31,30,31]

	Field map_dayfest:tmap = CreateMap()
	Field map_appointment:tmap = CreateMap()
	Field _fest_data$[] = ["01-01","06-01","25-04","01-05","02-06","15-08","01-11","08-12","25-12","26-12"]
	Field _fest_Desc$[] = ["New year","Epifany","Liberation day","Worker day","Republic Day","Ferragosto","All saints","Immaculate conception","Nativity","S.Steven"]
	Field _app_data$[]
	Field _app_desc$[]
	
	Field _keephidden:Int
	Field panel:TGadget
	Field style:Int
	Field year_dec:TGadget,year_inc:TGadget,year:TGadget
	Field month_dec:TGadget,month_inc:TGadget,month:TGadget
	Field day_panel:TGadget
	Field days:TGadget[49],label:TGadget[7]
	Field current_year:Int,current_month:Int,current_day:Int
	Field day_wide:Int = 21,day_height:Int = 21
	Field max_wide:Int = 146,max_heigth:Int = 191
	Field data$
	

	Method SetEnabled(sta:Int = True)

		Local k:TGadget
		
		If sta = False
			DisableGadget panel
			DisableGadget year_dec
			DisableGadget year_inc
			DisableGadget year
			DisableGadget month_dec
			DisableGadget month_inc
			DisableGadget month
			
			For k = EachIn days
				DisableGadget k
			Next
			
			For k = EachIn label
				DisableGadget k
			Next
		Else
			EnableGadget panel
			EnableGadget year_dec
			EnableGadget year_inc
			EnableGadget year
			EnableGadget month_dec
			EnableGadget month_inc
			EnableGadget month
			
			For k = EachIn days
				EnableGadget k
			Next
			For k = EachIn label
				EnableGadget k
			Next


		End If
		
	End Method
	
	Method Free()
		RemoveHook EmitEventHook,EventHandler,Self
		If panel FreeGadget panel
	
		If year_dec FreeGadget year_dec
		If year_inc FreeGadget year_inc
		If year	FreeGadget year
		If month_dec FreeGadget month_dec
		If month_inc FreeGadget month_inc
		If month FreeGadget month
		
		Local gg:TGadget
		If days
			For gg = EachIn days
				FreeGadget gg
				gg = Null
			Next
			days = Null
		End If
		
		If label
			For gg = EachIn label
				FreeGadget gg
				gg = Null
			Next
			label = Null
		End If
		
		_app_desc=Null
		_app_data=Null
		_fest_desc=Null
		_fest_Data=Null
		ClearMap map_dayfest
		ClearMap map_appointment
		map_dayfest=Null
		map_appointment=Null
	
		panel = Null
		Super.Free
	End Method

	Method SetColor(red:Int,green:Int,blue:Int)
		SetPanelColor panel,red,green,blue
	End Method

	
	Function Create:TCalendar(x:Int,y:Int,w:Int,h:Int,group:TGadget,style:Int = 0)
		Local sp:TCalendar = New TCalendar
		
		sp.panel = 		CreatePanel(x,y,w,h,group,PANEL_BORDER)
		
		w =  sp.panel.ClientWidth()
		h =  sp.panel.ClientHeight()
		
		HideGadget sp.panel
		SetPanelColor sp.panel, 255, 255, 255
		
		sp.year_dec = 	CreateButton("<",0,0,20,20,sp.panel )
		SetGadgetLayout sp.year_dec, EDGE_ALIGNED, EDGE_CENTERED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.year_inc = 	CreateButton(">",w-20,0,20,20,sp.panel )
		SetGadgetLayout sp.year_inc, EDGE_CENTERED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.year	 = 	CreateLabel ("year",20,0,W-40,20,sp.panel,LABEL_CENTER )
		SetGadgetLayout sp.year, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.month_dec = 	CreateButton("<",0,20,20,20,sp.panel )
		SetGadgetLayout sp.month_dec, EDGE_ALIGNED, EDGE_CENTERED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.month_inc = 	CreateButton(">",w-20,20,20,20,sp.panel )
		SetGadgetLayout sp.month_inc, EDGE_CENTERED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
		
		sp.month = 		CreateLabel ("month",20,20,W-40,20,sp.panel,LABEL_CENTER )
		SetGadgetLayout sp.month, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
	
		SetGadgetLayout CreateLabel("",0,40,W,2,sp.panel,LABEL_SEPARATOR), EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_CENTERED
	
		Local XX:Int,YY:Int = 62
		Local nam$,k:Int,lbl:TGadget,counter:Int
		
		sp._keepHidden = style&HIDDEN 'Dont' show the selected day...
		
		sp.day_wide = w/7
		sp.max_wide = w-sp.day_wide
		
		Local dyear:Int,dmonth:Int,dday:Int,ddate:String
		Local dinfo:String[]
		
		ddate = CurrentDate().ToLower()'"%d %m %Y"))
		'with my CurrentDate() hack everything will be faster...
		'so at the moment I need to convert the months in an index...
		dinfo = ddate.split(" ")
	
		Local mcounter:Int = 0
		For Local ch$ = EachIn month_name$
			mcounter:+1
			If dinfo[1][..3] = ch.ToLower()[..3] Then dinfo[1] = String(mcounter)'for linux compatibility
		Next
			
		ddate = dinfo[0]+" "+dinfo[1]+" "+dinfo[2]

		sp.current_day = 	Int(dinfo[0])
		sp.current_month = Int(dinfo[1])
		sp.current_year = 	Int(dinfo[2])
		
		SetGadgetText sp.year,dinfo[2]
		SetGadgetText sp.month,month_name[Int(dinfo[1])-1]
		
		Local tmpOffset:Int =  (w-(sp.day_wide*7))/2
		
		sp.day_panel =  CreatePanel( tmpOffset, yy-20, w-(tmpOffset*2), sp.day_height*7, sp.panel )
		SetGadgetLayout sp.day_panel, EDGE_ALIGNED, EDGE_RELATIVE, EDGE_ALIGNED, EDGE_ALIGNED
		
		For counter = 0 Until 7
			lbl = CreateLabel(day_name[counter],xx,0,sp.day_wide,18,sp.day_panel,LABEL_CENTER)
			SetGadgetLayout lbl,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_ALIGNED,EDGE_CENTERED
			xx:+sp.day_wide
			If counter = 6 SetGadgetColor lbl,128,128,128
			If STYLE&WEEKEND And counter=5 SetGadgetColor lbl,168,168,168
			sp.label[counter] = lbl
	
		Next
		
		Local julian_time:Int = Conv_Date2Julian(ddate)
		Local day_week:Int = DayOfTheWeek(julian_time) ' 0 : Sunday, 1 : Monday...
		
		For Local i:Int =  0 Until 49
			sp.days[i] =  CreateButton("",(i Mod 7) * sp.day_wide,20+(i/7)*sp.day_height,sp.day_wide,sp.day_height,sp.day_panel)
			SetGadgetLayout sp.days[i],EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE
		Next
		
		sp.DrawCalendar(-1,dinfo) ' it reports the CURRENT DATA
		AddHook EmitEventHook,EventHandler,sp
		sp.data = ddate
		sp.SetProxy sp.panel
		
		'add festivity
		'change the global array for your purposes
		
		For Local s:Int = 0 Until sp._Fest_data.length
				MapInsert(sp.map_dayfest,sp._fest_data[s],sp._fest_desc[s])
		Next
		
		ShowGadget sp.panel
		Return sp
	End Function
	
	Method DrawCalendar(day_offset:Int = 0,info:String[])
		Local yy:Int = 62,nam$,k:Int
		Local max_days:Int = month_days[Int(info[1])-1]
		If AnnoBisesto(Int(info[2])) = 1 And Int(info[1]) = 2 Then max_days = 29
		
		Local festday$[],_array_des$[],_tool$
				
		For Local k:Int =  0 Until days.length
			If k>=day_offset And k<(max_days+day_offset) Then
					
				nam = String((k-day_offset)+1)
				SetGadgetText days[k], nam
				
				_tool = ""
				
				SetGadgetColor days[k],200,200,200
				SetGadgetColor days[k],0,0,0,False
			
				If Int(GadgetText(days[k]))  = Int(info[0]) And _keephidden = 0 
					SetGadgetColor days[k],125,125,230
					SetGadgetColor days[k],255,255,255,False
				End If
		
				'check for fest day
							
				For Local fd:String = EachIn MapKeys(map_dayfest)
					festday = fd.split("-")
					
					If Int(GadgetText(days[k])) = Int(festday[0]) And Int(info[1]) = Int(festday[1]) 	
							SetGadgetColor days[k],128,128,128
							SetGadgetToolTip days[k],String(MapValueForKey(map_dayfest,fd))
					End If
					
				Next
		
					
				'check for appointment day 
				
				For Local fd:String = EachIn MapKeys(map_appointment)
					festday = fd.split("-")
				
					If festday.length = 2
	
						If Int(GadgetText(days[k])) = Int(festday[0]) And Int(info[1]) = Int(festday[1])
							SetGadgetColor days[k],0,200,20
							_array_des = String[](MapValueForKey(map_appointment,fd))
							Local coco:Int=0
							For Local sas$ = EachIn _array_des
								If sas<>"" 
									If _array_des.length>1 'more than 1 appointment
										_tool = _tool+"("+String(coco+1)+") "+sas+"~n";coco:+1
									Else
										_tool = _tool+sas+"~n"
									End If
								End If
							Next
							_tool = _tool[..Len(_tool)-1]
							SetGadgetToolTip days[k],_tool
						End If
					ElseIf festday.length = 3
						'Print "This is a FIXED appointment DD-MM-YYYY"
						If Int(GadgetText(days[k])) = Int(festday[0]) And  Int(info[1]) = Int(festday[1]) And Int(info[2]) = Int(festday[2])
							SetGadgetColor days[k],0,200,20
							_array_des = String[](MapValueForKey(map_appointment,fd))
							Local coco:Int=0
							For Local sas$ = EachIn _array_des

							If sas<>"" 
								If _Array_Des.length>1
									_tool =_tool+"("+String(coco+1)+") "+sas+"~n";coco:+1
								Else
									_tool = _tool+sas+"~n"

								End If
							End If
							Next
							_tool = _tool[..Len(_tool)-1]
							SetGadgetToolTip days[k],_tool
						End If
	
	
					End If
	
						
					
				Next
				
				If GadgetHidden(days[k]) Then ShowGadget(days[k])
				
			Else
				If Not GadgetHidden(days[k]) Then HideGadget(days[k])
			EndIf
			
		Next
	End Method
	
	Method GetAppointment$[](_Dat$ = "",index:Int=-1)
		If _dat = "" Return [""]
		
		If index=-1
			Return String[](MapValueForKey(map_appointment,_dat))
		Else
			Local _array_des$[]=String[](MapValueForKey(map_appointment,_dat))
			If index>=0 And index<_array_des.length
				Return [_array_des[index]]
			End If
		End If
	End Method
	
	Method SetAppointment(_dat$ = "",_des$ = "")
		If _dat = "" Or _des = "" Return
		'check if any appointments is already present and add it to a string array
		Local _array_des$[]
		_array_des = String[](MapValueForKey(map_appointment,_dat))
		_array_des = _array_des[.._array_des.length+1]
		_array_des[_array_des.length-1] = _des

		MapInsert(map_appointment,_dat,_array_des)
	End Method
	
	Method Activate(command:Int)
		SetDate()
	End Method

	
	Method SetDate()
		If current_month>12 current_month = 1
		If current_month<1 current_month = 12
		Local newdate$ = Right("00"+String(current_day),2)+" "+Right("00"+String(current_month),2)+" "+String(current_year)
		SetGadgetText year,String(current_year)
		SetGadgetText month,month_name[current_month-1]
		
		Local xx:Int,dinfo:String[] = [String(current_Day),String(current_month),String(current_year)]
	
		Local julian_time:Int = Conv_Date2Julian("01 "+dinfo[1]+" "+dinfo[2])'the first day of the month
		Local day_week:Int = DayOfTheWeek(julian_time)
		
		DrawCalendar(day_week,dinfo)
		data = newdate
	End Method
	
	
	Function eventHandler:Object( pID%, pData:Object, pContext:Object )
		Local pEvent:TEvent =  TEvent(pData)
		Local obj:TCalendar = TCalendar(pContext)
		
		If pEvent
		
				
			Select pEvent.Source
				Case obj.year_Inc
				'	Print "Anno +"
					obj.current_year:+1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent

						
				Case obj.year_dec
				'	Print "Anno -"
					obj.current_year:-1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent

				Case obj.month_Inc
				'	Print "Mese +"
					obj.current_month:+1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj					
					Return pevent

				Case obj.month_dec
					'Print "Mese -"
					obj.current_month:-1
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent

			End Select			

			For Local dgad:TGadget = EachIn obj.days
				If pevent.Source = dgad
					'Print "Pressed DAY: "+GadgetText(dgad)
					obj.current_day = Int(GadgetText(dgad))
					obj.SetDate()
					pevent.extra = obj.data
					pevent.source = obj
					Return pevent
				End If
			Next
			
			
		End If
		
		Return pData
	EndFunction

	
End Type

Function AnnoBisesto:Int(anno:Int = 0)
If anno = 0 Return 0
Local bisesto:Int = 0
	If (anno Mod 4) = 0 bisesto = 1
	If (anno Mod 100) = 0
		If (anno Mod 400) = 0
			bisesto = 1
		Else
			bisesto = 0
		End If
	End If
	Return bisesto
End Function

Function Conv_Date2Julian:Int(_data$ = "")
	If _data$ = "" Return 0

	Local year:Int,month:Int,day:Int
	Local _din$[] = _Data.split(" ")
	year = Int(_din[2])
	month = Int(_din[1])
	day = Int(_din[0])
	
	Local JulianDate:Int
	' conversion taken from a website (lost link)
	JulianDate =  367 * Year - ((7 * (Year + 5001 + ((Month - 9) / 7))) / 4) + ((275 * Month) / 9) + Day + 1729777
	
	Return JulianDate
End Function

Function DayOfTheWeek:Int(pjulian:Int)
	Local Jt:Float = Float(pjulian)+1.5
	Return (jt Mod 7)
End Function

GaryV

(Posted 2009) [#15]

Just curious. Is there any reason you are not using the native calendar gadget on Windows?

Ked	(Posted 2009) [#16]

Degac's method is cross-platform.

GaryV

(Posted 2009) [#17]

To appease, and still just curious, is there any reason you are not using the native calendar gadget on each platform?

degac

(Posted 2009) [#18]

To appease, and still just curious, is there any reason you are not using the native calendar gadget on each platform?

I doubt there is a 'standard' calendar gadget on every platforms. For example look at the FLTK documentation: http://www.fltk.org/doc-1.3/index.html - I didn't find any 'calendar-like' gadget.
And even on MacOS-Cocoa I haven't found anything...I found user-made solutions, bridge via-JScript with Ical and so on...
Maybe I'm blind.
Only on Windows I found the 'Month Calendar Controls' http://msdn.microsoft.com/en-us/library/bb760913(VS.85).aspx
So I think my solution is faster and easy to implement - and multiplatform.

PS: there are some little bugs to correctly display/use the calendar under Mac and Linux: Sebholl is working to fix these bugs (and some bugs are already fixed).
I found that under MacOS the size/shape of the standard buttons depends (in MaxGUI) on the 'widht/height' control: so technically under a determinated (I dont remember actually!) size the button is 'squared', otherwise is 'rounded'...I made a little hack to allow the user to choose to draw a squared (or rounded) button...maybe Sebholl & co can make it as 'standard' in MaxGUI (it doesn't affect the other platforms - as they dont' have rounded buttons).