GadgetY() and Disable WINDOW_CLIENTCOORDS?

BlitzMax Forums/MaxGUI Module/GadgetY() and Disable WINDOW_CLIENTCOORDS?

Grisu

(Posted 2014) [#1]

Hello,

in my app I have to use the WINDOW_CLIENTCOORDS flag for the main window. Nevertheless I need to get the absolute Y position of the main window in order to see if it's no longer visible on the desktop.

Example: *with solution*

SuperStrict 

Framework Maxgui.Drivers
	Import Maxgui.xpmanifest
	Import Brl.EventQueue

	
Const MAINWINDOW_W:Int = 278 
Const MAINWINDOW_H:Int = 154

Local Style:Int = WINDOW_TITLEBAR | WINDOW_CLIENTCOORDS | WINDOW_CENTER | WINDOW_ACCEPTFILES | WINDOW_RESIZABLE | WINDOW_HIDDEN

Global MainWindow:TGadget  = CreateWindow("GadgetY() Issue" , 0 , 0 , MAINWINDOW_W , MAINWINDOW_H , Null , Style)
SetMinWindowSize(MainWindow,MAINWINDOW_W,MAINWINDOW_H)
SetMaxWindowSize(MainWindow,MAINWINDOW_W,DesktopHeight())
ShowGadget (MainWindow)

Global Status_Label:TGadget=CreateLabel("WinY: "+GadgetY(MainWindow),3,3,MAINWINDOW_W-6,16,MainWindow) ' Showing the current WinY position

Global Button_Enlarge:TGadget=CreateButton("Click to ENLARGE this window!",0,MAINWINDOW_H-26,MAINWINDOW_W,26,MainWindow,BUTTON_OK) 


Repeat ' Main Loop
	Select WaitEvent()
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
		End

	
	Case EVENT_WINDOWMOVE
	    SetGadgetText(Status_Label,"WinY: "+GadgetY(MainWindow)) ' WINDOW_CLIENTCOORDS

	Case EVENT_GADGETACTION
     
     Enlarge_Window()
	 SetGadgetText(Status_Label,"WinY: "+GadgetY(MainWindow)) ' WINDOW_CLIENTCOORDS

	End Select 

Forever
End ' of the world ;)

Function Enlarge_Window()
If MAINWINDOW_H = GadgetHeight(MainWindow) Then ' Only change size if Window has its default height!

MainWindow.style:~ WINDOW_CLIENTCOORDS

If GadgetY(MainWindow)-MAINWINDOW_H*1.5+MAINWINDOW_H<=0 Then ' Desktopborder reached, so increads DOWNWARDS
	MainWindow.style:| WINDOW_CLIENTCOORDS
	SetGadgetShape(MainWindow, GadgetX(MainWindow), GadgetY(MainWindow), MAINWINDOW_W, MAINWINDOW_H*1.5)
'    Print "Inceased Windowsize DOWNWARDS!"

Else ' Window can be resized properly
	MainWindow.style:| WINDOW_CLIENTCOORDS
	SetGadgetShape(MainWindow, GadgetX(MainWindow), GadgetY(MainWindow)-MAINWINDOW_H*1.5+MAINWINDOW_H, MAINWINDOW_W, MAINWINDOW_H*1.5)
'    Print "Inceased Windowsize UPWARDS!"

EndIf

EndIf 
End Function

If the changed window size is out of the desktop view, the window has to be resized downwards. If not, it will increase in size (default).

For Windows 8.11 I need to add 31 pixels to the results on my system. But the code has to work multiplatform.

Is there a way to disable the WINDOW_CLIENTCOORDS for a brief call, so GagdetY() returns "0" when the top of the desktop has been reached?

Grisu

Henri

(Posted 2014) [#2]

Hello again,

to disable WINDOW_CLIENTCOORDS use:

MainWindow.style:~ WINDOW_CLIENTCOORDS

to enable use:

MainWindow.style:| WINDOW_CLIENTCOORDS

-Henri

Grisu

(Posted 2014) [#3]

That was as simple as it should be. ;) Thanks.. again.

P.S. I added the updated example to the first post.