Improved Snowflakes Disco?

BlitzMax Forums/MaxGUI Module/Improved Snowflakes Disco?

Grisu

(Posted 2013) [#1]

Hi!

I'm working on a new spectrum analyser with a winter theme for my radio player. I coded a little platform to show the effect in action.
The viewport is limited to 274x87 pixel, so there's not much room. You need to have Brucey's Fmod Lib installed in order to run the code.

Source code:

' Disco Snowflakes 0.1 by Grisu
SuperStrict 

Framework Maxgui.Drivers
Import MaxGui.Drivers
Import Maxgui.ProxyGadgets
Import Brl.EventQueue
Import Brl.Timer     
Import Brl.Pixmap  
Import Brl.Pngloader
Import Brl.Jpgloader
Import BRL.GLGraphics
Import BRL.GLMax2D
Import BRL.random

Import Bah.FMOD ' <a href="http://www.fmod.org/fmod-downloads.html" target="_blank">http://www.fmod.org/fmod-downloads.html</a>
	
Const MAINWINDOW_W:Int = 278 
Const MAINWINDOW_H:Int = 154
Const Buttonsize: Int = 32
Const BUTTON_ACTION:Int = EVENT_GADGETACTION

SetGraphicsDriver GLMax2DDriver()

Global SpectrumTimer:TTimer=CreateTimer(20) ' Used for the spectrum analyser updates!
Global Spec_BackgroundIMG:TImage=LoadImage("prp_noico.png",Null) 

Local Style:Int = WINDOW_TITLEBAR | WINDOW_CLIENTCOORDS | WINDOW_CENTER | WINDOW_ACCEPTFILES | WINDOW_RESIZABLE
Global MainWindow:TGadget  = CreateWindow("Spectrum Test App" , 0 , 0 , MAINWINDOW_W , MAINWINDOW_H , Null , Style)
SetMinWindowSize(MainWindow,MAINWINDOW_W,MAINWINDOW_H)
SetMaxWindowSize(MainWindow,MAINWINDOW_W,DesktopHeight())

Global MainPanel:TGadget = CreatePanel(0 , 0 , MAINWINDOW_W , MAINWINDOW_H , MainWindow )
SetGadgetLayout MainPanel , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED

Global MainLabel:TGadget=CreateLabel("",3,3,MAINWINDOW_W-6,26,MainPanel) 
SetGadgetLayout MainLabel , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED

Global RadioStationCanvas:TGadget = CreateCanvas(2, MAINWINDOW_H - 100-19 , 274 , 87 , MainPanel )', PANEL_ACTIVE) '110
SetGadgetLayout RadioStationCanvas, Null, Null, EDGE_ALIGNED, Null

' Init FMOD
Global AverageLeft:Int
Global AverageRight:Int
Global stationsound:TFMODSound
Global system:TFMODSystem = New TFMODSystem.Create() ' <- FModEX Init!
Global stationchannel:TFMODChannel

' Put your stream url here...
Global station_url:String="http://193.200.42.208:80"
'Global station_url:String="http://87.230.103.85:80"

Global result:Int=system.Init(4, FMOD_INIT_NORMAL)
If result <> FMOD_OK Then 
	Print "Fatal error!"
	End
EndIf

SetGadgetText (MainLabel,"Loading "+station_url+" - Please wait...")

stationsound:TFMODSound = system.CreateStreamURL(station_url, FMOD_HARDWARE | FMOD_2D | FMOD_CREATESTREAM)
stationchannel = system.PlaySound(FMOD_CHANNEL_FREE,stationsound) ' start streaming

' Spectrum specific global vars
Type TSnowflake
	Field x:Int
	Field y:Int
	Field z:Int 'speed 1-3
End Type

Const SNOW_MAX:Int=300
Global SnowflakeList:TList=CreateList()

' Init main canvas
SetGraphics( CanvasGraphics( RadioStationCanvas ) )
SetBlend SolidBLEND
If Spec_BackgroundIMG = Null Then Print "Image file NOT found!"

Repeat ' Main Loop
	Select WaitEvent()
	Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			End

	Case EVENT_TIMERTICK
		Select EventSource()
				
		Case SpectrumTimer
             If SnowflakeList.count() < SNOW_MAX Then Create_a_Bunch_of_Snowflakes()
	       Update_Snowflakes()

	     End Select 
     End Select 

Forever
End ' of the world

Function Create_a_Bunch_of_Snowflakes()
Local s:TSnowflake
For Local m:Int=1 To 5
	s=New TSnowflake
	s.x = Rand(1 , 273)
	s.y = 1
	s.z = Rand(1 , 3)
	ListAddLast(SnowflakeList,s)
Next 
End Function

Function Update_Snowflakes()
SetGraphics( CanvasGraphics( RadioStationCanvas ) )

Cls
Update_Spectrum_Color()
'SetColor 90,90,90
If Spec_BackgroundIMG <> Null Then DrawImage Spec_BackgroundIMG,0,0

SetColor 255,225,255 
For Local s:TSnowflake=EachIn SnowflakeList
s.x = s.x + Rand( - 1 , 1)
s.y = s.y + s.z

' Check Screen borders left and right
If s.x<1 Then s.x=273
If s.x>272 Then s.x=1

Plot (s.x,s.y)

' Reset snowflake if out of screen
If s.y > 86 Then
	s.x = Rand(2 , 273)
	s.y = 1
	s.z = Rand (1 , 3)
	'SnowflakeList.remove s
EndIf

Next

Flip 0

SetGadgetText (MainLabel,("Particles: "+SnowflakeList.count()))
End Function

Function Update_Spectrum_Color()

If stationchannel <> Null Then 
   Local Spectrum2:Float[64]
   '1 = Right, 0 = Left
   If stationchannel.GetSpectrum(spectrum2 , 0 , FMOD_DSP_FFT_WINDOW_TRIANGLE) = FMOD_OK Then
     GetAverage(spectrum2)
    Else ' Failsafe If only 1 channel is available
     If stationchannel.GetSpectrum(spectrum2, 1,FMOD_DSP_FFT_WINDOW_TRIANGLE) = FMOD_OK Then GetAverage(spectrum2)
   EndIf 
EndIf

End Function

Function GetAverage(_source:Float[])
Local _av:Float 
Local f_value:Float
Local _destout:Float

  If _source 
	
  For f_value = EachIn _source 
    	_av = _av+f_value
  Next 
    _destout = Int( (_av / 64) * 400)
 EndIf
 _destout=_destout*16 ' Max 240
 SetColor _destout,_destout,_destout

 'Print _destout

End Function

Background image:

Download: exe & source
http://www.mediafire.com/download/4xwu977pdqhrnwf/SnowTest.zip

If you have the time, please give it a try.
I'm looking for ways to improve it in terms of speed and effect. Keep in mind that the background image is random.

Would you use DrawRect() instead of Plot() to gain speed?

Grisu

GaryV

(Posted 2013) [#2]

I did not see any snowflakes until I used a magnifying app. They looked good.

Perhaps have wind and have wind react to the music, and naturally the snow would be affected by the wind.

Also how heavy of a snow fall could be determined by the music.

Grisu

(Posted 2013) [#3]

Thanks for trying it out and for the feedback.
What resolution you use on your desktop?

As the first code was to hard on some people eyes, I changed the effect and added 2 layers of snowflakes. This should be more "readable".

' Disco Snowflakes 0.2 by Grisu
SuperStrict 

Framework Maxgui.Drivers
Import MaxGui.Drivers
Import Maxgui.ProxyGadgets
Import Brl.EventQueue
Import Brl.Timer     
Import Brl.Pixmap  
Import Brl.Pngloader
Import Brl.Jpgloader
Import BRL.GLGraphics
Import BRL.GLMax2D
Import BRL.random

Import Bah.FMOD ' <a href="http://www.fmod.org/fmod-downloads.html" target="_blank">http://www.fmod.org/fmod-downloads.html</a>
	
Const MAINWINDOW_W:Int = 278 
Const MAINWINDOW_H:Int = 154
Const Buttonsize: Int = 32
Const BUTTON_ACTION:Int = EVENT_GADGETACTION

SetGraphicsDriver GLMax2DDriver()

Global SpectrumTimer:TTimer=CreateTimer(20) ' Used for the spectrum analyser updates!
Global Spec_BackgroundIMG:TImage=LoadImage("prp_noico.png",Null) 

Local Style:Int = WINDOW_TITLEBAR | WINDOW_CLIENTCOORDS | WINDOW_CENTER | WINDOW_ACCEPTFILES | WINDOW_RESIZABLE
Global MainWindow:TGadget  = CreateWindow("Spectrum Test App" , 0 , 0 , MAINWINDOW_W , MAINWINDOW_H , Null , Style)
SetMinWindowSize(MainWindow,MAINWINDOW_W,MAINWINDOW_H)
SetMaxWindowSize(MainWindow,MAINWINDOW_W,DesktopHeight())

Global MainPanel:TGadget = CreatePanel(0 , 0 , MAINWINDOW_W , MAINWINDOW_H , MainWindow )
SetGadgetLayout MainPanel , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED

Global MainLabel:TGadget=CreateLabel("",3,3,MAINWINDOW_W-6,26,MainPanel) 
SetGadgetLayout MainLabel , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED , EDGE_ALIGNED

Global RadioStationCanvas:TGadget = CreateCanvas(2, MAINWINDOW_H - 100-19 , 274 , 87 , MainPanel )', PANEL_ACTIVE) '110
SetGadgetLayout RadioStationCanvas, Null, Null, EDGE_ALIGNED, Null

' Init FMOD
Global AverageLeft:Int
Global AverageRight:Int
Global stationsound:TFMODSound
Global system:TFMODSystem = New TFMODSystem.Create() ' <- FModEX Init!
Global stationchannel:TFMODChannel

' Put your stream url here...
Global station_url:String="http://193.200.42.208:80"
'Global station_url:String="http://87.230.103.85:80"

Global result:Int=system.Init(4, FMOD_INIT_NORMAL)
If result <> FMOD_OK Then 
	Print "Fatal error!"
	End
EndIf

SetGadgetText (MainLabel,"Loading "+station_url+" - Please wait...")

stationsound:TFMODSound = system.CreateStreamURL(station_url, FMOD_HARDWARE | FMOD_2D | FMOD_CREATESTREAM)
stationchannel = system.PlaySound(FMOD_CHANNEL_FREE,stationsound) ' start streaming

' Spectrum specific global vars
Type TSnowflake
	Field x:Int
	Field y:Int
	Field z:Int 'speed 1-3
End Type

Const SNOW_MAX:Int=500
Global SnowflakeList:TList=CreateList()

' Init main canvas
SetGraphics( CanvasGraphics( RadioStationCanvas ) )
SetBlend SolidBLEND
If Spec_BackgroundIMG = Null Then Print "Image file NOT found!"

Repeat ' Main Loop
	Select WaitEvent()
	Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			End

	Case EVENT_TIMERTICK
		Select EventSource()
				
		Case SpectrumTimer
             If SnowflakeList.count() < SNOW_MAX Then Create_a_Bunch_of_Snowflakes()
	       Update_Snowflakes()

	     End Select 
     End Select 

Forever
End ' of the world

Function Create_a_Bunch_of_Snowflakes()
Local s:TSnowflake
For Local m:Int=1 To 5
	s=New TSnowflake
	s.x = Rand(1 , 273)
	s.y = 1
	s.z = Rand(1 , 2)
	ListAddLast(SnowflakeList,s)
Next 
End Function

Function Update_Snowflakes()
SetGraphics( CanvasGraphics( RadioStationCanvas ) )

Cls
SetColor 55,55,55 
Update_Spectrum_Color()

For Local s:TSnowflake=EachIn SnowflakeList
s.x = s.x + Rand( - 1 , 1)
s.y = s.y + s.z

' Check Screen borders left and right
If s.x<1 Then s.x=273
If s.x>272 Then s.x=1

If s.z = 2 Then
	SetColor 225 , 225 , 225
	Drawrect s.x,s.y,2,2
	If s.y > 85 Then
		s.x = Rand(2 , 273)
		s.y = 1
		s.z = Rand (1 , 2)
	EndIf
Else
	SetColor 125,125,125 
	DrawRect s.x,s.y,1,1
	If s.y > 86 Then
		s.x = Rand(2 , 273)
		s.y = 1
		s.z = Rand (1 , 2)
	EndIf
EndIf

Next

Flip 0

SetGadgetText (MainLabel,("Particles: "+SnowflakeList.count()))
End Function

Function Update_Spectrum_Color()
If stationchannel <> Null Then 
   Local Spectrum2:Float[64]
   '1 = Right, 0 = Left
   If stationchannel.GetSpectrum(spectrum2, 1, FMOD_DSP_FFT_WINDOW_TRIANGLE) = FMOD_OK Then
     GetAverage(spectrum2)
    Else ' Failsafe If only 1 channel is available
     If stationchannel.GetSpectrum(spectrum2, 2,FMOD_DSP_FFT_WINDOW_TRIANGLE) = FMOD_OK Then GetAverage(spectrum2)
   EndIf 
EndIf

End Function

Function GetAverage(_source:Float[])
Local _av:Float 
Local f_value:Float
Local _destout:Float

  If _source 
	
  For f_value = EachIn _source 
    	_av = _av+f_value
  Next 
    _destout = Int( (_av / 64) * 400)
 EndIf
 _destout=_destout*7

If Spec_BackgroundIMG <> Null Then DrawImageRect Spec_BackgroundIMG,0,87-_destout,274,_destout

End Function

How can I rotate a rectangle via BMX. B3D had such a command as I recall.

|EDIT| Uploaded a full version here: http://www.mediafire.com/download/dbax8m3agq528ub/PRP_Snow.zip 'right click on a station logo to switch through the spectrum analysers.

GaryV

(Posted 2013) [#4]

My resolution is 1920x1080 on a 24 inch monitor. I am old and have 20/200 vision, so that is the biggest issue. Usually I can squint and see small things, but I couldn't even see these when squinting.

Grisu

(Posted 2013) [#5]

Well, that explains the issue.

Still tweaking bits & bolts: http://www.mediafire.com/download/ajngr5hgb6jjaht/PRP_Snow.zip