Createwindow with minimize and close button only?

BlitzMax Forums/MaxGUI Module/Createwindow with minimize and close button only?

Grisu

(Posted 2008) [#1]

Hi!

Is it possible to create an app window with just these 2 buttons?
Or at least is there a way to disable the maximize button?

Thanks!
Grisu

jsp	(Posted 2008) [#2]

To have the window size always the same you could also use the min and max ...

Local Window1:TGadget = CreateWindow:TGadget("Window1",279,96,200,200,Null,WINDOW_TITLEBAR|WINDOW_RESIZABLE )
	SetMinWindowSize( Window1:TGadget, 200 , 200 )
	SetMaxWindowSize( Window1:TGadget, 200 , 200 )

plash

(Posted 2008) [#3]

I think if your window has both minimize and maximize buttons you can use Style = 2 to invert them (disable). Play around with it.

Function ModifyWindowButtons(Gadget:TGadget, Style:Int = 1) 
  Local hWnd_temp:Int = QueryGadget(Gadget, QUERY_HWND) 
	
  Local xs:Int = GetWindowLong(hWnd_temp, - 16) 
	Select Style
		Case 1
			xs :| $20000   'WS_MINIMIZEBOX - add Minimize button
			xs :| $10000   'WS_MAXIMIZEBOX - add Maximize button
			
		Case 2
			xs :| $20000   'WS_MINIMIZEBOX - add Minimize button
			
		Case 3
			xs :| $10000   'WS_MAXIMIZEBOX - add Maximize button
	End Select
	
	SetWindowLong hWnd_temp, -16, xs
	UpdateWindowMenu Gadget
	
End Function

Grisu

(Posted 2008) [#4]

Thanks for the help guys!

Here's a fully working test code....

SuperStrict
Import maxgui.Drivers

Local Style:Int = WINDOW_TITLEBAR | WINDOW_CLIENTCOORDS | WINDOW_CENTER '| WINDOW_RESIZABLE
Global MainWindow:TGadget
MainWindow:TGadget = CreateWindow("test app", 0, 0, 340, 106, Null, Style)
ModifyWindowButtons(MainWindow,2)

Repeat
	WaitEvent() 
	Select EventID()
		Case EVENT_WINDOWCLOSE Or EVENT_APPTERMINATE
		End
	End Select
Forever
End

Function ModifyWindowButtons(Gadget:TGadget, Style:Int=1) 
  Local hWnd:Int = QueryGadget(Gadget, QUERY_HWND) 
  Local xs:Int = GetWindowLongA(hWnd, - 16) 
	Select Style
		Case 1
			xs :| $20000   'WS_MINIMIZEBOX - add Minimize button
			xs :| $10000   'WS_MAXIMIZEBOX - add Maximize button
			
		Case 2
			xs :| $20000   'WS_MINIMIZEBOX - add Minimize button
			
		Case 3
			xs :| $10000   'WS_MAXIMIZEBOX - add Maximize button
	End Select
	SetWindowLongA hWnd, -16, xs
	UpdateWindowMenu Gadget	
End Function

Tani	(Posted 2010) [#5]

I found this code very useful too, thanks! Is sad it's not available in the actual language itself though. >.<

I'm sorry for bumping a one year old thread (but the threads in this forum never go old in my opinion, the search function is a hot button for me at least), but I updated the function and wanted to share it with you others, in case more people been struggling with this.

This version works fine with both resizable and static windows and lets you both enable and disable the buttons as you like:

' Sets the applications minimize and/or maximize buttons as enabled or disabled
Function ModifyWindowButtons(Gadget:TGadget,Mini_Style:Int=-1,Maxi_Style:Int=-1) 
	Local hWnd_temp:Int=QueryGadget(Gadget,QUERY_HWND)
	Local xs:Int=GetWindowLongA(hWnd_temp,-16)
	
	'Sets the style of the Minimize button
	Select Mini_Style
		Case -1				'No modification
		Case False			'Disable Minimize button
			xs :& ~$20000
		Case True			'Enable Minimize button
			xs :| $20000
		Default				'Enable/Disable Minimize button (switch status)
			xs :~ $20000
	End Select
	
	'Sets the style of the Maximize button
	Select Maxi_Style
		Case -1				'No modification
		Case False			'Disable Maximize button
			xs :& ~$10000
		Case True			'Enable Maximize button
			xs :| $10000
		Default				'Enable/Disable Maximize button (switch status)
			xs :~ $10000
	End Select
	
	SetWindowLongA(hWnd_temp,-16,xs)
	UpdateWindowMenu(Gadget)
End Function

I could have made it more like the original example though, with only one variable reference for the style in the function. But I prefer this system with one reference for each button instead myself; the amount of combinations is a bit much to remember if giving the same flexibility to a single reference covering both buttons. ^^;

GfK	(Posted 2010) [#6]

Old thread, but here's a Windows-only, non-MaxGUI method:

Strict

?Win32
Extern "win32"
	Function GetActiveWindow%()
End Extern
?

Graphics 800,600
ccEnableMinimize(getActiveWindow())

While Not KeyDown(key_escape)
	Delay 1
Wend

Function ccEnableMinimize(hwnd:Long)
	' Adds the Minimize Button "_"
	?Win32
	Local tmp:Long = GetWindowLongA( hwnd, GWL_STYLE )
	tmp:|WS_MINIMIZEBOX
	SetWindowLongA( hwnd, GWL_STYLE, tmp )
	DrawMenuBar( hwnd )
	?
End Function