BaH.Crypto

BlitzMax Forums/Brucey's Modules/BaH.Crypto

Brucey

(Posted 2008) [#1]

Well, it's been such a long time since I came out with a new module (if you don't count the one from a week or so ago :-p ), that I thought I should just knock together something for the weekend.

The Crypto module uses OpenSSL's crypto libs ( "libcrypto" on Linux/Mac and "eay32.dll" on Win32) to do all the hard work of ciphering.

It currently supports BlowFish, CAST, DES, RC2, RC4 and RC5, in various modes (see HERE for a good description of the modes and how they work).

Currently only tested on OS X, which has OpenSSL installed by default. Linux should be okay too, as most distros package OpenSSL, although you may need to download the Dev package.

On Win32, you'll need the OpenSSL DLLs. I've shipped the MinGW .a and includes, so it might compile. (Haven't tested this yet.. Later today hopefully - once Eskom turn the power back on - bloody rolling blackouts!)

Available in SVN only until it's all working fine on all platforms...

http://code.google.com/p/maxmods/wiki/CryptoModule

:o)

Oh, and I hope to be adding Digest support in the not too distant future too. (eg. HMAC, MD2, MD5, MDC2, SHA and RIPEMD-160)

Brucey

(Posted 2008) [#2]

Now working fine on Win32... Yay!

Seems RC5 isn't compiled into the "usual" libs on Windows, so I've left it out of the module on that platform.

Downloading and installing "Win32 OpenSSL v0.9.8g Light" from HERE is enough to get the examples running. Note, if you want to distribute the libs with your app, you might want to include the libeay32.dll that gets installed into the system32 folder.

:o)

Brucey

