BASS - End of Stream

BlitzMax Forums/Brucey's Modules/BASS - End of Stream

degac

(Posted 2009) [#1]

Maybe this is a stupid question, but I have a problem to check if a 'stream' is still playing or not.
The idea is to play the 'next' song in the queue when the current one has finished...but I get only a 'forever' loop.

SuperStrict

Framework BaH.Bass
Import BRL.GLMax2D
Import brl.StandardIO


Graphics 640,480

If Not TBass.Init(-1,44100,0,Null,Null) Then
	Print "Can't initialize device : " + TBass.ErrorGetCode()
	End
End If

Global file:TStream
Global stream:TBassStream
Global SongName:String[]=["resources/bass_track_baby.mp3","resources/piratesnewv.ogg"]
Local _exit:Int=False
Local current_song:Int=0

Global stream_size:Long

InitStream(current_song)
Local active:Int

While _exit=False

	If stream

		active = stream.IsActive()
				
		While stream.play(False)' And active
			Local _left:Int, _right:Int

			stream.GetLevel(_left, _right)
			Local lwidth:Int = _left / 410.0
			Cls
			DrawText "Song     - " + songName[current_song]+" "+current_song,50,30

			DrawRect 100 - lwidth, 100, lwidth, 20
			DrawRect 110, 100, _right / 410.0, 20

			Local pos:Long = stream.GetPosition(BASS_POS_BYTE)
			Local time:Double = stream.Bytes2Seconds(pos)
			DrawText "position - " + pos, 50, 50
			DrawText "elapsed  - " + Int(time/60) + ":" + Int(time Mod 60), 50, 70
			DrawText "Active: "+active,5,0

			active = stream.IsActive()
		
			If KeyHit(key_enter) ' move quite the end of the songs...
				stream.SetPosition(95 *Float(stream_size:Long)/100, BASS_POS_BYTE)
			End If
				
			If KeyHit(key_Space)	'change the music
				current_song:+1
				If current_song>1 current_song=0
				StopMusic()
				InitStream(current_song)
			End If
			Delay 50
	Flip

		Wend
	Else
		Print "NO stream!"
	End If
	
	Print "Finish playing..."
	
	If KeyHit(KEY_ESCAPE) _Exit=True

Wend
TBass.Free()

End

Function StopMusic()
'	Print "Clear all..."
	If stream stream.Free();stream=Null
	If file CloseStream(file);file=Null
	
End Function
Function InitStream(song:Int=0)
file = ReadStream(SongName[song])
	Print "Read <"+songName[song]+">"
	If file
		stream= New TBassStream.CreateTStream(file, 0,0)' BASS_SAMPLE_FX)
		Print "Stream Init..."
		If stream=Null Print "Problem!!!"
		stream_size=stream.GetLength(BASS_POS_BYTE)

	End If
End Function

You can skip the current song pressing SPACE key; ENTER key will move to 95% of the song to check the 'skipping'.

Where is the error?

Brucey

(Posted 2009) [#2]

Sorry for the late reply... I was away for a few days.

Here's a tweaked version of your example which detects the end of a track :

SuperStrict

Framework BaH.Bass
Import BRL.GLMax2D
Import brl.StandardIO

Graphics 640,480

If Not TBass.Init(-1,44100,0,Null,Null) Then
	Print "Can't initialize device : " + TBass.ErrorGetCode()
	End
End If

Global syncData:TBassSyncData = New TBassSyncData

Global file:TStream
Global stream:TBassStream
Global SongName:String[]=["resources/bass_track_baby.mp3","resources/bass_track_baby.mp3"]
Local _exit:Int=False
Local current_song:Int=0

Global stream_size:Long

InitStream(current_song)
Local active:Int

While _exit=False

	If stream

		active = stream.IsActive()
				
		While stream.play(False)' And active
			Local _left:Int, _right:Int

			stream.GetLevel(_left, _right)
			Local lwidth:Int = _left / 410.0
			Cls
			DrawText "Song     - " + songName[current_song]+" "+current_song,50,30

			DrawRect 100 - lwidth, 100, lwidth, 20
			DrawRect 110, 100, _right / 410.0, 20

			Local pos:Long = stream.GetPosition(BASS_POS_BYTE)
			Local time:Double = stream.Bytes2Seconds(pos)
			DrawText "position - " + pos, 50, 50
			DrawText "elapsed  - " + Int(time/60) + ":" + Int(time Mod 60), 50, 70
			DrawText "Active: "+active,5,0

			active = stream.IsActive()
		
			If KeyHit(key_enter) ' move quite the end of the songs...
				stream.SetPosition(95 *Float(stream_size:Long)/100, BASS_POS_BYTE)
			End If
				
			If syncData.IsSet() Or KeyHit(key_Space) 'change the music
				current_song:+1
				If current_song>1 current_song=0
				StopMusic()
				InitStream(current_song)
			End If
			Delay 50
			Flip


		If KeyHit(KEY_ESCAPE)
			_Exit=True
			Exit
		End If

		Wend
	Else
		Print "NO stream!"
	End If
	
	Print "Finish playing..."
	

Wend
TBass.Free()

End

Function StopMusic()
'	Print "Clear all..."
	If stream stream.Free();stream=Null
	If file CloseStream(file);file=Null
	
End Function
Function InitStream(song:Int=0)
file = ReadStream(SongName[song])
	Print "Read <"+songName[song]+">"
	If file
		stream= New TBassStream.CreateTStream(file, 0,0)' BASS_SAMPLE_FX)
		Print "Stream Init..."
		If stream=Null Print "Problem!!!"
		stream_size=stream.GetLength(BASS_POS_BYTE)

		stream.SetSync(BASS_SYNC_END, 0, syncData) ' sync for stream end
		
	End If
End Function

Note the use of the TBassSyncData object, and the call to SetSync() when the stream is created.
The reason we use this object is to get around the issue of having a callback into BlitzMax code from a separate thread - which breaks BlitzMax using the default GC.
You simply call syncData.IsSet(), which will return True whenever the sync is triggered. So you should check it often. Checking for the value is thread-safe :-)

HTH

degac

(Posted 2009) [#3]

Oh thank you very much!
I'll never found the solution!

SetSync() & TBassSyncData dont' seem to have any useful informations in the help...Is there somewhere a 'manual/help' about BASS, because the BASS's forum is not useful: too many threads.

In any case, thank you very much!

Brucey

(Posted 2009) [#4]

Is there somewhere a 'manual/help' about BASS, because the BASS's forum is not useful

Nothing that will have this specific information about the Type, but the docs on BASS_ChannelSetSync should help a bit.
Obviously, I need to improve the module documentation here, as it is sorely lacking.