Drag and Drop files

BlitzMax Forums/Brucey's Modules/Drag and Drop files

Pete Rigz

(Posted 2009) [#1]

Sorry me again...

I'm trying add a feature to drag and drop files from windows explorer into the application to load files that way, but when trying to create a wxFileDropTarget it returns null. I don't know if it's a bug or I'm just doing it all wrong!

Here's the sample code, where i've tried to (more or less) copy the sample from the wxWidgets book:

SuperStrict

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxWindow
Import wx.wxListCtrl
Import wx.wxFileDropTarget


Type MyFrame1Base Extends wxFrame

	Field m_listctrl:wxListCtrl

	Method Create:MyFrame1Base(parent:wxWindow = Null, id:Int = wxID_ANY, title:String = "", x:Int = -1, y:Int = -1, w:Int = 200, h:Int = ..
		300, style:Int = wxDEFAULT_FRAME_STYLE|wxTAB_TRAVERSAL)
		Return MyFrame1Base(Super.Create(parent, id, title, x, y, w, h, style))
	End Method

	Method OnInit()

		Local bSizer1:wxBoxSizer
		bSizer1 = New wxBoxSizer.Create(wxVERTICAL)
		m_listctrl = New wxListCtrl.Create(Self, wxID_ANY)
		
		Local draggedfile:DnDFile = DnDFile(New wxFileDropTarget.Create())
		draggedfile.owner = m_listctrl
		m_listctrl.SetDropTarget(draggedfile)

		bSizer1.Add(m_listctrl, 1, wxEXPAND | wxALL, 5)
		
		SetSizer(bSizer1)
		Layout()

	End Method

End Type

New MyApp.Run()

Type MyApp Extends wxApp

	Field mainwin:MyFrame1
	
	Method OnInit:Int()

		mainwin = MyFrame1(New MyFrame1.Create(,, "Drag and Drop"))

		mainwin.Show()

		Return True
	End Method

End Type
Type MyFrame1 Extends MyFrame1Base

	Method OnInit()
		Super.OnInit()

		' Add own initialisation code here

	End Method

End Type
Type DnDFile Extends wxFileDropTarget
	Field owner:wxListCtrl

	Method OnDropFiles:Int(x:Int, y:Int, filenames:String[])
		DebugLog "Dropped a file"
	End Method
End Type

Brucey

(Posted 2009) [#2]

I added support for it in wxCodeGen. If it works there for you, then it should work :-)

It certainly used to work.

Pete Rigz

(Posted 2009) [#3]

o, I'm an idiot.

Local draggedfile:DnDFile = DnDFile(New wxFileDropTarget.Create())

should of course be

Local draggedfile:DnDFile = DnDFile(New DnDFile.Create())

Brucey

(Posted 2009) [#4]

Oh yes. That'll help! :-)