Strange Issue with wxRadioButon/Box

BlitzMax Forums/Brucey's Modules/Strange Issue with wxRadioButon/Box

Pete Rigz

(Posted 2016) [#1]

I have a very strange issue with radio buttons, where by they're not unselecting as you select each one, so they all end up looking like they're all selected. Functionality wise they are working ok so it seems it's a display issue. Trouble is I can't isolate the issue, if I create an example app with a radio button it works fine. I have no idea what is different in TimelineFX that might be causing it. It's only happening in el capitan, mountain lion was fine on my old mac, and windows is all good too.

Any idea how I could go about debugging this? Or where I might look in the wx module?

Henri

(Posted 2016) [#2]

Hi,

problems happening on platform that I have no access to are hard to give an advice, but couple of things you could try:

1.
Try changing creation flags for radiobutton to see if it makes any difference.

2.
Is radiobutton attached to sizer ? if you unattach it does it make a difference ?
What if you create a sizer just for the radio group ?
Any bitmaps in same parent ? If it's an graphical glitch refreshing window might
show this.

3.
Check from https://github.com/maxmods
that you are running newest version.

-Henri

Derron

(Posted 2016) [#3]

WX from 2.9.4.0 to 2.9.5.0 fixed some issues with radio button groups ...

If you are able to select multiple RB without deselecting the other ones, they might not belong to the same "radio button group" (first one has to get style/flag "wxRB_GROUP").

From the docs: wx.mod/wxradiobutton.mod/wxradiobutton.bmx:

You can create a group of mutually-exclusive radio buttons by specifying wxRB_GROUP for the first in the
group. The group ends when another radio button group is created, or there are no more radio buttons.

Did you use the groups style?

bye
Ron

Pete Rigz

(Posted 2016) [#4]

This is with the latest checkout from git. The code in the program hasn't changed for a few years now and has always worked fine, it's just since the upgrade to el capitan.

Some of the things I've tried that haven't made a difference:
- forcing a refresh of the window.
- Using set value to force them to toggle off
- Using wxRB_SINGLE and manually setting them instead of exRB_GROUP.

It happens with wxRadioBox as well.

I do use bitmaps elsewhere in the tab so i'll try disabling those to see if it makes a difference. It must be due to a combination with something else as like I say, isolating in a separate app to test doesn't recreate the issue.

Derron

(Posted 2016) [#5]

Think as long as you are not able to provide a "sample" reproducing the bug, you are on your own.

Dunno how "modular" your code is, so you might easily disable certain things in your app until the bug is gone.

Maybe Brucey is able to update to the latest wxWidgets-variant on github and the bugs are gone. I just checked the last 3 months on the git commits of wxwidgets but while scanning the logs I did not find something useful (hard to find if you do not know what keywords a dev would use :-)).

bye
Ron

Henri

(Posted 2016) [#6]

Did you try creating a new sizer just for the radiobuttons ?

-Henri

Pete Rigz

(Posted 2016) [#7]

Problem solved! it was due to the fact that I'm rendering a graphics context at 60fps. The main problem being that I have timer that ticks every millisecond, I guess it was stopping the radio boxes from being redrawn. I needed it to tick at that rate otherwise it suffered a lot of stuttering in the preview window, however it doesn't seem to do that anymore so I can get away with a lower tick rate which fixes the problem.

I've kind of recreated the problem here with the glmax2d example, except it does manage to redraw them after a delay I guess because there's less stuff going on (In timelinefx they all end up being selected and not unselecting at all). I made it render 3 times every tick to show the issue more - if it is an issue. It does work fine on windows though. Click the radio buttons quickly to see it happening.

SuperStrict

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxglmax2D
Import wx.wxTimer
Import wx.wxPanel
Import wx.wxRadioBox

SetGraphicsDriver GLMax2DDriver()

New MyApp.run()


Type MyApp Extends wxApp

	Field frame:MyFrame

	Method OnInit:Int()

		' Create the main application windowType MyFrame Extends wxFrame

		frame = MyFrame(New MyFrame.Create(,,"", , , 640, 480))
		
		' Show it and tell the application that it's our main window
		frame.show(True)
		SetTopWindow(frame)

		Return True
	End Method

End Type

Type MyFrame Extends wxFrame

	Field canvas:MyCanvas

	Method OnInit()
		Local mainSizer:wxBoxSizer = New wxBoxSizer.Create(wxVERTICAL)
		SetSizer(mainSizer)

		canvas = MyCanvas(New MyCanvas.Create(Self, -1, GRAPHICS_BACKBUFFER|GRAPHICS_DEPTHBUFFER))
		
		Local panel:wxPanel = New wxPanel.Create(Self, - 1)
		
		Local effecttypes:String[] = ["Point", "Area", "Line", "Ellipse"]
		Local ep_effect_type:wxRadioBox = New wxRadioBox.Create(panel, wxID_HIGHEST + 1, "Effect Type",,, ,, effecttypes)
		
		mainSizer.Add(canvas,1, wxALL | wxEXPAND)
		mainSizer.Add(panel,0,wxAll | wxExpand)
	
		ConnectAny(wxEVT_CLOSE, OnClose)
	End Method
	
	Function OnClose(event:wxEvent)
		MyFrame(event.parent).canvas.timer.Stop() ' we really need to stop the timer on Mac...
		event.Skip()
	End Function

End Type


Type MyCanvas Extends wxGLCanvas

	Field timer:wxTimer
	Field cw:Int
	Field ch:Int

	Method OnInit()
		SetBackgroundStyle(wxBG_STYLE_CUSTOM)
	
		timer = New wxTimer.Create(Self)


		ConnectAny(wxEVT_TIMER, OnTick)
		connectany(wxEVT_SIZE, OnSize)

		timer.Start(1)
	End Method

	Method OnPaint(event:wxPaintEvent)
		Render()
		Render()
		Render()
	End Method
	
	Function OnSize(Event:wxEvent)
		Local w:Int, h:Int
		MyCanvas(event.parent).GetSize(w, h)
		MyCanvas(event.parent).cw = w
		MyCanvas(event.parent).ch = h
		MyCanvas(event.parent).Refresh()
	End Function

	Method Render()

		SetGraphics CanvasGraphics2D( Self )
		SetVirtualResolution(cw, ch)
		SetViewport(0, 0, cw, ch)

		SetClsColor(255, 255, 255)
		SetColor(0, 0, 0)
		
		Cls

		drawClock()
		
		Flip

	End Method

	Function OnTick(event:wxEvent)
		Local canvas: MyCanvas = MyCanvas(event.parent)
		
		canvas.Refresh()
		
	End Function
	
	
	Method drawClock()
	
		SetLineWidth(2)

		Local x:Int = 200, y:Int = 200
		Local radius:Int = 100
		' clock ticks
		For Local i:Int = 0 Until 12
			Local inset:Double = 0
		
			If i Mod 3 = 0 Then
				SetLineWidth(2)
				inset = 0.2 * radius
			Else
				inset = 0.1 * radius
				SetLineWidth(1)
			End If
			
			DrawLine x + (radius - inset) * Cos(i * 30), y + (radius - inset) * Sin(i * 30), ..
				x + radius * Cos(i * 30), y + radius * Sin (i * 30)
			
			' draw numbers
			inset = 0.3 * radius
			
			Local t:Int = (i + 2) Mod 12 + 1
			DrawText romanNumerals(t), x + (radius - inset) * Cos(i * 30) - 7, y + (radius - inset) * Sin(i * 30) - 6
		Next


		' clock hands
		Local hours:Int = CurrentTime()[0..2].toInt() Mod 12
		Local minutes:Int = CurrentTime()[3..5].toInt()
		Local seconds:Int = CurrentTime()[6..8].toInt()
		
		' hour hand:
		' the hour hand is rotated 30 degrees  per hour + 1/2 a degree per minute
		'
		SetLineWidth(4)

		DrawLine x, y, x + radius / 2 * Sin(30 * hours + minutes / 2.0), ..
				   y + radius / 2 * -Cos(30 * hours + minutes / 2.0)
		
		
		' minute hand:
		' the minute hand is rotated 6 degrees per minute + 1/10 a degree per second
		'
		SetLineWidth(2)
		DrawLine x, y, x + radius * 0.75 * Sin(6 * minutes + seconds / 10.0), ..
				   y + radius * 0.75 * -Cos(6 * minutes + seconds / 10.0)
		
		' seconds hand:
		' the second hand is rotated 6 degrees per second
		'
		SetColor(255, 0, 0)

		DrawLine x, y, x + radius * 0.7 * Sin(6 * seconds), ..
				   y + radius * 0.7 * -Cos(6 * seconds)


	End Method

	Method romanNumerals:String(value:Int)
		Local rn:String = ""
		
		While value > 9
			rn:+ "X"
			value:- 10
		Wend
	
		If value > 8 Then
			rn:+ "IX"
			value:- 9
		End If
		
		If value > 4 Then
			rn:+ "V"
			value:- 5
		End If
		
		If value > 3 Then
			rn:+ "IV"
			value:- 4
		End If
		
		While value > 0
			rn:+ "I"
			value:- 1
		Wend
		
		Return rn
	End Method

End Type

Derron

(Posted 2016) [#8]

Where does "wx.wxglmax2D" come from? Seems you use an older wxMax.

I adjusted it to use the current revisions:

SuperStrict

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxmax2D
Import wx.wxglcanvas
Import wx.wxTimer
Import wx.wxPanel
Import wx.wxRadioBox
Import Brl.GLMax2D
SetGraphicsDriver GLMax2DDriver()

New MyApp.run()


Type MyApp Extends wxApp

	Field frame:MyFrame

	Method OnInit:Int()

		' Create the main application windowType MyFrame Extends wxFrame

		frame = MyFrame(New MyFrame.Create(,,"", , , 640, 480))
		
		' Show it and tell the application that it's our main window
		frame.show(True)
		SetTopWindow(frame)

		Return True
	End Method

End Type

Type MyFrame Extends wxFrame

	Field canvas:MyCanvas

	Method OnInit()
		Local mainSizer:wxBoxSizer = New wxBoxSizer.Create(wxVERTICAL)
		SetSizer(mainSizer)

		canvas = MyCanvas(New MyCanvas.Create(Self, -1, GRAPHICS_BACKBUFFER|GRAPHICS_DEPTHBUFFER))
		
		Local panel:wxPanel = New wxPanel.Create(Self, - 1)
		
		Local effecttypes:String[] = ["Point", "Area", "Line", "Ellipse"]
		Local ep_effect_type:wxRadioBox = New wxRadioBox.Create(panel, wxID_HIGHEST + 1, "Effect Type",,, ,, effecttypes)
		
		mainSizer.Add(canvas,1, wxALL | wxEXPAND)
		mainSizer.Add(panel,0,wxAll | wxExpand)
	
		ConnectAny(wxEVT_CLOSE, OnClose)
	End Method
	
	Function OnClose(event:wxEvent)
		MyFrame(event.parent).canvas.timer.Stop() ' we really need to stop the timer on Mac...
		event.Skip()
	End Function

End Type


Type MyCanvas Extends wxGLCanvas

	Field timer:wxTimer
	Field cw:Int
	Field ch:Int

	Method OnInit()
		SetBackgroundStyle(wxBG_STYLE_CUSTOM)
	
		timer = New wxTimer.Create(Self)


		ConnectAny(wxEVT_TIMER, OnTick)
		connectany(wxEVT_SIZE, OnSize)

		timer.Start(1)
	End Method

	Method OnPaint(event:wxPaintEvent)
		Render()
		Render()
		Render()
	End Method
	
	Function OnSize(Event:wxEvent)
		Local w:Int, h:Int
		MyCanvas(event.parent).GetSize(w, h)
		MyCanvas(event.parent).cw = w
		MyCanvas(event.parent).ch = h
		MyCanvas(event.parent).Refresh()
	End Function

	Method Render()
rem
		SetGraphics Self.CanvasGraphics()
		SetVirtualResolution(cw, ch)
		SetViewport(0, 0, cw, ch)

		SetClsColor(255, 255, 255)
		SetColor(0, 0, 0)
		
		Cls

		drawClock()
		
		Flip
endrem
	End Method

	Function OnTick(event:wxEvent)
		Local canvas: MyCanvas = MyCanvas(event.parent)
		
		canvas.Refresh()
		
	End Function
	
	
	Method drawClock()
	
		SetLineWidth(2)

		Local x:Int = 200, y:Int = 200
		Local radius:Int = 100
		' clock ticks
		For Local i:Int = 0 Until 12
			Local inset:Double = 0
		
			If i Mod 3 = 0 Then
				SetLineWidth(2)
				inset = 0.2 * radius
			Else
				inset = 0.1 * radius
				SetLineWidth(1)
			End If
			
			DrawLine x + (radius - inset) * Cos(i * 30), y + (radius - inset) * Sin(i * 30), ..
				x + radius * Cos(i * 30), y + radius * Sin (i * 30)
			
			' draw numbers
			inset = 0.3 * radius
			
			Local t:Int = (i + 2) Mod 12 + 1
			DrawText romanNumerals(t), x + (radius - inset) * Cos(i * 30) - 7, y + (radius - inset) * Sin(i * 30) - 6
		Next


		' clock hands
		Local hours:Int = CurrentTime()[0..2].toInt() Mod 12
		Local minutes:Int = CurrentTime()[3..5].toInt()
		Local seconds:Int = CurrentTime()[6..8].toInt()
		
		' hour hand:
		' the hour hand is rotated 30 degrees  per hour + 1/2 a degree per minute
		'
		SetLineWidth(4)

		DrawLine x, y, x + radius / 2 * Sin(30 * hours + minutes / 2.0), ..
				   y + radius / 2 * -Cos(30 * hours + minutes / 2.0)
		
		
		' minute hand:
		' the minute hand is rotated 6 degrees per minute + 1/10 a degree per second
		'
		SetLineWidth(2)
		DrawLine x, y, x + radius * 0.75 * Sin(6 * minutes + seconds / 10.0), ..
				   y + radius * 0.75 * -Cos(6 * minutes + seconds / 10.0)
		
		' seconds hand:
		' the second hand is rotated 6 degrees per second
		'
		SetColor(255, 0, 0)

		DrawLine x, y, x + radius * 0.7 * Sin(6 * seconds), ..
				   y + radius * 0.7 * -Cos(6 * seconds)


	End Method

	Method romanNumerals:String(value:Int)
		Local rn:String = ""
		
		While value > 9
			rn:+ "X"
			value:- 10
		Wend
	
		If value > 8 Then
			rn:+ "IX"
			value:- 9
		End If
		
		If value > 4 Then
			rn:+ "V"
			value:- 5
		End If
		
		If value > 3 Then
			rn:+ "IV"
			value:- 4
		End If
		
		While value > 0
			rn:+ "I"
			value:- 1
		Wend
		
		Return rn
	End Method

End Type

Changes:
- see "imports"
- SetGraphics Self.CanvasGraphics()

But running results in an error (seems "Samples/glcube.bmx" does it similar - and fails similar):

./bmk makeapp -t console -quick -r -x "testcodes/wxlag.bmx"
[ 96%] Processing:wxlag.bmx
[ 98%] Compiling:wxlag.bmx.console.release.linux.x86.s
flat assembler  version 1.68  (32768 kilobytes memory)
3 passes, 29315 bytes.
[100%] Linking:wxlag
Executing:wxlag
The program 'wxlag' received an X Window System error.
This probably reflects a bug in the program.
The error was 'BadDrawable (invalid Pixmap or Window parameter)'.
  (Details: serial 29 error_code 9 request_code 14 minor_code 0)
  (Note to programmers: normally, X errors are reported asynchronously;
   that is, you will receive the error a while after causing it.
   To debug your program, run it with the --sync command line
   option to change this behavior. You can then get a meaningful
   backtrace from your debugger if you break on the gdk_x_error() function.)

commenting the "render" functionality, the app starts, so something with the GL canvas is bugging out the app.

bye
Ron

Pete Rigz

(Posted 2016) [#9]

Ahh yes I forgot about that, I think Brucey removed wxglmax2d at some point so I did have to put it back because I still use it (apart from that though it is the latest wx). Why I still use it though I can't remember as it's been a few years, there is a reason though!

Derron

(Posted 2016) [#10]

So you mixed "new" and "old" ...dunno if this is flawed then already.

older wxWidgets lead to some debug messages in the console, so an update is nice to have - albeit "3.1" (which is what Brucey uses) is not stable.

Next to wxglmax2D you of course also use another wxglcanvas.mod then (the current one has the wxGLGraphics commented out - maybe for some reason?).

Nonetheless I created an issue for this on github, so Brucey might tackle it somewhen in the future.

bye
Ron

Pete Rigz

(Posted 2016) [#11]

Yes I did have to uncomment those as well. I shall have to try and make it work without needing glmax2d, then I'll probably find out why I needed it, although it wouldn't surprise me if it's not necessary anymore.

Thanks for taking a look anyway.

Derron

(Posted 2016) [#12]

Try the following:

SuperStrict

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxmax2D
Import wx.wxTimer
Import wx.wxPanel
Import wx.wxRadioBox

New MyApp.run()


Type MyApp Extends wxApp

	Field frame:MyFrame

	Method OnInit:Int()

		' Create the main application windowType MyFrame Extends wxFrame

		frame = MyFrame(New MyFrame.Create(,,"", , , 640, 480))
		
		' Show it and tell the application that it's our main window
		frame.show(True)
		SetTopWindow(frame)

		Return True
	End Method

End Type


Type MyFrame Extends wxFrame

	Field canvas:MyCanvas

	Method OnInit:Int()
		Local mainSizer:wxBoxSizer = New wxBoxSizer.Create(wxVERTICAL)
		SetSizer(mainSizer)
				
		canvas = MyCanvas(New MyCanvas.CreateWin(Self))
		
		Local panel:wxPanel = New wxPanel.Create(Self, - 1)
		
		Local effecttypes:String[] = ["Point", "Area", "Line", "Ellipse"]
		Local ep_effect_type:wxRadioBox = New wxRadioBox.Create(panel, wxID_HIGHEST + 1, "Effect Type",,, ,, effecttypes)
		
		mainSizer.Add(canvas,1, wxALL | wxEXPAND)
		mainSizer.Add(panel,0,wxAll | wxExpand)

		ConnectAny(wxEVT_CLOSE, OnClose)
	End Method

	Function OnClose(event:wxEvent)
		MyFrame(event.parent).canvas.timer.Stop() ' we really need to stop the timer on Mac...
		'not in your code
		'wxWindow(event.parent).Destroy() ' remove the frame

		event.Skip()
	End Function

End Type


Type MyCanvas Extends wxWindow

	Field timer:wxTimer
	Field cw:Int
	Field ch:Int

	Method OnInit:Int()
		SetBackgroundStyle(wxBG_STYLE_CUSTOM)
	
		timer = New wxTimer.Create(Self)


		ConnectAny(wxEVT_PAINT, OnPaint)
		ConnectAny(wxEVT_TIMER, OnTick)
		connectany(wxEVT_SIZE, OnSize)

		timer.Start(1)
	End Method


	Function OnPaint(event:wxEvent)
		Local canvas:MyCanvas = MyCanvas(event.parent)
		canvas.Paint()
	End Function
	
	Method Paint()
		Render()
		Render()
		Render()
	End Method
	
	Function OnSize(Event:wxEvent)
		Local w:Int, h:Int
		MyCanvas(event.parent).GetSize(w, h)
		MyCanvas(event.parent).cw = w
		MyCanvas(event.parent).ch = h
		MyCanvas(event.parent).Refresh()
	End Function

	Method Render()
		SetGraphics wxGraphics(self)
		SetVirtualResolution(cw, ch)
		SetViewport(0, 0, cw, ch)

		SetClsColor(255, 255, 255)
		SetColor(0, 0, 0)
		
		Cls

		drawClock()
		
		Flip

	End Method

	Function OnTick(event:wxEvent)
		wxWindow(event.parent).Refresh()
	End Function
	
	
	Method drawClock()
	
		SetLineWidth(2)

		Local x:Int = 200, y:Int = 200
		Local radius:Int = 100
		' clock ticks
		For Local i:Int = 0 Until 12
			Local inset:Double = 0
		
			If i Mod 3 = 0 Then
				SetLineWidth(2)
				inset = 0.2 * radius
			Else
				inset = 0.1 * radius
				SetLineWidth(1)
			End If
			
			DrawLine x + (radius - inset) * Cos(i * 30), y + (radius - inset) * Sin(i * 30), ..
				x + radius * Cos(i * 30), y + radius * Sin (i * 30)
			
			' draw numbers
			inset = 0.3 * radius
			
			Local t:Int = (i + 2) Mod 12 + 1
			DrawText romanNumerals(t), x + (radius - inset) * Cos(i * 30) - 7, y + (radius - inset) * Sin(i * 30) - 6
		Next


		' clock hands
		Local hours:Int = CurrentTime()[0..2].toInt() Mod 12
		Local minutes:Int = CurrentTime()[3..5].toInt()
		Local seconds:Int = CurrentTime()[6..8].toInt()
		
		' hour hand:
		' the hour hand is rotated 30 degrees  per hour + 1/2 a degree per minute
		'
		SetLineWidth(4)

		DrawLine x, y, x + radius / 2 * Sin(30 * hours + minutes / 2.0), ..
				   y + radius / 2 * -Cos(30 * hours + minutes / 2.0)
		
		
		' minute hand:
		' the minute hand is rotated 6 degrees per minute + 1/10 a degree per second
		'
		SetLineWidth(2)
		DrawLine x, y, x + radius * 0.75 * Sin(6 * minutes + seconds / 10.0), ..
				   y + radius * 0.75 * -Cos(6 * minutes + seconds / 10.0)
		
		' seconds hand:
		' the second hand is rotated 6 degrees per second
		'
		SetColor(255, 0, 0)

		DrawLine x, y, x + radius * 0.7 * Sin(6 * seconds), ..
				   y + radius * 0.7 * -Cos(6 * seconds)


	End Method

	Method romanNumerals:String(value:Int)
		Local rn:String = ""
		
		While value > 9
			rn:+ "X"
			value:- 10
		Wend
	
		If value > 8 Then
			rn:+ "IX"
			value:- 9
		End If
		
		If value > 4 Then
			rn:+ "V"
			value:- 5
		End If
		
		If value > 3 Then
			rn:+ "IV"
			value:- 4
		End If
		
		While value > 0
			rn:+ "I"
			value:- 1
		Wend
		
		Return rn
	End Method

End Type

I replaced some portions in your code - it now uses the standard wxmax2d.mod

Just the changes (diff):

--- <old>
+++ <new>
@@ -2,13 +2,11 @@
 
 Framework wx.wxApp
 Import wx.wxFrame
-Import wx.wxglmax2D
+Import wx.wxmax2D
 Import wx.wxTimer
 Import wx.wxPanel
 Import wx.wxRadioBox
 
-SetGraphicsDriver GLMax2DDriver()
-
 New MyApp.run()
 
 
@@ -31,15 +29,16 @@
 
 End Type
 
+
 Type MyFrame Extends wxFrame
 
 	Field canvas:MyCanvas
 
-	Method OnInit()
+	Method OnInit:Int()
 		Local mainSizer:wxBoxSizer = New wxBoxSizer.Create(wxVERTICAL)
 		SetSizer(mainSizer)
-
-		canvas = MyCanvas(New MyCanvas.Create(Self, -1, GRAPHICS_BACKBUFFER|GRAPHICS_DEPTHBUFFER))
+				
+		canvas = MyCanvas(New MyCanvas.CreateWin(Self))
 		
 		Local panel:wxPanel = New wxPanel.Create(Self, - 1)
 		
@@ -54,31 +53,41 @@
 	
 	Function OnClose(event:wxEvent)
 		MyFrame(event.parent).canvas.timer.Stop() ' we really need to stop the timer on Mac...
+		'not in your code
+		'wxWindow(event.parent).Destroy() ' remove the frame
+
 		event.Skip()
 	End Function
 
 End Type
 
 
-Type MyCanvas Extends wxGLCanvas
+Type MyCanvas Extends wxWindow
 
 	Field timer:wxTimer
 	Field cw:Int
 	Field ch:Int
 
-	Method OnInit()
+	Method OnInit:Int()
 		SetBackgroundStyle(wxBG_STYLE_CUSTOM)
 	
 		timer = New wxTimer.Create(Self)
 
 
+		ConnectAny(wxEVT_PAINT, OnPaint)
 		ConnectAny(wxEVT_TIMER, OnTick)
 		connectany(wxEVT_SIZE, OnSize)
 
 		timer.Start(1)
 	End Method
 
-	Method OnPaint(event:wxPaintEvent)
+
+	Function OnPaint(event:wxEvent)
+		Local canvas:MyCanvas = MyCanvas(event.parent)
+		canvas.Paint()
+	End Function
+	
+	Method Paint()
 		Render()
 		Render()
 		Render()
@@ -93,8 +102,7 @@
 	End Function
 
 	Method Render()
-
-		SetGraphics CanvasGraphics2D( Self )
+		SetGraphics wxGraphics(self)
 		SetVirtualResolution(cw, ch)
 		SetViewport(0, 0, cw, ch)
 
@@ -110,10 +118,7 @@
 	End Method
 
 	Function OnTick(event:wxEvent)
-		Local canvas: MyCanvas = MyCanvas(event.parent)
-		
-		canvas.Refresh()
-		
+		wxWindow(event.parent).Refresh()
 	End Function

Pete Rigz

(Posted 2016) [#13]

Ok, so i found out why I use glmax2d :)

I had a go at using wxmax2d but looking in that module I notice that it doesn't actually use gl or dx rendering at all, it uses a DC context which isn't any good for particle rendering as it's basically software rendering. This also means that standard functions in max2d like setclsolor don't work as they're all remmed out in the driver.

@Brucey: was their a specific reason this was changed like this? It's no biggy really as I can just use the wxglmax2d.mod which I still have and edit wxglcanvas to uncomment everything so it works with the standard max2d commands. Be nice if it was in there officially though, unless i'm missing something!

Brucey

(Posted 2016) [#14]

Hallo :-)

Does this work for you?

SuperStrict

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxGLCanvas
Import wx.wxTimer
Import wx.wxPanel
Import wx.wxRadioBox
Import brl.glmax2d


New MyApp.run()


Type MyApp Extends wxApp

	Field frame:MyFrame

	Method OnInit:Int()

		' Create the main application windowType MyFrame Extends wxFrame

		frame = MyFrame(New MyFrame.Create(,,"", , , 640, 480))
		
		' Show it and tell the application that it's our main window
		frame.show(True)
		SetTopWindow(frame)

		Return True
	End Method

End Type


Type MyFrame Extends wxFrame

	Field canvas:MyCanvas

	Method OnInit:Int()
		Local mainSizer:wxBoxSizer = New wxBoxSizer.Create(wxVERTICAL)
		SetSizer(mainSizer)
				
		canvas = MyCanvas(New MyCanvas.Create(Self, -1, GRAPHICS_BACKBUFFER|GRAPHICS_DEPTHBUFFER))
		
		Local panel:wxPanel = New wxPanel.Create(Self, - 1)
		
		Local effecttypes:String[] = ["Point", "Area", "Line", "Ellipse"]
		Local ep_effect_type:wxRadioBox = New wxRadioBox.Create(panel, wxID_HIGHEST + 1, "Effect Type",,, ,, effecttypes)
		
		mainSizer.Add(canvas,1, wxALL | wxEXPAND)
		mainSizer.Add(panel,0,wxAll | wxExpand)

		ConnectAny(wxEVT_CLOSE, OnClose)
	End Method

	Function OnClose(event:wxEvent)
		MyFrame(event.parent).canvas.timer.Stop() ' we really need to stop the timer on Mac...
		'not in your code
		'wxWindow(event.parent).Destroy() ' remove the frame

		event.Skip()
	End Function

End Type


Type MyCanvas Extends wxGLCanvas

	Field timer:wxTimer
	Field cw:Int
	Field ch:Int

	Method OnInit:Int()
		SetBackgroundStyle(wxBG_STYLE_CUSTOM)
	
		timer = New wxTimer.Create(Self)


		ConnectAny(wxEVT_TIMER, OnTick)
		connectany(wxEVT_SIZE, OnSize)

		timer.Start(1)
	End Method


	Method OnPaint(event:wxPaintEvent)
		Render()
	End Method
	
	Function OnSize(Event:wxEvent)
		Local w:Int, h:Int
		MyCanvas(event.parent).GetSize(w, h)
		MyCanvas(event.parent).cw = w
		MyCanvas(event.parent).ch = h
		MyCanvas(event.parent).Refresh()
	End Function

	Method Render()
		SetGraphics CanvasGraphics()
		SetVirtualResolution(cw, ch)
		SetViewport(0, 0, cw, ch)

		SetClsColor(255, 255, 255)
		SetColor(0, 0, 0)
		
		Cls

		drawClock()
		
		Flip

	End Method

	Function OnTick(event:wxEvent)
		wxWindow(event.parent).Refresh()
	End Function
	
	
	Method drawClock()
	
		SetLineWidth(2)

		Local x:Int = 200, y:Int = 200
		Local radius:Int = 100
		' clock ticks
		For Local i:Int = 0 Until 12
			Local inset:Double = 0
		
			If i Mod 3 = 0 Then
				SetLineWidth(2)
				inset = 0.2 * radius
			Else
				inset = 0.1 * radius
				SetLineWidth(1)
			End If
			
			DrawLine x + (radius - inset) * Cos(i * 30), y + (radius - inset) * Sin(i * 30), ..
				x + radius * Cos(i * 30), y + radius * Sin (i * 30)
			
			' draw numbers
			inset = 0.3 * radius
			
			Local t:Int = (i + 2) Mod 12 + 1
			DrawText romanNumerals(t), x + (radius - inset) * Cos(i * 30) - 7, y + (radius - inset) * Sin(i * 30) - 6
		Next


		' clock hands
		Local hours:Int = CurrentTime()[0..2].toInt() Mod 12
		Local minutes:Int = CurrentTime()[3..5].toInt()
		Local seconds:Int = CurrentTime()[6..8].toInt()
		
		' hour hand:
		' the hour hand is rotated 30 degrees  per hour + 1/2 a degree per minute
		'
		SetLineWidth(4)

		DrawLine x, y, x + radius / 2 * Sin(30 * hours + minutes / 2.0), ..
				   y + radius / 2 * -Cos(30 * hours + minutes / 2.0)
		
		
		' minute hand:
		' the minute hand is rotated 6 degrees per minute + 1/10 a degree per second
		'
		SetLineWidth(2)
		DrawLine x, y, x + radius * 0.75 * Sin(6 * minutes + seconds / 10.0), ..
				   y + radius * 0.75 * -Cos(6 * minutes + seconds / 10.0)
		
		' seconds hand:
		' the second hand is rotated 6 degrees per second
		'
		SetColor(255, 0, 0)

		DrawLine x, y, x + radius * 0.7 * Sin(6 * seconds), ..
				   y + radius * 0.7 * -Cos(6 * seconds)


	End Method

	Method romanNumerals:String(value:Int)
		Local rn:String = ""
		
		While value > 9
			rn:+ "X"
			value:- 10
		Wend
	
		If value > 8 Then
			rn:+ "IX"
			value:- 9
		End If
		
		If value > 4 Then
			rn:+ "V"
			value:- 5
		End If
		
		If value > 3 Then
			rn:+ "IV"
			value:- 4
		End If
		
		While value > 0
			rn:+ "I"
			value:- 1
		Wend
		
		Return rn
	End Method

End Type

Note we are extending wxGLCanvas.
Also note how the Canvas is created, that wxGLCanvas already handles OnPaint (we just need to override the OnPaint method), and SetGraphics calls the wxGLCanvas method CanvasGraphics().
This is using the built-in brl.glmax2d (as it should really).

Basically all we are doing is setting up a GL context with wxGLCanvas - glmax2d shouldn't care how we've done that. It just wants something to draw on.

This is a better implementation as it uses the stuff already available, rather than copying and replicating a whole bunch of functionality.

Pete Rigz

(Posted 2016) [#15]

Yes that does work!

I was extending wxglcanvas but i was using wxmax2d not brl.glmax2d which is a bit daft, thought I was missing something :)

Thanks!