(Posted 2008) [#3]

Since everything *appears* to be working as expected so far... the first release is now available from HERE.

plash

(Posted 2008) [#4]

Compiled mod, then installed "Win32 OpenSSL v0.9.8g Light".

BOTH examples give me this error.

The procedure entry point EVP_bf_cfb64 could not be located in the dynamic link library libeay32.dll.

Did I miss anything?

Brucey

(Posted 2008) [#5]

Haw... that's strange.

Originally tested it on XP, worked okay.
Just installed OpenSSL on Win2k and it is also working as expected.

Are you sure that you are using that latest dll? (perhaps there is another on your PATH that is found first?)

Try copying it into the app dir and see if that works better?
(when I installed v0.9.8g onto the win2k, it did ask if I wanted to overwrite the DLLs in System32 - which I said yes to).

plash

(Posted 2008) [#6]

Ahh.. the problem was, I initially installed an older version (didn't look to much at the instructions you gave) of the OpenSSL dll, which I placed in the app and sys32 dir.

After installing v0.9.8g I didn't replace the one in the app dir with the new dll (which the installer placed in sys32).

Works now :)

Chroma

(Posted 2008) [#7]

Any idea when IDEA will be supported Brucey?

Also, which encryption in the mod is the fastest?

Brucey

(Posted 2008) [#8]

IDEA seems to excluded from most default builds of OpenSSL because of patent issues with Ascom-Tech AG. It appears you need a license for commercial apps.

As for the fastest, I haven't given them all a thorough test. You might wish to try the different combinations of the algorithms with the various modes.

slenkar

(Posted 2008) [#9]

is this module used to encrypt files?

Brucey

(Posted 2008) [#10]

If you like.

There's an example which shows how to use a TStream for input/output.
In theory you could then also use a RamStream and do stuff in-memory, assuming you setup enough space for it (streaming out of ram shouldn't be a problem).

The other example shows encryption from/to a String.

Basically, all you need is some kind of data to feed it.

Sub_Zero

(Posted 2011) [#11]

Hi and thank you very much for this module, it is working great.

However, I've encountered a bug in v1.02/v1.03 when it comes to encrypting larger (>3000 bytes) of data. Basically what i was trying to do was encrypt all my .bmx files, and encountered a segmentation fault on some of the larger files... When calling encryptupdate and or encryptfinal sometimes dumped alot of crap onscreen and then a segmentation fault, some just threw a segmentation fault, and the rest of the files encrypted ok... I did not use the TStream method, instead i used loadtext and then stringtobytearray before encrypting.

I also looked over you code, and found no errors whatsoever, it looked perfectly clean, so I tried to build the module against various subversions of libssl 0.9.8 stable without any luck. I also tried to compile the module on different stations (intel/amd), but still no luck.

I also tried passing 2048 bytes at a time to encryptupdate before doing a encryptfinal, but still segmentation fault.

Strange this segmentation fault, since it happens only to 5% of the files i tried to encrypt, but it seems it happens to only of the larger files.

Also i tried different ciphers, aes128cbc, aes256cbc, bf-cbc, etc... Still the same result.

So i beg you please can we try to figure out this problem.... And ofcourse, I'm running linux.

You've done alot of wonderful work since the time I suggested you to make the gtkwebmozilla module ;) Good work indeed.

Kind regards from norway, Sub Zero

Last edited 2011

Brucey

(Posted 2011) [#12]

The "crap" is part of the memory dump when linux seg faults.

I'll write up a little test which can handle large files and see how it performs for me.
The encrypt_decrypt example isn't really appropriate because you don't really want to do it in a single hit...

Brucey

(Posted 2011) [#13]

Hi again.

It appears to be a problem with your code. I've just written an example which encrypts (and decrypts) the entire text of war and peace (about 3.3mb) and it does this without crashing. Sure, it did take me a while to work out the best method, but if the code is written correctly, it works as you'd expect. :)


SuperStrict

Framework BaH.Crypto
Import BRL.StandardIO
Import BRL.textstream


' Bogus key And IV: we'd normally set these from another source.
Local key:Byte[] = IntToByteArray([0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15])
Local iv:Byte[] = IntToByteArray([1,2,3,4,5,6,7,8])
Local intext:String = LoadText("war_and_peace.txt")


Local arr:Byte[] = StringToByteArray(intext)
Local length:Int = arr.length

Local tmplen:Int

Local inbuf:Byte[]

Print "Original       : " + length + " bytes"

' +++++++++++++++++++++++++++++++++++++++
' encrypt
' +++++++++++++++++++++++++++++++++++++++

Local ds:String

Local ctx:EVP_CIPHER_CTX = New EVP_CIPHER_CTX.Create()

ctx.EncryptInit(EVP_CIPHER.bf_cbc(), Null, key, iv)

Local count:Int = 0
Const BUF_SIZE:Int = 2048 ' our block size

' size should be big enough to hold the block plus a bit more
Local outbuf:Byte[BUF_SIZE + ctx.GetBlockSize()]
Local outlen:Int


' loop all the full blocks
For Local i:Int = 0 Until length / BUF_SIZE

	If Not ctx.EncryptUpdate(outbuf, outlen, arr[count..count + BUF_SIZE], BUF_SIZE) Then
		Print "Error..."
		End
	End If

	' update input buffer offset
	count :+ BUF_SIZE
	
	' store encrypted
	inbuf :+ outbuf[0..outlen]
	
Next

' encrypt remaining part block
If length Mod BUF_SIZE Then

	If Not ctx.EncryptUpdate(outbuf, outlen, arr[count..count + length Mod BUF_SIZE], length Mod BUF_SIZE) Then
		Print "Error..."
		End
	End If
	
	' update input buffer offset
	count :+ length Mod BUF_SIZE
	
	' store encrypted
	inbuf :+ outbuf[0..outlen]

End If

' Tidy up
If Not ctx.EncryptFinal(outbuf, outlen) Then
	Print "Error..."
	End
End If

' add any padding
inbuf :+ outbuf[0..outlen]

ctx.Cleanup()


Print "Processed      : " + count
Print "Encrypted data : " + inbuf.length
Print "~n"

Local s:String

' +++++++++++++++++++++++++++++++++++++++
' decrypt
' +++++++++++++++++++++++++++++++++++++++


length = inbuf.length

Print "Input data     : " + length + " bytes"

ctx.DecryptInit(EVP_CIPHER.bf_cbc(), Null, key, iv)

outbuf = New Byte[BUF_SIZE + ctx.GetBlockSize() + 10]

count = 0

For Local i:Int = 0 Until length / BUF_SIZE

	If Not ctx.DecryptUpdate(outbuf, outlen, inbuf[count..count + BUF_SIZE], BUF_SIZE)
		Print "Error..."
		End
	End If

	s :+ String.FromBytes(outbuf, outlen)

	count :+ BUF_SIZE
	
Next

If length Mod BUF_SIZE Then

	If Not ctx.DecryptUpdate(outbuf, outlen, inbuf[count..count + length Mod BUF_SIZE], length Mod BUF_SIZE)
		Print "Error..."
		End
	End If

	s :+ String.FromBytes(outbuf, outlen)

	count :+ length Mod BUF_SIZE
End If


If Not ctx.DecryptFinal(outbuf, outLen) Then
	Print "Error..."
	End
End If

s :+ String.FromBytes(outbuf, outlen)

ctx.Cleanup()

Print "Processed      : " + count
Print "Decrypted      : " + s.length + " bytes"
Print "~n"

Sub_Zero

(Posted 2011) [#14]

Ah, thanks alot for that.... I forgot to post, I also solved the problem using cipherinit/update/final instead, according to your example...

But thanks, keep up the good work, you're doing great.

Sub_Zero

(Posted 2013) [#15]

Looking back, it might have been because the keylength was wrong (oops)

By the way, now when i tried to compile your example, i get an error stating GetBlockSize() not found....

Would this be the equivalent to EVP_MAX_BLOCK_LENGTH ?
EVP_MAX_BLOCK_LENGTH

Edit: Now I know what's wrong... I've downloaded v1.02 from googlecode.... Why don't you put the v1.03 version in hte download section instead ;)

Brucey

(Posted 2013) [#16]

Yes, it's probably a good idea. :-)

Sub_Zero

(Posted 2013) [#17]

Thanks alot :)

Sub_Zero

(Posted 2013) [#18]

I'm having some problems again:


Strict

Framework BRL.Retro
Import BRL.Filesystem
Import BaH.Crypto
'Import BRL.Random
'Import MaxGui.Drivers
'Import BRL.Eventqueue


Local key:Byte[] = IntToByteArray([50,51,52,53,54,55,56,57,58])
Local iv:Byte[] = IntToByteArray([1,2,3,4,5,6,7,8])

Print encrypt("/root/dl.data", "/root/Desktop/dl2.cry", key, iv)
Print decrypt("/root/Desktop/dl2.cry", "/root/Desktop/dl.txt", key, iv)


Function encrypt:Int(infile:String, outfile:String, key:Byte[], iv:Byte[])
  Local inbuf:Byte[]
  Local arr:Byte[]
  Local ctx:EVP_CIPHER_CTX
  Local cipher_:EVP_CIPHER
  Local cipher:String
  Local count:Int
  Const BUF_SIZE:Int = 2048 ' our block size
  Local outlen:Int
  Local i:Int
  Local file:TStream

  If FileMode(infile) > 0
	arr = LoadByteArray(infile)
  Else
    Return -1
  EndIf

  cipher_ = EVP_CIPHER.rc4()

  ctx = New EVP_CIPHER_CTX.Create()
  ctx.CipherInit(cipher_, Null, Null, Null, True)
  ctx.SetKeyLength(key.length)
  ctx.CipherInit(cipher_, Null, key, iv, True)
  Local outbuf:Byte[BUF_SIZE + ctx.GetBlockSize()]
  Local length:Int = arr.length
  count = 0
  ' loop all the full blocks
  For i = 0 Until length / BUF_SIZE
	If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + BUF_SIZE], BUF_SIZE)
	  Return -2
	End If
	' update input buffer offset
	count :+ BUF_SIZE
	' store encrypted
	inbuf :+ outbuf[0..outlen]	
  Next

' encrypt remaining part block
  If length Mod BUF_SIZE
	If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + length Mod BUF_SIZE], length Mod BUF_SIZE)
	  Return -2
	End If	
	' update input buffer offset
	count :+ length Mod BUF_SIZE
	' store encrypted
	inbuf :+ outbuf[0..outlen]
  End If

  ' Tidy up
  If Not ctx.CipherFinal(outbuf, outlen) Then
	Return -2
  End If

  ' add any padding
  inbuf :+ outbuf[0..outlen]
  ctx.Cleanup()
  SaveByteArray(inbuf, outfile)

  ' Clear memory just in case
  For i = 0 Until inbuf.length
    inbuf[i] = 0
  Next
  For i = 0 Until outbuf.length
    outbuf[i] = 0
  Next
  For i = 0 Until arr.length
    arr[i] = 0
  Next
  For i = 0 Until key.length
    key[i] = 0
  Next
  For i = 0 Until iv.length
    iv[i] = 0
  Next

  Return True
End Function


Function decrypt:Int(infile:String, outfile:String, key:Byte[], iv:Byte[])
  Local inbuf:Byte[]
  Local outbuf:Byte[]
  Local arr:Byte[]
  Local ctx:EVP_CIPHER_CTX
  Local cipher_:EVP_CIPHER
  Local cipher:String
  Local count:Int
  Const BUF_SIZE:Int = 2048 ' our block size
  Local outlen:Int
  Local i:Int
  Local file:TStream
  Local length:Int

  If FileMode(infile) > 0
	arr = LoadByteArray(infile)
  Else
    Return -1
  EndIf

  cipher_ = EVP_CIPHER.rc4()

  length = arr.length
  ctx = New EVP_CIPHER_CTX.Create()
  ctx.CipherInit(cipher_, Null, Null, Null, False)
  ctx.SetKeyLength(key.length)
  ctx.CipherInit(cipher_, Null, key, iv, False)
  outbuf = New Byte[BUF_SIZE + ctx.GetBlockSize() + 10]

  count = 0

  For i = 0 Until length / BUF_SIZE
	If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + BUF_SIZE], BUF_SIZE)
	  Return -2
	End If
    inbuf :+ outbuf[0..outlen]
    count :+ BUF_SIZE
  Next

  If length Mod BUF_SIZE
    If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + length Mod BUF_SIZE], length Mod BUF_SIZE)
      Return -2	
    End If
    inbuf :+ outbuf[0..outlen]
    count :+ length Mod BUF_SIZE
  End If


  If Not ctx.CipherFinal(outbuf, outLen)
    Return -2
  End If

  inbuf :+ outbuf[0..outlen]
  ctx.Cleanup()

  SaveByteArray(inbuf, outfile)

  ' Clear memory just in case
  For i = 0 Until inbuf.length
    inbuf[i] = 0
  Next
  For i = 0 Until outbuf.length
    outbuf[i] = 0
  Next
  For i = 0 Until arr.length
    arr[i] = 0
  Next
  For i = 0 Until key.length
    key[i] = 0
  Next
  For i = 0 Until iv.length
    iv[i] = 0
  Next

  Return True

End Function

Encryption/decryption breaks somehow.... Not sure why.. I have a another example where the almost exact same function works, but I'll have to email it to you. There is some strange behaviour.... And the exact same thing happens in windows aswell... I'm guessing it might be a openssl bug for now....

By the way I tried to send you an email, but it wouldn't let me....

So I'm posting an example that works like a charm here:


Strict

Framework BaH.Crypto
Import BRL.Filesystem
Import BRL.Retro
Import BRL.Random

Global version:String = "1.1"

' Bogus key And IV: we'd normally set these from another source.
'Local key:Byte[] = IntToByteArray([0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15])
'Local iv:Byte[] = IntToByteArray([1,2,3,4,5,6,7,8])

Local commandOK:Int
Local command:String
Local infile:String
Local outfile:String
Local keyfile:String
Local result:Int
Local file:TStream
Local cipher:String

If AppArgs.length < 2
  printHelp()
  End
Else
  command = Trim(AppArgs[1])
  If command <> "help" And command <> "encrypt" And command <> "decrypt" And command <> "makekey"
    printHelp()
    End
  EndIf
  If command = "help"
  	Print "subcrypter v" + version + " (C) SubSoft 2013"
  	Print "--------------------------------"
  	Print "Available ciphers:"
	Print "AES"
  	Print "Blowfish"
    Print "CAST5"
    Print "DES"
  	Print "RC2"
    Print "RC4"
    End
  EndIf
  If AppArgs.length < 3
    printHelp()
    End
  Else
    If command = "makekey"
      cipher = Lower(Trim(AppArgs[2]))
      If cipher <> "aes" And cipher <> "blowfish" And cipher <> "rc2" And cipher <> "cast5" And cipher <> "des" And cipher <> "rc4" And cipher <> "rc5"
        Print "Invalid cipher error"
        End
      EndIf
      file = WriteStream(Trim(AppArgs[3]))
      If cipher = "aes"
		WriteLine(file, anpass(6,1))
		WriteLine(file, anpass(8,1))
		WriteLine(file, "aes_256_cbc")
	  EndIf
      If cipher = "blowfish"
		WriteLine(file, anpass(7,1))
		WriteLine(file, anpass(8,1))
		WriteLine(file, "bf_cbc")
	  EndIf
	  If cipher = "cast5"
		WriteLine(file, anpass(5,1)) '4
		WriteLine(file, anpass(8,1))
		WriteLine(file, "cast5_cbc")
	  EndIf
	  If cipher = "des"
		WriteLine(file, anpass(4,1))
		WriteLine(file, anpass(8,1))
		WriteLine(file, "des_cbc")
	  EndIf
	  If cipher = "rc2"
		WriteLine(file, anpass(5,1))
		WriteLine(file, anpass(8,1))
		WriteLine(file, "rc2_cbc")
	  EndIf
	  If cipher = "rc4"
		WriteLine(file, anpass(9,1))
		WriteLine(file, anpass(8,1))
		WriteLine(file, "rc4")
	  EndIf
	  If cipher = "rc5"
		WriteLine(file, anpass(9,1))
		WriteLine(file, anpass(8,1))
		WriteLine(file, "rc5_32_12_16_cbc")
	  EndIf
      CloseStream(file)
      End
    EndIf
    If command <> "makekey" And AppArgs.length < 5
      printHelp()
      End
    EndIf

    infile  = Trim(AppArgs[2])
	outfile = Trim(AppArgs[3])
	keyfile = Trim(AppArgs[4])
    If Not FileMode(infile) > 0
	  Print "infile: File not found"
	  End
	EndIf
	If Not FileMode(keyfile) > 0
	  Print "keyfile: File not found"
	  End
	EndIf
    
    If AppArgs.length > 4 And command = "encrypt"
	  result = encrypt(infile, outfile, keyfile)
	  If result = -1
	    Print "File not found error"
	    End
	  EndIf
	  If result = -2
	    Print "Encryption error"
	    End
	  EndIf
	  If result = -3
	    Print "Key file error"
	    End
	  EndIf
    EndIf
    If AppArgs.length > 4 And command = "decrypt"
      result = decrypt(infile, outfile, keyfile)
	  If result = -1
	    Print "File not found error"
	    End
	  EndIf
	  If result = -2
	    Print "Encryption error"
	    End
	  EndIf
	  If result = -3
	    Print "Key file error"
	    End
	  EndIf
    EndIf
  EndIf
EndIf

Function printHelp:Int()
  Print "subcrypter v" + version + " (C) SubSoft 2013"
  Print "--------------------------------"
  Print "usage: subcrypter encrypt [infile] [outfile] [keyfile]"
  Print "       subcrypter decrypt [infile] [outfile] [keyfile]"
  Print "       subcrypter makekey [cipher] [keyfile]"
  Print "       subcrypter help (for more information)"
End Function

' +++++++++++++++++++++++++++++++++++++++
' encrypt
' Return codes:
' -1 = File not found error
' -2 = Encrypt error
' -3 = Key file error
' +++++++++++++++++++++++++++++++++++++++
Function encrypt:Int(infile:String, outfile:String, keyfile:String)
  Local inbuf:Byte[]
  Local arr:Byte[]
  Local ctx:EVP_CIPHER_CTX
  Local cipher_:EVP_CIPHER
  Local cipher:String
  Local count:Int
  Const BUF_SIZE:Int = 2048 ' our block size
  Local outlen:Int
  Local i:Int
  Local file:TStream
  Local key:Byte[]
  Local iv:Byte[]

  If FileMode(infile) > 0 And FileMode(keyfile) > 0
	arr = LoadByteArray(infile)
  Else
    Return -1
  EndIf

  ' Read keyfile
  file   = ReadStream(keyfile)
  key    = StringToByteArray(ReadLine(file))
  iv     = StringToByteArray(ReadLine(file))
  cipher = ReadLine(file)
  CloseStream(file)

  If Len(iv) <> 8
    Return -3
  EndIf

  If cipher = "aes_256_cbc"
    If Len(key) < 6 Or Len(key) > 6
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.aes_256_cbc()
	EndIf
  EndIf
  If cipher = "bf_cbc"
    If Len(key) < 3 Or Len(key) > 7
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.bf_cbc()
	EndIf
  EndIf
  If cipher = "cast5_cbc"
    If Len(key) < 4 Or Len(key) > 5
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.cast5_cbc()
	EndIf
  EndIf
  If cipher = "des_cbc"
    If Len(key) < 4 Or Len(key) > 4
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.des_cbc()
	EndIf
  EndIf  
  If cipher = "rc2_cbc"
    If Len(key) < 1 Or Len(key) > 5
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.rc2_cbc()
	EndIf
  EndIf
  If cipher = "rc4"
    If Len(key) < 4 Or Len(key) > 9
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.rc4()
	EndIf
  EndIf
  
  If cipher_ = Null Then Return -3
  
  ctx = New EVP_CIPHER_CTX.Create()
  ctx.CipherInit(cipher_, Null, Null, Null, True)
  ctx.SetKeyLength(key.length)
  ctx.CipherInit(cipher_, Null, key, iv, True)
  Local outbuf:Byte[BUF_SIZE + ctx.GetBlockSize()]
  Local length:Int = arr.length
  count = 0
  ' loop all the full blocks
  For i = 0 Until length / BUF_SIZE
	If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + BUF_SIZE], BUF_SIZE)
	  Return -2
	End If
	' update input buffer offset
	count :+ BUF_SIZE
	' store encrypted
	inbuf :+ outbuf[0..outlen]	
  Next

' encrypt remaining part block
  If length Mod BUF_SIZE
	If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + length Mod BUF_SIZE], length Mod BUF_SIZE)
	  Return -2
	End If	
	' update input buffer offset
	count :+ length Mod BUF_SIZE
	' store encrypted
	inbuf :+ outbuf[0..outlen]
  End If

  ' Tidy up
  If Not ctx.CipherFinal(outbuf, outlen) Then
	Return -2
  End If

  ' add any padding
  inbuf :+ outbuf[0..outlen]
  ctx.Cleanup()
  SaveByteArray(inbuf, outfile)

  ' Clear memory just in case
  For i = 0 Until inbuf.length
    inbuf[i] = 0
  Next
  For i = 0 Until outbuf.length
    outbuf[i] = 0
  Next
  For i = 0 Until arr.length
    arr[i] = 0
  Next
  For i = 0 Until key.length
    key[i] = 0
  Next
  For i = 0 Until iv.length
    iv[i] = 0
  Next

  Return True
End Function


' +++++++++++++++++++++++++++++++++++++++
' decrypt
' Return codes:
' -1 = File not found error
' -2 = Encrypt error
' -3 = Key file error
' +++++++++++++++++++++++++++++++++++++++

Function decrypt:Int(infile:String, outfile:String, keyfile:String)
  Local inbuf:Byte[]
  Local outbuf:Byte[]
  Local arr:Byte[]
  Local ctx:EVP_CIPHER_CTX
  Local cipher_:EVP_CIPHER
  Local cipher:String
  Local count:Int
  Const BUF_SIZE:Int = 2048 ' our block size
  Local outlen:Int
  Local i:Int
  Local file:TStream
  Local key:Byte[]
  Local iv:Byte[]
  Local length:Int

  If FileMode(infile) > 0 And FileMode(keyfile) > 0
	arr = LoadByteArray(infile)
  Else
    Return -1
  EndIf

  ' Read  & check keyfile
  file   = ReadStream(keyfile)
  key    = StringToByteArray(ReadLine(file))
  iv     = StringToByteArray(ReadLine(file))
  cipher = ReadLine(file)
  CloseStream(file)

  If Len(iv) <> 8
    Return -3
  EndIf

  If cipher = "aes_256_cbc"
    If Len(key) < 6 Or Len(key) > 6
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.aes_256_cbc()
	EndIf
  EndIf
  If cipher = "bf_cbc"
    If Len(key) < 3 Or Len(key) > 7
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.bf_cbc()
	EndIf
  EndIf
  If cipher = "cast5_cbc"
    If Len(key) < 4 Or Len(key) > 5
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.cast5_cbc()
	EndIf
  EndIf
  If cipher = "des_cbc"
    If Len(key) < 4 Or Len(key) > 4
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.des_cbc()
	EndIf
  EndIf  
  If cipher = "rc2_cbc"
    If Len(key) < 1 Or Len(key) > 5
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.rc2_cbc()
	EndIf
  EndIf
  If cipher = "rc4"
    If Len(key) < 4 Or Len(key) > 9
	  Return -3
	Else
	  cipher_ = EVP_CIPHER.rc4()
	EndIf
  EndIf
  
  If cipher_ = Null Then Return -3

  length = arr.length
  ctx = New EVP_CIPHER_CTX.Create()
  ctx.CipherInit(cipher_, Null, Null, Null, False)
  ctx.SetKeyLength(key.length)
  ctx.CipherInit(cipher_, Null, key, iv, False)
  outbuf = New Byte[BUF_SIZE + ctx.GetBlockSize() + 10]

  count = 0

  For i = 0 Until length / BUF_SIZE
	If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + BUF_SIZE], BUF_SIZE)
	  Return -2
	End If
    inbuf :+ outbuf[0..outlen]
    count :+ BUF_SIZE
  Next

  If length Mod BUF_SIZE
    If Not ctx.CipherUpdate(outbuf, outlen, arr[count..count + length Mod BUF_SIZE], length Mod BUF_SIZE)
      Return -2	
    End If
    inbuf :+ outbuf[0..outlen]
    count :+ length Mod BUF_SIZE
  End If


  If Not ctx.CipherFinal(outbuf, outLen)
    Return -2
  End If

  inbuf :+ outbuf[0..outlen]
  ctx.Cleanup()

  SaveByteArray(inbuf, outfile)

  ' Clear memory just in case
  For i = 0 Until inbuf.length
    inbuf[i] = 0
  Next
  For i = 0 Until outbuf.length
    outbuf[i] = 0
  Next
  For i = 0 Until arr.length
    arr[i] = 0
  Next
  For i = 0 Until key.length
    key[i] = 0
  Next
  For i = 0 Until iv.length
    iv[i] = 0
  Next

  Return True

End Function

'//Passord Generator
Function anpass:String(anplen:Int, ansens:Int)
  '$anplen = 8;        // Passord Lengde
  '$ansens = 0;        // Passord Case sensitive
  Local antype:Int = Rand(0,1)  ' Alpha/numerisk
  Local anlen:Int = Rand(0,2)   ' Rekke lengde
  Local antcount:Int = 0       ' Posisjon i rekke
  Local anpassword:String = ""
  Local tmpc:Int

  SeedRnd(MilliSecs())  

  Local i:Int = 0
  While i < anplen
    If antype = 0    '// Alpha
      If ansens = 1
        tmpc = Rand (0,1)
      Else 
        tmpc = 1
      EndIf
      If tmpc = 0
        anpassword$ = anpassword$ + Chr(Rand(65,71))  '//65 90 A-F
      EndIf
      If tmpc = 1
        anpassword$ = anpassword$ + Chr(Rand(97,102)) '//97 122 a-f
       EndIf
    EndIf
    If antype = 1    '// Numeric
      anpassword$ = anpassword$ + Chr(Rand(48,57))    '//48 58 0-9
    EndIf
    antcount = antcount + 1
    If antcount > anlen
      If antype = 0
		  antype = 1
		Else 
		  antype = 0
		EndIf
      anlen = Rand(0,2)
      antcount = 0
    EndIf
    i = i + 1
  Wend
  Return anpassword$
End Function

Brucey

(Posted 2013) [#19]

Well, I'm not sure why it isn't working in your first example, but if I use the decrypt functions, it seems to work.

Sub_Zero

(Posted 2013) [#20]

I can't get it to work even with your large file example when integrating in my larger programs... sometimes it works, sometimes it doesn't, and when turning on debug mode it breaks, and sometimes it works when commenting out import BRL.Eventqueue ! So I have no clue any more

Sub_Zero

(Posted 2013) [#21]

Hi

I've installed the latest ubuntu wich uses libssl-dev_1.0.1c, and i get this message when trying to compile a program using BaH.Crypto:

/home/BlitzMax/mod/bah.mod/crypto.mod/crypto.debug.linux.x86.a(crypto.bmx.debug.linux.x86.o): In function `_bah_crypto_EVP_CIPHER_des_cfb':
(code+0x1262): undefined reference to `EVP_des_cfb'
/home/BlitzMax/mod/bah.mod/crypto.mod/crypto.debug.linux.x86.a(crypto.bmx.debug.linux.x86.o): In function `_bah_crypto_EVP_CIPHER_des_ede_cfb':
(code+0x14e7): undefined reference to `EVP_des_ede_cfb'
/home/BlitzMax/mod/bah.mod/crypto.mod/crypto.debug.linux.x86.a(crypto.bmx.debug.linux.x86.o): In function `_bah_crypto_EVP_CIPHER_des_ede3_cfb':
(code+0x16eb): undefined reference to `EVP_des_ede3_cfb'
/home/BlitzMax/mod/bah.mod/crypto.mod/crypto.debug.linux.x86.a(crypto.bmx.debug.linux.x86.o): In function `_bah_crypto_EVP_CIPHER_bf_cfb':
(code+0x18ef): undefined reference to `EVP_bf_cfb'
/home/BlitzMax/mod/bah.mod/crypto.mod/crypto.debug.linux.x86.a(crypto.bmx.debug.linux.x86.o): In function `_bah_crypto_EVP_CIPHER_rc2_cfb':
(code+0x1b74): undefined reference to `EVP_rc2_cfb'
/home/BlitzMax/mod/bah.mod/crypto.mod/crypto.debug.linux.x86.a(crypto.bmx.debug.linux.x86.o): In function `_bah_crypto_EVP_CIPHER_cast5_cfb':
(code+0x1d78): undefined reference to `EVP_cast5_cfb'

Might be some changes in the latest libssl-dev?