changing tree ctrl for a window

BlitzMax Forums/Brucey's Modules/changing tree ctrl for a window

UNZ	(Posted 2013) [#1]

Hi folks,

I try to create multiple wxTreeCtrl to store data. But only one of them should be visible.
My thought is to hide the unused trees and only show the active. Problem is that the active tree is not resized, unless you resize the window.

It seems like Refresh() and Update() do nothing...

example:

SuperStrict

Framework wx.wxApp
Import wx.wxPanel
Import wx.wxFrame
Import wx.wxButton
Import wx.wxTreeCtrl

Import brl.map
Import brl.random

New MyApp.Run()

Type MyApp Extends wxApp

	Field frame:MyFrame

	'-----------------------------------------------------
	Method OnInit:Int()
		frame = MyFrame(New MyFrame.Create(Null, wxID_ANY) )
		frame.Show()
		Return True
	End Method
End Type

Type MyFrame Extends wxFrame

	Field map:TMap = New TMap
	Field tree:wxTreeCtrl
	Field sizer:wxSizer
	Field id:Int
	
	Const MAX_TREES:Int= 5
	Const ID_NEXT:Int = 1
	
	'-----------------------------------------------------
	Method OnInit()
		Local menubar:wxMenuBar = New wxMenuBar.Create()
		SetMenuBar(menuBar)
		Local menu:wxMenu = New wxMenu.Create()
		menubar.Append(menu, "file")
		
		menu.Append(ID_NEXT, "next")
		
		Connect(ID_NEXT, wxEVT_COMMAND_MENU_SELECTED, OnNext, Self)
		
		For Local i:Int = 0 To MAX_TREES - 1
			AddTree(String(i) )
		Next
	End Method
	
	'-----------------------------------------------------
	Rem
		bbdoc: set next tree to active
	End Rem
	Function OnNext(event:wxEvent)
		Local f:MyFrame = MyFrame(event.userData)
		
		f.id :+ 1
		f.id = f.id Mod MAX_TREES
		Local t:wxTreeCtrl = wxTreeCtrl(f.map.ValueForKey(String(f.id) ) )
		f.SetTree(t)
	End Function
	
	'-----------------------------------------------------
	Rem
		bbdoc: create and add a new tree to the map
	End Rem
	Method AddTree(key$)
		Local t:wxTreeCtrl = wxTreeCtrl(map.ValueForKey(key) )
		If Not t
			t = CreateTree(key)
			map.Insert(key, t)
		EndIf
		SetTree(t)
	End Method
	
	'-----------------------------------------------------
	Rem
		bbdoc: change the active tree
	End Rem
	Method SetTree(t:wxTreeCtrl)
		If Not t Then DebugLog "no tree to set"
		If t And t <> tree
			sizer = New wxBoxSizer.Create(wxHORIZONTAL)
			
			'hide old tree
			If tree Then tree.Hide()
			
			'remember new tree
			tree = t
			
			'set size for new tree
			sizer.Add(t, 1, wxEXPAND)
			SetSizer(sizer, True)
			
			Refresh(True) 'nothing happens?
			Update() 'nothing happens?
			
			'show new
			t.Show()
		EndIf
	End Method
	
	'-----------------------------------------------------
	Rem
		bbdoc: create a tree with some content
	End Rem
	Method CreateTree:wxTreeCtrl(key$)
		Local t:wxTreeCtrl = New wxTreeCtrl.Create(Self, wxID_ANY)
		Local root:wxTreeItemId = t.AddRoot("root")
		t.AppendItem(root, key + "_a")
		t.AppendItem(root, key + "_b")
		t.AppendItem(root, key + "_b")
		t.ExpandAll()
		
		Return t
	End Method
End Type

Derron

(Posted 2013) [#2]

What happens if you use a parent panel for each treectrl?

Then just resize that parent panels according to your whishes (or hide them or ...).

As this would only be hacking I assume there is just something missing in the code sending out the correct event...

bye
Ron

UNZ	(Posted 2013) [#3]

I found a solution.
Looks like the problem was that the sizer did not update or whatever.

Sizers have their own Show() method. And a method Layout() to apply such changes. After I hide the old ctrl and show the new ctrl both with the sizer's method everything works.

example:

SuperStrict

Framework wx.wxApp
Import wx.wxPanel
Import wx.wxFrame
Import wx.wxButton
Import wx.wxTreeCtrl

Import brl.map
Import brl.random

New MyApp.Run()

Type MyApp Extends wxApp

	Field frame:MyFrame

	'-----------------------------------------------------
	Method OnInit:Int()
		frame = MyFrame(New MyFrame.Create(Null, wxID_ANY) )
		frame.Show()
		Return True
	End Method
End Type

Type MyFrame Extends wxFrame

	Field map:TMap = New TMap
	Field tree:wxTreeCtrl
	Field sizer:wxSizer
	Field id:Int
	
	Const MAX_TREES:Int= 5
	Const ID_NEXT:Int = 1
	
	'-----------------------------------------------------
	Method OnInit()
		Local menubar:wxMenuBar = New wxMenuBar.Create()
		SetMenuBar(menuBar)
		Local menu:wxMenu = New wxMenu.Create()
		menubar.Append(menu, "file")
		
		menu.Append(ID_NEXT, "next")
		
		Connect(ID_NEXT, wxEVT_COMMAND_MENU_SELECTED, OnNext, Self)
		
		sizer = New wxBoxSizer.Create(wxHORIZONTAL)
		SetSizer(sizer)
		For Local i:Int = 0 To MAX_TREES - 1
			tree = AddTree(String(i) )
		Next
	End Method
	
	'-----------------------------------------------------
	Rem
		bbdoc: set next tree to active
	End Rem
	Function OnNext(event:wxEvent)
		Local f:MyFrame = MyFrame(event.userData)
		
		f.id :+ 1
		f.id = f.id Mod MAX_TREES
		Local t:wxTreeCtrl = wxTreeCtrl(f.map.ValueForKey(String(f.id) ) )
		f.SetTree(t)
	End Function
	
	'-----------------------------------------------------
	Rem
		bbdoc: create and add a new tree to the map
	End Rem
	Method AddTree:wxTreeCtrl(key$)
		Local t:wxTreeCtrl = wxTreeCtrl(map.ValueForKey(key) )
		If Not t
			t = CreateTree(key)
			map.Insert(key, t)
		EndIf
		SetTree(t)
		Return t
	End Method
	
	'-----------------------------------------------------
	Rem
		bbdoc: change the active tree
	End Rem
	Method SetTree(t:wxTreeCtrl)
		If Not t Then DebugLog "no tree to set"
		If t And t <> tree
			'hide old tree
			If tree Then sizer.Show(tree, False)
			
			'remember new tree
			tree = t
			
			'show new
			sizer.Show(t, True)
			
			'set sizer for new tree
			sizer.Layout()
		EndIf
	End Method
	
	'-----------------------------------------------------
	Rem
		bbdoc: create a tree with some content
	End Rem
	Method CreateTree:wxTreeCtrl(key$)
		Local t:wxTreeCtrl = New wxTreeCtrl.Create(Self, wxID_ANY)
		sizer.Add(t, 1, wxEXPAND)
		sizer.Show(t, False)
		Local root:wxTreeItemId = t.AddRoot("root")
		For Local i:Int = 0 To 30
			t.AppendItem(root, key + "_" + i)
		Next
		t.ExpandAll()
		
		Return t
	End Method
End Type

Derron

(Posted 2013) [#4]

Think the sizers are something like a dynamically sized panel (or "rectangle widget"). So they need to get resized to adjust their children. Maybe they do something like "auto full size / extend" for their children (think Delphi had such behaviour for some of its components).
If not, they should not care about their children. You then would have a hidden Tree but an still expanded sizer.

But glad you found a workaround (people are awaiting next release :D).

bye
Ron