Wx Issues

BlitzMax Forums/Brucey's Modules/Wx Issues

Pete Rigz

(Posted 2013) [#1]

Sorry, me again :)

So TimelineFX is compiling ok however I'm getting one or two errors occurring. The first one in dialog boxes dont seem to be returning string in a friendly way. Here's a sample program that replicates the issue:

'
' wxAboutBox sample
'
'
'
SuperStrict

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxAboutBox
Import wx.wxFileDialog
Import wx.wxBusyInfo


New MyApp.run()


Type MyApp Extends wxApp

	Field frame:MyFrame
	Field file_menu_importshape:wxMenuItem

	Method OnInit:Int()

		frame = MyFrame(New MyFrame.Create(, -1, "AboutBox example"))
		
		frame.Center()
		frame.Show()
		
	
		Return True
	
	End Method

End Type

Type MyFrame Extends wxFrame

	Method OnInit()
	
		' create a menu bar
		
		Local fileMenu:wxMenu = wxMenu.CreateMenu()
		
		' the "About" item should be in the help menu
		Local helpMenu:wxMenu = wxMenu.CreateMenu()
		Local file_menu_importshape:wxMenuItem
		
		helpMenu.Append(wxID_ABOUT, "&About...~tF1", "Show about dialog")
		
		fileMenu.Append(wxID_EXIT, "E&xit~tAlt-X", "Quit this program")
		file_menu_importshape = New wxMenuItem.CreateMenuItem(fileMenu, 9999, "Import &Shape~tCTRL+SHIFT+I", "Load a particle shape")
		fileMenu.AppendItem(file_menu_importshape)
		
		' now append the freshly created menu to the menu bar...
		Local menuBar:wxMenuBar = wxMenuBar.CreateMenuBar()
		menuBar.Append(fileMenu, "&File")
		menuBar.Append(helpMenu, "&Help")
		

		SetMenuBar(menuBar)
		
		' create a status bar just for fun
		CreateStatusBar(2)
		SetStatusText("Welcome to wxWidgets!")
		
		Connect(wxID_EXIT, wxEVT_COMMAND_MENU_SELECTED, OnQuit)
		Connect(wxID_ABOUT, wxEVT_COMMAND_MENU_SELECTED, OnAbout)
		Connect(9999, wxEVT_COMMAND_MENU_SELECTED, OnImportShape)
		
	End Method

	Function OnQuit(event:wxEvent)
		' true is to force the frame to close
		wxWindow(event.parent).Close(True)
	End Function
	
	Function OnAbout(event:wxEvent)
		
		Local info:wxAboutDialogInfo = New wxAboutDialogInfo.Create()
		
		info.SetName("My Program")
		info.SetVersion("1.2.3 Beta")
		info.SetDescription("This program does something great.")
		info.SetCopyright("(C) 2007 Me <my@...;")
		
		' uncomment to see "generic" about box
		'info.SetWebSite("http://www.blitzmax.com", "Visit BlitzMax for cool stuff!")
		
		wxAboutBox(info)
		
	End Function
	
	Function OnImportShape(event:wxEvent)
		Local OpenLib:wxFileDialog = New wxFileDialog.Create(wxWindow(event.parent), "Load a Particle Shape",, ,  ..
			, wxFD_OPEN | wxFD_MULTIPLE)
		If openlib.Showmodal() = wxID_OK
			Local busyinfo:wxBusyInfo = New wxBusyInfo.CreateBusyInfo("Please wait, Loading shape...")
			For Local filename:String = EachIn OpenLib.GetPaths()
				DebugLog filename

			Next
			busyinfo.Free()
		End If
		openlib.free()
	End Function
	
End Type

Just select any file and see what debuglog throws up, I'm getting:

DebugLog:E\ieieXPrcehpsEpoin\asi.n

Any ideas? Thanks!

Brucey

