Creating a BMax default style window with MaxGUI?

BlitzMax Forums/MaxGUI Module/Creating a BMax default style window with MaxGUI?

QuickSilva

(Posted 2009) [#1]

Is it possible to create a window that acts like a normal BMax one, i.e. one that works in an identical manner without the need to use wait events to get keyboard input and so on with the added benefit of a minimize and maximise button hence why I need to use MaxGUI. This is the only extra functionality that I need but it seems that I have to rework all of my keyboard input, screen updating code etc... to be able to use MaxGUI windows. Is this correct or am I missing something? Maybe another option is available?

Thanks for any help,

Jason.

SebHoll

(Posted 2009) [#2]

Just call EnablePolledInput(), and the normal Max2D keyboard commands should work.

QuickSilva

(Posted 2009) [#3]

I`ve seen this command mentioned before but it doesn`t seem to highlight\register in the IDE (BMax.133) like the other GUI commands do. It is also not listed in the help files.

I`m pretty sure that this is the command that I am looking for so I`m not sure why I cannot use it? Any ideas?

Jason.

klepto2

(Posted 2009) [#4]

If you're using Framework, you may need to import brl.polledinput.

maybe this code helps you a bit:

Framework MaxGui.Drivers
Import brl.glmax2d
Import brl.Timer
Import brl.EventQueue

Strict 

AppTitle = "Advanced Max2D GraphicsWindow"
GraphicsAdvanced(800,600,-1)

Global FramesPerSec:Int
Global FrameCounter:Int 
Global Start:Int 

Local X:Float = GraphicsWidth() / 2
Local Y:Float = GraphicsHeight() / 2
 
While Not AppTerminate() And Not KeyHit(KEY_ESCAPE)
	Cls
		DrawText "Mouse : " + MouseX() + ";" + MouseY() + "--> " + AppTerminate(),20,20 
		DrawText "FPS :" + FramesPerSec,20,40
		
		DrawRect x,y,10,10
		
		If KeyDown(KEY_DOWN)Y:+1
		If KeyDown(KEY_UP)Y:-1
		If KeyDown(KEY_RIGHT) x:+1
		If KeyDown(KEY_LEFT) x:-1
		
		
		UpdateFrameCounter() 	
	Flip
Wend

Print "End"
End

Function UpdateFrameCounter() 
	FrameCounter:+1 
	If MilliSecs() > Start + 1000 
		Start = MilliSecs() 
		FramesPerSec = FrameCounter 
		FrameCounter = 0 
	EndIf 
End Function


Type TGraphicsWindow
	Global _graphicswindow:TGraphicsWindow
	
	Field Window:TGadget
	Field Canvas:TGadget
	Field Timer:TTimer
	Field sized:Byte = False
	Field terminate:Byte = False
	
	Function Create:TGraphics(Width:Int,Height:Int,Refresh:Int = 60)
		Local GW:TGraphicsWindow = New TGraphicsWindow
		Local wx=(ClientWidth(Desktop())-WIDTH)/2
		Local wy=(ClientHeight(Desktop())-HEIGHT)/2
		GW.Window = CreateWindow(AppTitle,wx,wy,Width,Height,Null,WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS|WINDOW_RESIZABLE)
		GW.Canvas = CreateCanvas(0,0,ClientWidth(GW.window),ClientHeight(GW.Window),GW.window)
		SetGadgetLayout(GW.Canvas,1,1,1,1)
		If Refresh <> -1 Then 
			GW.Timer = CreateTimer(Refresh)
		End If
		GW.Setup()
		_graphicsWindow = GW
		Return CanvasGraphics(GW.Canvas)
	End Function
	
	Method SetUp()
		EnablePolledInput(canvas)
		SetGraphics CanvasGraphics(Canvas)
		AddHook EmitEventHook,eventhook,Self
	End Method
	
	Method OnEvent(event:TEvent)
	   	Select event.id
	   	Case EVENT_WINDOWSIZE
	   		sized = True
			SetGraphics CanvasGraphics(Canvas)
			SetViewport 0,0,ClientWidth(Window),ClientHeight(Window) 
			RedrawGadget(canvas)
		Case	EVENT_WINDOWCLOSE
			terminate = True
	   	End Select
   	End Method

	Method IsResized:Byte()
		If sized = True
			sized = False
			Return True
		End If
		Return False
	End Method

	Function eventhook:Object(id,data:Object,context:Object)
	   Local event:TEvent
	   Local app:TGraphicsWindow
	   event=TEvent(data)
	   app=TGraphicsWindow(context)
	   If app Then 
		app.OnEvent event	
	   End If
		Return data
	End Function
	
	Method Flip(sync:Int = 0)
		PollSystem()
		If Timer Then 
			WaitTimer(Timer)
			_max2dDriver.Flip(sync)
		Else
			_max2dDriver.Flip(sync)
		End If
	End Method
	
	Method AppTerminate:Int()
		Return terminate
	End Method
	
	
End Type

Function GraphicsAdvanced:TGraphics(Width:Int,Height:Int,Refresh:Int = -1)
	Return TGraphicsWindow.Create(Width,Height,Refresh)
End Function

Function Flip(state:Int = 0)
	TGraphicsWindow._graphicsWindow.Flip(state)
End Function

Function AppTerminate:Byte()
	Return TGraphicsWindow._graphicsWindow.AppTerminate()
End Function

QuickSilva

(Posted 2009) [#5]

OK, I`ve got it now, thanks for the help both of you :)

Jason.