GetGraphics:TGraphics() function

BlitzMax Forums/MaxGUI Module/GetGraphics:TGraphics() function

Kistjes

(Posted 2009) [#1]

Hello,

In my current MaxGUI project I have to deal with multiply canvas.
I have a list of sprites (let's say simple white rectangles) that need to be drawn in the correct canvas.
Now I can add a TList of all related sprites to the canvas but I can also add a reference to the correct CanvasGraphics to every sprite. I prefer the second approach.

Each sprite has a container and it's location is relative to it's container. The container can be another sprite or can be null. If the sprite's container is null the location is relative to the graphical object: in non MaxGUI apps it is the Graphics() object but in a MaxGUI app it's CanvasGraphics(canvas).
When the Draw() method of the sprite is called, the sprite needs to know if it's container is currently active (with the setGraphics(CanvasGraphics(canvas)) function).
There is no GetGraphics() function. How can I get the currenty active TGraphics object?

I hope the example code below helps to clarify my question...

SuperStrict

'create two windows
TMainWindow.Create(100, 100, 800, 600)
TSecondWindow.Create(460, 300, 640, 480)

CreateTimer(100)

While True
	WaitEvent()

	Select EventID()
		Case EVENT_TIMERTICK
'			DebugLog("EVENT_TIMERTICK")
			'draw the canvas content
			TGraphicalWindow.DrawAllWindows()
		Case EVENT_GADGETPAINT
'			DebugLog("EVENT_GADGETPAINT")

		Case EVENT_MOUSEMOVE
'			DebugLog("EVENT_MOUSEMOVE")

		Case EVENT_WINDOWCLOSE
			DebugLog("EVENT_WINDOWCLOSE")
			End

		Case EVENT_APPTERMINATE
			DebugLog("EVENT_APPTERMINATE")
			End
	End Select
Wend

End

'I need to have a function like this to retreive the current active graphics window
Function GetGraphics:TGraphics()
	'ok, how to do this?
	Return Null
End Function

'this type contains a full size canvas
Type TGraphicalWindow Abstract
	Global golWindows:TList
	
	Field poWindow:TGadget
	Field poCanvas:TGadget
	
	
	Method New()
		If golWindows = Null Then golWindows = CreateList()
		golWindows.AddLast(Self)
	End Method


	Function DrawAllWindows()
		For Local o:TGraphicalWindow = EachIn golWindows
			o.DrawWindow()
		Next
	End Function
	
	Method DrawWindow() Abstract
	
	Method Remove()
		FreeGadget(poCanvas)
		FreeGadget(poWindow)
		golWindows.Remove(Self)
	End Method

End Type

'This window should display two sprites:
'-one reletive to upper-left corner of canvas
'-and another one reletive to the first sprite

Type TMainWindow Extends TGraphicalWindow
	Field poSprite1:TSprite
	Field poSprite2:TSprite
	
	Function Create:TMainWindow(ix:Int, iy:Int, iWidth:Int, iHeight:Int)
		Local o:TMainWindow = New TMainWindow
		o.poWindow = CreateWindow("Main", ix, iy, iWidth, iHeight)
		o.poCanvas = CreateCanvas(0, 0, iWidth, iHeight, o.poWindow)
		Return o
	End Function

	Method DrawWindow()
		SetGraphics(CanvasGraphics(poCanvas))
		If Not poSprite1 Then
			poSprite1 = TSprite.Create(Null, 200, 100, 50, 50)
			poSprite2 = TSprite.Create(poSprite1, 100, 100, 50, 50)
		End If
		Cls

		TSprite.DrawAll()
		Flip
	End Method

End Type

'This window should show only one sprite
Type TSecondWindow Extends TGraphicalWindow
	Field poSprite:TSprite
	
	Function Create:TSecondWindow(ix:Int, iy:Int, iWidth:Int, iHeight:Int)
		Local o:TSecondWindow = New TSecondWindow
		o.poWindow = CreateWindow("Second", ix, iy, iWidth, iHeight)
		o.poCanvas = CreateCanvas(0, 0, iWidth, iHeight, o.poWindow)
		Return o
	End Function

	Method DrawWindow()
		SetGraphics(CanvasGraphics(poCanvas))
		If Not poSprite Then
			poSprite = TSprite.Create(Null, 20, 10, 150, 50)
		End If
		Cls

		TSprite.DrawAll()
		Flip
	End Method

End Type


'Simplyfied sprite type to illustrate the purpose of the TGraphicalWindow type
Type TSprite

	Global golSprites:TList
	
	Field poGraphics:TGraphics
	Field poContainer:TSprite
	Field pfRelX:Float
	Field pfRelY:Float
	Field pfWidth:Float
	Field pfHeight:Float
	
	Function Create:TSprite(oContainer:TSprite = Null, fx:Float, fy:Float, fWidth:Float, fHeight:Float)
		Local o:TSprite = New TSprite
		If golSprites = Null Then golSprites = CreateList()
		golSprites.AddLast(o)
		
		If oContainer Then
			o.poContainer = oContainer
		End If
'		Here we create the connection to the active TGraphics object
'		perhaps I can use the poContainer variable for this as well.
 		o.poGraphics = GetGraphics()

		o.pfRelX = fx
		o.pfRelY = fy
		o.pfWidth = fWidth
		o.pfHeight = fHeight
		return o
	End Function
	

	Function DrawAll()
		For Local o:TSprite = EachIn golSprites
			'only draw the sprites that are connected to the active TGraphics object
			If o.poGraphics = GetGraphics() Then o.Draw()
		Next
	End Function
	

	Method GetAbsX:Float()
		If poContainer Then Return poContainer.GetAbsX() + pfRelX
		Return pfRelX
	End Method
	
	
	Method GetAbsY:Float()
		If poContainer Then Return poContainer.GetAbsY() + pfRelY
		Return pfRelY
	End Method
	
	
	Method Draw()
		'for the sake of this demo, sprites are only drawn as white rectangles
		DrawRect(Self.GetAbsX(), Self.GetAbsY(), pfWidth, pfHeight)
	End Method
End Type

Kistjes

(Posted 2009) [#2]

Same question but without all the explanation...

To set a TGraphics object I use SetGraphics()
How do I get the active TGraphics object? There is no such command like GetGraphics:TGraphics()

kfprimm

(Posted 2009) [#3]

No there is not. Add the following to BRL.Graphics,

Function GetGraphics:TGraphics()
	Return _graphics
End Function

Alternatively, you could just store the Graphics object in a global variable and modify it each time you call SetGraphics.

That would most easily be accomplished with,

Function SetGraphics(g:TGraphics)
	Global _graphics:TGraphics
	_graphics=g
	Return brl.graphics.SetGraphics(_graphics)
End Function

Just stick this into your source.

All of this code is untested but it should function properly.

Kistjes

(Posted 2009) [#4]

Thanks! I'll try that.

kfprimm

(Posted 2009) [#5]

Ha. Sorry, I was tired when I wrote that code.
The following should be used instead of just the SetGraphics function.

Private
Global _graphics:TGraphics

Public
Function SetGraphics(g:TGraphics)
	_graphics=g
	Return brl.graphics.SetGraphics(_graphics)
End Function

Function GetGraphics:TGraphics()
	Return _graphics
End Function

Kistjes

(Posted 2009) [#6]

The getGraphics() functions should work in all circumstances. In a non-maxGUI project I only use the Graphics(x,y,d,hz) function. This functions does not call my own SetGraphics() function and will therefor not set the global _graphics.

That's why I decided to add a GetGraphics() function to brl.Graphics (your first suggestion, Khomy).

kfprimm

(Posted 2009) [#7]

Alright cool. What I was saying with the SetGraphics function is that originally, the _graphics was set as global in the function and therefore inaccessible outside the function. That snippet corrects the original. When calling brl.graphics.SetGraphics, the _graphics variable in BRL.Graphics is set.