(Posted 2013) [#2]

Apologies. I seem to have introduced a string problem in a recent commit.

It should be working again now.

Pete Rigz

(Posted 2013) [#3]

Great thanks Brucey :)

Pete Rigz

(Posted 2013) [#4]

I also have an issue with capturing the mouse. If I double click on the canvas window or If I click on another window and the mouse happens to be also over the canvas window it throws an error:

Assert "GetCapture() == this" failed in ReleaseMouse(): attempt to release mouse but this window hasn't captured it.

I recreated int eh glCanvas sample, just try double clicking on the canvas:

SuperStrict

Framework wx.wxApp
Import wx.wxFrame
Import wx.wxglmax2D
Import wx.wxTimer
Import wx.wxMouseEvent

SetGraphicsDriver GLMax2DDriver()

New MyApp.run()


Type MyApp Extends wxApp

	Field frame:MyFrame

	Method OnInit:Int()

		' Create the main application windowType MyFrame Extends wxFrame

		frame = MyFrame(New MyFrame.Create(,,"", , , 640, 480))
		
		' Show it and tell the application that it's our main window
		frame.show(True)
		SetTopWindow(frame)

		Return True
	End Method

End Type

Type MyFrame Extends wxFrame

	Field canvas:MyCanvas

	Method OnInit()

		canvas = MyCanvas(New MyCanvas.Create(Self, -1, GRAPHICS_BACKBUFFER|GRAPHICS_DEPTHBUFFER))
	
		ConnectAny(wxEVT_CLOSE, OnClose)
	End Method
	
	Function OnClose(event:wxEvent)
		MyFrame(event.parent).canvas.timer.Stop() ' we really need to stop the timer on Mac...
		event.Skip()
	End Function

End Type


Type MyCanvas Extends wxGLCanvas

	Field timer:wxTimer
	Field left_mouse_state:Int

	Method OnInit()
		SetBackgroundStyle(wxBG_STYLE_CUSTOM)
	
		timer = New wxTimer.Create(Self)


		ConnectAny(wxEVT_TIMER, OnTick)
		ConnectAny(wxEVT_MOUSE_EVENTS, onMouse)

		timer.Start(100)
	End Method

	Method OnPaint(event:wxPaintEvent)
		Render()
	End Method

	Method Render()

		SetGraphics CanvasGraphics2D( Self )

		SetClsColor(255, 255, 255)
		SetColor(0, 0, 0)
		
		Cls

		drawClock()
		
		Flip

	End Method

	Function OnTick(event:wxEvent)
		wxWindow(event.parent).Refresh()
	End Function
	
	Function onMouse(event:wxEvent)
		Local evt:wxMouseEvent = wxMouseEvent(event)
		Local canvas:MyCanvas = MyCanvas(event.parent)
		Select evt.GetEventType()
			Case wxEVT_MOTION
			Case wxEVT_LEFT_DOWN
				canvas.left_mouse_state = True
				canvas.CaptureMouse()
			Case wxEVT_LEFT_UP
				canvas.left_mouse_state = False
				canvas.ReleaseMouse()
		End Select
	End Function	
	
	
	Method drawClock()
	
		SetLineWidth(2)

		Local x:Int = 200, y:Int = 200
		Local radius:Int = 100
		' clock ticks
		For Local i:Int = 0 Until 12
			Local inset:Double = 0
		
			If i Mod 3 = 0 Then
				SetLineWidth(2)
				inset = 0.2 * radius
			Else
				inset = 0.1 * radius
				SetLineWidth(1)
			End If
			
			DrawLine x + (radius - inset) * Cos(i * 30), y + (radius - inset) * Sin(i * 30), ..
				x + radius * Cos(i * 30), y + radius * Sin (i * 30)
			
			' draw numbers
			inset = 0.3 * radius
			
			Local t:Int = (i + 2) Mod 12 + 1
			DrawText romanNumerals(t), x + (radius - inset) * Cos(i * 30) - 7, y + (radius - inset) * Sin(i * 30) - 6
		Next


		' clock hands
		Local hours:Int = CurrentTime()[0..2].toInt() Mod 12
		Local minutes:Int = CurrentTime()[3..5].toInt()
		Local seconds:Int = CurrentTime()[6..8].toInt()
		
		' hour hand:
		' the hour hand is rotated 30 degrees  per hour + 1/2 a degree per minute
		'
		SetLineWidth(4)

		DrawLine x, y, x + radius / 2 * Sin(30 * hours + minutes / 2.0), ..
				   y + radius / 2 * -Cos(30 * hours + minutes / 2.0)
		
		
		' minute hand:
		' the minute hand is rotated 6 degrees per minute + 1/10 a degree per second
		'
		SetLineWidth(2)
		DrawLine x, y, x + radius * 0.75 * Sin(6 * minutes + seconds / 10.0), ..
				   y + radius * 0.75 * -Cos(6 * minutes + seconds / 10.0)
		
		' seconds hand:
		' the second hand is rotated 6 degrees per second
		'
		SetColor(255, 0, 0)

		DrawLine x, y, x + radius * 0.7 * Sin(6 * seconds), ..
				   y + radius * 0.7 * -Cos(6 * seconds)


	End Method

	Method romanNumerals:String(value:Int)
		Local rn:String = ""
		
		While value > 9
			rn:+ "X"
			value:- 10
		Wend
	
		If value > 8 Then
			rn:+ "IX"
			value:- 9
		End If
		
		If value > 4 Then
			rn:+ "V"
			value:- 5
		End If
		
		If value > 3 Then
			rn:+ "IV"
			value:- 4
		End If
		
		While value > 0
			rn:+ "I"
			value:- 1
		Wend
		
		Return rn
	End Method

End Type

Thanks!

Brucey

(Posted 2013) [#5]

It's possible that a double click handles differently than a normal click because it is so fast.
To stop the warning, you can use :

If canvas.HasCapture()
   canvas.ReleaseMouse()
End If

or perhaps use HasCapture() elsewhere when you need to be sure it is captured.

I also believe that when you have the mouse down, it is automatically captured for the duration of the time you press the mouse button until you release it. (Can't remember where I read that tho…)

Also, if you are running a timer, you should stop it before you destruct something which it is connected to - or there is a chance the timer will tick, and call against an object (window/etc) which no longer exists. This happens with your above example on OS X ;-)
If it is still live when your window closes, you can always call Stop() on it, just to be on the safe side before your window Destroy() call.

Pete Rigz

(Posted 2013) [#6]

Cheers, that seems to have worked :)

Just another quick question about wxListCtrl. I was inserting an item like this:

		item.SetText(name)
		item.SetImage(image)
		item.SetData(shape)
		Self.InsertItem(item)

However that doesn't seem to insert anything anymore. I've had to change it to use InsertImageStringItem, and then use SetItemData separately. I don't think it liked the fact that an index wasn't being set. I tried SetID on the item before inserting it but still nothing happened. InsertImageStringItem seems to be working OK as an alternative so that's fine, just wondering if perhaps there's a bug in there?

Pete Rigz

(Posted 2013) [#7]

Actually I just tested again on a different list and using SetId on the item did work so, it does seem ok.. I must have missed something first time round :)