Draggable window - Ghosting issue!

BlitzMax Forums/MaxGUI Module/Draggable window - Ghosting issue!

Scaremonger

(Posted May) [#1]

Hi,
I'm trying to create a draggable window that doesn't have a titlebar. The code below sort of works, but I get a ghosting effect where the mouse seems to jump when drag it!

Run the following code, click and hold the mouse button and drag the window around the screen. The more you move it, the more the ghosting occurs!

RIGHT-CLICK to quit!

I've only tested this on Windows so far.

Any suggestions?

SuperStrict
Import Maxgui.drivers

Global window:TGadget = CreateWindow( "Window", 64,64, 128,256, Null, 0 )
Global canvas:TGadget=CreateCanvas(0,0,GadgetWidth(window),GadgetHeight(window),window)
SetGadgetLayout(canvas,1,1,1,1)

'# CREATE A REDRAW TIMER
CreateTimer 60

'# CREATE A POPUP MENU
Global menu:Tgadget = CreateMenu( "popup", 0, Null )
CreateMenu( "Quit", 199, menu )

'# EVENT HOOK
AddHook EmitEventHook, window_hook

'# DRAG AND DROP
Global Drag:Int = False
Global drag_MX:Int = 0
Global drag_MY:Int = 0

Repeat
	Select WaitEvent()
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			FreeGadget canvas
			End
	EndSelect
Forever

Function Redraw()
	SetGraphics CanvasGraphics(canvas)
	'# Fill window with Canvas
	SetViewport 0,0, GadgetWidth(window),GadgetHeight(window)
	SetOrigin GadgetWidth(canvas)/2,GadgetHeight(canvas)/2
	'#
	SetLineWidth 5
	Cls
	Local t:Float=MilliSecs()
	DrawLine 0,0,120*Cos(t),120*Sin(t)
	DrawLine 0,0,80*Cos(t/60),80*Sin(t/60)
	Flip
End Function

Function window_hook:Object( id:Int, data:Object, context:Object)
	Local ev:TEvent = TEvent( data)
	
	If ev Then
		Select ev.ID 
		Case EVENT_TIMERTICK
			RedrawGadget canvas
		Case EVENT_GADGETPAINT
			Redraw()
		Case EVENT_MENUACTION
			If ev.data=199 Then '# QUIT
				FreeGadget( canvas )
				End
			End If
		Case EVENT_MOUSEDOWN
			Select ev.data
			Case 1	'# LEFT MOUSE BUTTON
				drag = True
				'# Set offset of mouse from window
				drag_MX = ev.x - GadgetX(window)
				drag_MY = ev.y - GadgetY(window)
Print "DRAG START"
				Return Null
			Case 2	'# RIGHT MOUSE BUTTON
				PopupWindowMenu window, menu
				Return Null
			End Select
		Case EVENT_MOUSEUP
			Select ev.data
			Case 1	'# LEFT MOUSE BUTTON
				If drag Then drag = False
Print "DRAG STOP"
				Return Null
			End Select
		Case EVENT_MOUSEMOVE
			Local wx%, wy%

			If drag And ev.source=canvas Then
				'# Calculate where mouse is
				wx = ev.x - drag_MX
				wy = ev.y - drag_MY
Print "DRAG TO: "+wx+","+wy
				SetGadgetShape( window, wx, wy, GadgetWidth(window), GadgetHeight(window) )
			End If

		End Select
	EndIf
	Return data
EndFunction

xlsior

(Posted May) [#2]

FWIW, when I drag the window, the lage severely behind the mouse (e.g. the mouse travels the entire width of the screen, your window maybe 1/4th of the way)

The biggest problem here is that normally, windows suspends the drawing of the windows contents while you move the window. I think that whenever you're forcing it to redraw, windows isn't able to move the window at the same time, so it starts lagging behind.

Not sure what to do about that...

skidracer

(Posted May) [#3]

This kind of works in FLTK:

SuperStrict
Import Maxgui.drivers

Global window:TGadget = CreateWindow( "Window", 64,64, 128,256, Null, 0 )
Global canvas:TGadget=CreateCanvas(0,0,GadgetWidth(window),GadgetHeight(window),window)
SetGadgetLayout(canvas,1,1,1,1)

'# CREATE A REDRAW TIMER
CreateTimer 60

'# CREATE A POPUP MENU
Global menu:Tgadget = CreateMenu( "popup", 0, Null )
CreateMenu( "Quit", 199, menu )

'# EVENT HOOK
AddHook EmitEventHook, window_hook

'# DRAG AND DROP
Global Drag:Int = False
Global drag_MX:Int = 0
Global drag_MY:Int = 0

Repeat
	Select WaitEvent()
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			FreeGadget canvas
			End
	EndSelect
Forever

Function Redraw()
	SetGraphics CanvasGraphics(canvas)
	'# Fill window with Canvas
	SetViewport 0,0, GadgetWidth(window),GadgetHeight(window)
	SetOrigin GadgetWidth(canvas)/2,GadgetHeight(canvas)/2
	'#
	SetLineWidth 5
	Cls
	Local t:Float=MilliSecs()
	DrawLine 0,0,120*Cos(t),120*Sin(t)
	DrawLine 0,0,80*Cos(t/60),80*Sin(t/60)
	Flip
End Function

Function window_hook:Object( id:Int, data:Object, context:Object)
	Local ev:TEvent = TEvent( data)
	
	If ev Then
		Select ev.ID 
		Case EVENT_TIMERTICK
			RedrawGadget canvas
		Case EVENT_GADGETPAINT
			Redraw()
		Case EVENT_MENUACTION
			If ev.data=199 Then '# QUIT
				FreeGadget( canvas )
				End
			End If
		Case EVENT_MOUSEDOWN
			Select ev.data
			Case 1	'# LEFT MOUSE BUTTON
				drag = True
				'# Set offset of mouse from window
				drag_MX = ev.x 
				drag_MY = ev.y
Print "DRAG START"
				Return Null
			Case 2	'# RIGHT MOUSE BUTTON
				PopupWindowMenu window, menu
				Return Null
			End Select
		Case EVENT_MOUSEUP
			Select ev.data
			Case 1	'# LEFT MOUSE BUTTON
				If drag Then drag = False
Print "DRAG STOP"
				Return Null
			End Select
		Case EVENT_MOUSEMOVE
			Local wx%, wy%

			If drag And ev.source=canvas Then
				'# Calculate where mouse is
				wx = GadgetX(window) + ev.x - drag_MX
				wy = GadgetY(window) + ev.y - drag_MY
Print "DRAG TO: "+wx+","+wy
				SetGadgetShape( window, wx, wy, GadgetWidth(window), GadgetHeight(window) )
			End If

		End Select
	EndIf
	Return data
EndFunction

Scaremonger

(Posted May) [#4]

@skidracer: Thats it! - You are a star :)

Thanks.

skidracer

(Posted May) [#5]