Maxgui Timer Limitation

BlitzMax Forums/MaxGUI Module/Maxgui Timer Limitation

Scaremonger

(Posted 2013) [#1]

Take the code below; If you increase the timer to 60 (On my laptop) the application no longer runs. I suspect this is because MAXGUI is spending all it's time processing messages rather than running the game.

Does anyone have a suggestion for calculating the best timer speed for a given PC so that this situation does not occur?

SuperStrict
Import MaxGui.Drivers

Global T:TTimer = CreateTimer(30)

Global flags%=WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS|WINDOW_CENTER
Global window:TGadget = CreateWindow( AppTitle, 0, 0, 400,200, Null, FLAGS )
Global canvas:TGadget = CreateCanvas( 0, 0, 400, 200, window )
SetGadgetLayout canvas, EDGE_CENTERED, EDGE_ALIGNED, EDGE_CENTERED, EDGE_ALIGNED
SetGraphics CanvasGraphics( canvas )

Const SPEED% = 50

Global ang:Float
Global CX%=GraphicsWidth()/2
Global CY%=GraphicsHeight()/2
Global quit% = False

AddHook EmitEventHook, eventHook
Repeat WaitEvent() Until quit

End

'############################################################
Function eventHook:Object( ID:Int, Data:Object, Context:Object )
Local E:TEvent = TEvent(Data)
	If Not E Then Return Data
	Select E.id
		Case EVENT_WINDOWCLOSE
			quit = True
		Case EVENT_TIMERTICK
			CX%=GraphicsWidth()/2
			CY%=GraphicsHeight()/2
			ang :+ SPEED * delta.time 
			delta.update()
			RedrawGadget(canvas)
		Case EVENT_GADGETPAINT
			SetGraphics CanvasGraphics( Canvas )
			SetLineWidth( 5 )
			Cls
			DrawText( "EXAMPLE 1", 10,10 )
			DrawLine( CX, CY, CX+Sin(ang)*CX, CY+Cos(ang)*CY ) 
			Flip 0
	EndSelect
Return Data
EndFunction

'############################################################
'# Delta Time, based on code by WAVE
'# <a href="http://www.truplo.com/blitzmaxbeginnersguide/wave18.html" target="_blank">http://www.truplo.com/blitzmaxbeginnersguide/wave18.html</a>
Type Delta
Global Time#, TimeDelay%
	Function Start()
	TimeDelay = MilliSecs()
	End Function
	Function Update()
	Time = ( MilliSecs() - TimeDelay )*0.001 TimeDelay = MilliSecs()
	End Function
End Type

Derron

(Posted 2013) [#2]

First: RedrawGadget during the timerticks does not repaint the canvas on linux/fltk (you have to move the drawing section to a custom function and call it on timertick and on gadgetpaint).

I increased the timer to 300 and it did all - except reacting on the close button. Timer-tick still got triggered.

If you want to get a "maximum" to use: just calculate avg time for each run of eventprocessing. that average is the time you have to leave for the app to stay alive and halfway responding.

bye
Ron

jsp	(Posted 2013) [#3]

When using the WaitEvent loop the TimerTick cannot flood the eventqueue, but when using an addhook it can.
You have to have your own mechanism in place to avoid that, so be careful when you are using an AddHook command.

Scaremonger

(Posted 2013) [#4]

@Derron: Thanks for the advice about Linux.

On @JSP's advice I moved TIMERTICK and GADGETPAINT into the while loop and it didn't seem to make much difference, so I threw in a FPS function and was surprised to see I was getting a good frame rate!

The delta timer helped me identify the problem. ANG was a float, I changed ANG to a double and it now works...

Cheers guys :)

SuperStrict
Import MaxGui.Drivers

Global T:TTimer = CreateTimer(100)

Global flags%=WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS|WINDOW_CENTER
Global window:TGadget = CreateWindow( AppTitle, 0, 0, 400,200, Null, FLAGS )
Global canvas:TGadget = CreateCanvas( 0, 0, 400, 200, window )
SetGadgetLayout canvas, EDGE_CENTERED, EDGE_ALIGNED, EDGE_CENTERED, EDGE_ALIGNED
SetGraphics CanvasGraphics( canvas )

Const SPEED% = 50

Global ang:Double
Global CX%=GraphicsWidth()/2
Global CY%=GraphicsHeight()/2
Global quit% = False

AddHook EmitEventHook, eventHook
Repeat
	WaitEvent() 
	Select CurrentEvent.id
		Case EVENT_TIMERTICK
			CX%=GraphicsWidth()/2
			CY%=GraphicsHeight()/2
			ang :+ SPEED * delta.time 
			delta.update()
			draw()
		Case EVENT_GADGETPAINT
			draw()
	EndSelect
Until quit

End

'############################################################
Function draw()
	SetGraphics CanvasGraphics( Canvas )
	SetLineWidth( 5 )
	Cls
	DrawText( "EXAMPLE 1", 10,10 )
	DrawText( "FPS:   "+ FPS.calc(), 10,20 ) 
	DrawText( "DELTA: "+ Delta.time, 10,30 ) 
	DrawLine( CX, CY, CX+Sin(ang)*CX, CY+Cos(ang)*CY ) 
	Flip 0
End Function

'############################################################
Function eventHook:Object( ID:Int, Data:Object, Context:Object )
Local E:TEvent = TEvent(Data)
	If Not E Then Return Data
	Select E.id
		Case EVENT_WINDOWCLOSE
			quit = True
	EndSelect
Return Data
EndFunction

'############################################################
'# Delta Time, based on code by WAVE
'# <a href="http://www.truplo.com/blitzmaxbeginnersguide/wave18.html" target="_blank">http://www.truplo.com/blitzmaxbeginnersguide/wave18.html</a>
Type Delta
Global Time#, TimeDelay%
	Function Start()
	TimeDelay = MilliSecs()
	End Function
	Function Update()
	Time = ( MilliSecs() - TimeDelay )*0.001 TimeDelay = MilliSecs()
	End Function
End Type

'############################################################
'# Frame Counter, based on code by WAVE
'# <a href="http://www.truplo.com/blitzmaxbeginnersguide/wave18.html" target="_blank">http://www.truplo.com/blitzmaxbeginnersguide/wave18.html</a>
Type FPS
Global Counter%, Time%, Value%
	Function Calc%()
		Counter:+1
		If Time < MilliSecs() Then
			value = Counter ' <-Frames/Sec
			Time = MilliSecs() + 1000 ' Update
			Counter = 0
		EndIf
	Return value
	EndFunction
EndType