Active panel with a label

BlitzMax Forums/MaxGUI Module/Active panel with a label

JoshK

(Posted 2009) [#1]

I am having some success with a property grid control using MaxGUI. I am using an active panel for the category headers. When the user clicks on the header, it shows or hides the category properties.

However, the label on the header covers up a section of the panel, and if the user clicks on this nothing happens. In theory I could use an image for the text, but that is a pretty horrific work-around. Any ideas? You can just run this code without the two bitmaps it uses, and it will work:

Import MaxGui.Drivers

Strict 

Local window:TGadget

window=CreateWindow("My Window",40,40,640,480)

Local grid:TGrid=TGrid.Create(0,0,,,window)
SetGadgetLayout grid,1,1,1,1
Local gs:TGridSection=grid.addsection("Matrix")
gs.additem("Position:")
gs.additem("Rotation:")
gs.additem("Scale:")

gs=grid.addsection("Settings")
gs.additem("Color:")
gs.additem("Material:")
gs.additem("Intensity:")
gs.additem("Health:")


While True
	WaitEvent 
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	EndSelect
Wend



Type TGrid Extends TProxyGadget
	
	Const headerheight:Int=20
	Const headerspacer:Int=1
	
	Field panel:TGadget
	Field sections:TList=New TList
	
	Global list:TList=New TList
	
	Function Create:TGrid(x=0,y=0,width=-1,height=-1,group:TGadget)
		Local grid:TGrid=New tgrid
		If width=-1 width=group.ClientWidth()-x
		If height=-1 height=group.ClientHeight()-y
		grid.panel=CreatePanel(x,y,width,height,group)
		grid.SetProxy(grid.panel)
		AddHook EmitEventHook, eventHandler, Null, 1
		list.addlast(grid)
		Return grid
	EndFunction

	Method AddSection:TGridSection(name:String)
		Local gs:TGridSection=New TGridSection
		gs.header=CreatePanel(0,0,panel.ClientWidth(),20,panel,PANEL_ACTIVE)
		SetGadgetLayout gs.header,1,1,1,0
		SetPanelColor gs.header,128,128,128
		Local label:TGadget
		label=CreateLabel(name,headerheight,2,80,20,gs.header)
		SetGadgetColor label,255,255,255,0
		SetGadgetLayout label,1,0,1,0
		gs.panel=CreatePanel(0,20,panel.ClientWidth(),2,panel)
		SetGadgetLayout gs.panel,1,1,1,0
		gs.grid=Self
		sections.addlast(gs)

		gs.imagepanel=CreatePanel(0,0,headerheight,headerheight,gs.header,PANEL_ACTIVE)		
		SetGadgetPixmap gs.imagepanel,LoadPixmap("header.bmp")
		SetGadgetLayout gs.imagepanel,1,0,1,0
		SetPanelColor gs.imagepanel,128,128,128
		
		AdjustLayout()
		Return gs
	EndMethod
	
	Method AdjustLayout()
		Local x:Int
		Local y:Int
		For Local gs:TGridSection=EachIn sections
			SetGadgetShape gs.header,0,y,panel.ClientWidth(),headerheight
			If gs.hidden
				SetGadgetPixmap gs.imagepanel,LoadPixmap("header.bmp")
				HideGadget gs.panel
				y:+headerheight+headerspacer
			Else
				SetGadgetPixmap gs.imagepanel,LoadPixmap("header2.bmp")
				SetGadgetShape gs.panel,0,y+headerheight,panel.ClientWidth(),gs.y
				ShowGadget gs.panel
				y:+headerheight+gs.y
			EndIf
		Next
	EndMethod
	
	Function eventHandler:Object( pID%, pData:Object, pContext:Object )
		Local event:TEvent = TEvent(pData)
		
		If event
			Local grid:TGrid
			Local gs:TGridSection
			For grid=EachIn TGrid.list
			For gs=EachIn grid.sections
				If gs.header=event.source Or gs.imagepanel=event.source
					Return gs.EventHook(event)
				EndIf
			Next
			Next
		EndIf
		
		Return pData
	EndFunction
	
EndType

Type TGridSection

	Const indent:Int=20

	Field grid:TGrid
	Field imagepanel:TGadget
	Field header:TGadget
	Field panel:TGadget
	Field x:Int=8
	Field y:Int=2
	Field h:Int=2
	Field hidden:Int

	Method EventHook:TEvent( event:TEvent )
		Select event.id
			Case EVENT_MOUSEUP
				toggle()
				Return Null
		EndSelect
		Return event
	EndMethod

	Method Toggle()
		If hidden show() Else hide()
	EndMethod
	
	Method Hide()
		hidden=True
		grid.AdjustLayout()
	EndMethod
	
	Method Show()
		hidden=False
		grid.AdjustLayout()
	EndMethod
	
	Method AddItem(name:String,style:Int=0)
		Local g:TGadget
		g=CreateLabel(name,indent+x,y,60,20,panel)
		SetGadgetLayout g,1,0,1,0
		g=CreateTextField(indent+x+60,y,panel.ClientWidth()-x-60-2,20,panel)
		SetGadgetLayout g,1,1,1,0
		y:+22
		'SetGadgetShape panel,0,20,GadgetGroup(panel).ClientWidth(),y
		grid.AdjustLayout()
	EndMethod	
EndType

SebHoll

(Posted 2009) [#2]

Hey,

This is looking very nice!

Have you tried calling SetGadgetSensitivity( label, SENSITIZE_MOUSE ) on the label, so that it emits mouse events?

The following appears to work as might be expected:

Import MaxGui.Drivers

Strict 

Local window:TGadget

window=CreateWindow("My Window",40,40,640,480)

Local grid:TGrid=TGrid.Create(0,0,,,window)
SetGadgetLayout grid,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED
Local gs:TGridSection=grid.addsection("Matrix")
gs.additem("Position:")
gs.additem("Rotation:")
gs.additem("Scale:")

gs=grid.addsection("Settings")
gs.additem("Color:")
gs.additem("Material:")
gs.additem("Intensity:")
gs.additem("Health:")


While True
	WaitEvent 
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	EndSelect
Wend



Type TGrid Extends TProxyGadget
	
	Const headerheight:Int=20
	Const headerspacer:Int=1
	
	Field panel:TGadget
	Field sections:TList=New TList
	
	Global list:TList=New TList
	
	Function Create:TGrid(x=0,y=0,width=-1,height=-1,group:TGadget)
		Local grid:TGrid=New tgrid
		If width=-1 width=group.ClientWidth()-x
		If height=-1 height=group.ClientHeight()-y
		grid.panel=CreatePanel(x,y,width,height,group)
		grid.SetProxy(grid.panel)
		AddHook EmitEventHook, eventHandler, Null, 1
		list.addlast(grid)
		Return grid
	EndFunction

	Method AddSection:TGridSection(name:String)
		Local gs:TGridSection=New TGridSection
		gs.header=CreatePanel(0,0,panel.ClientWidth(),20,panel,PANEL_ACTIVE)
		SetGadgetLayout gs.header,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,0
		SetPanelColor gs.header,128,128,128
		
		gs.label=CreateLabel(name,headerheight,2,80,20,gs.header)
		SetGadgetColor gs.label,255,255,255,0
		SetGadgetLayout gs.label,EDGE_ALIGNED,0,EDGE_ALIGNED,0
		SetGadgetSensitivity gs.label, SENSITIZE_MOUSE
		
		gs.panel=CreatePanel(0,20,panel.ClientWidth(),2,panel)
		SetGadgetLayout gs.panel,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,0
		gs.grid=Self
		sections.addlast(gs)

		gs.imagepanel=CreatePanel(0,0,headerheight,headerheight,gs.header,PANEL_ACTIVE)		
		SetGadgetPixmap gs.imagepanel,LoadPixmap("header.bmp")
		SetGadgetLayout gs.imagepanel,EDGE_ALIGNED,0,EDGE_ALIGNED,0
		SetPanelColor gs.imagepanel,128,128,128
		
		AdjustLayout()
		Return gs
	EndMethod
	
	Method AdjustLayout()
		Local x:Int
		Local y:Int
		For Local gs:TGridSection=EachIn sections
			SetGadgetShape gs.header,0,y,panel.ClientWidth(),headerheight
			If gs.hidden
				SetGadgetPixmap gs.imagepanel,LoadPixmap("header.bmp")
				HideGadget gs.panel
				y:+headerheight+headerspacer
			Else
				SetGadgetPixmap gs.imagepanel,LoadPixmap("header2.bmp")
				SetGadgetShape gs.panel,0,y+headerheight,panel.ClientWidth(),gs.y
				ShowGadget gs.panel
				y:+headerheight+gs.y
			EndIf
		Next
	EndMethod
	
	Function eventHandler:Object( pID%, pData:Object, pContext:Object )
		Local event:TEvent = TEvent(pData)
		
		If event
			Local grid:TGrid
			Local gs:TGridSection
			For grid=EachIn TGrid.list
			For gs=EachIn grid.sections
				Select event.source
					Case gs.header, gs.imagepanel, gs.label
						Return gs.EventHook(event)
				EndSelect
			Next
			Next
		EndIf
		
		Return pData
	EndFunction
	
EndType

Type TGridSection

	Const indent:Int=20

	Field grid:TGrid
	Field imagepanel:TGadget
	Field header:TGadget
	Field panel:TGadget
	Field label:TGadget
	
	Field x:Int=8
	Field y:Int=2
	Field h:Int=2
	Field hidden:Int

	Method EventHook:TEvent( event:TEvent )
		Select event.id
			Case EVENT_MOUSEUP
				toggle()
				Return Null
		EndSelect
		Return event
	EndMethod

	Method Toggle()
		If hidden show() Else hide()
	EndMethod
	
	Method Hide()
		hidden=True
		grid.AdjustLayout()
	EndMethod
	
	Method Show()
		hidden=False
		grid.AdjustLayout()
	EndMethod
	
	Method AddItem(name:String,style:Int=0)
		Local g:TGadget
		g=CreateLabel(name,indent+x,y+2,60,20,panel)
		SetGadgetLayout g,EDGE_ALIGNED,0,EDGE_ALIGNED,0
		g=CreateTextField(indent+x+60,y,panel.ClientWidth()-x-60-2-indent,20,panel)
		SetGadgetLayout g,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,0
		y:+22
		'SetGadgetShape panel,0,20,GadgetGroup(panel).ClientWidth(),y
		grid.AdjustLayout()
	EndMethod	
EndType

I cleaned up a minor thing whereby the text-fields didn't take into account the indentation, and swapped a few literals for their equivalent constants, but it is effectively the same code as before.

Hope this helps...

Seb

degac

(Posted 2009) [#3]

Use SetGadgetSensitivity( gadget:TGadget, flags )
...
edit: too late...

JoshK

(Posted 2009) [#4]

Thanks!

It may take a few days to finish this, but it will be really good when I post it.