if enemy can see player

BlitzMax Forums/BlitzMax Beginners Area/if enemy can see player

redmoth

(Posted 2012) [#1]

Hi.
I've started a simple overhead shooter. But I want the enemies to shoot at the player depending if their angle is facing him.
What would be the best way and least resource intensive way to do this?

thanks

Last edited 2012

GfK	(Posted 2012) [#2]

I have some line intersection code that would probably do the job. It's fast, too.

Hotshot2005

(Posted 2012) [#3]

Look like METAL GEAR SOILD on NES :)

GaryV

(Posted 2012) [#4]

Nice looking GFX!

redmoth

(Posted 2012) [#5]

@GfK
I'm not great at reading code, but thanks I'll try and see if I can implement that code.

@Hotshot2005
Thanks, it doesn't play like it though, haha

@GaryV
Thanks, I'm not an artist but it's the best I can do.

redmoth

(Posted 2012) [#6]

I'm having trouble with this, this is what I have, but I can see it's wrong, but Im not sure how to fix it: Basically, a basic cone of sight:



For Local i:Int = 0 To 255
  If player1.x >= i*Cos(angle)+enemyX*tileSize  And  i*Cos(angle)+enemyX*tileSize+32
	If player1.y >= i*Sin(angle)+enemyY*tileSize And i*Sin(angle)+enemyY*tileSize+32
		Print "You've been seen"
	End If

	End If
Next

Last edited 2012

matibee

(Posted 2012) [#7]

Here's a cone of sight demo that should be fairly robust and easy to implement in your game..

SuperStrict 
Graphics 800, 600

' enemy view cone parameters
Local px:Int = 400			' position
Local py:Int = 300

Local pdir:Int = 90			' angular direction
Local viewAngle:Float = 10.0 	' viewing angle


While Not AppTerminate()
	
	cls
	
	SetColor ( 0, 0, 255 )
	DrawLine ( px, py, px + (Cos(pdir + viewAngle / 2) * 400), py + (Sin(pdir + viewAngle / 2) * 400) )
	DrawLine ( px, py, px + (Cos(pdir - viewAngle / 2) * 400), py + (Sin(pdir - viewAngle / 2) * 400) )
	DrawOval ( px - 3, py - 3, 6, 6 )
	
	If ( PointInViewAngle( MouseX(), MouseY(), px, py, pdir, viewAngle ) )
		SetColor( 255, 0, 0 )
	Else 
		SetColor( 255,255,255 )
	End If 
	
	DrawOval ( MouseX() - 4, MouseY() - 4, 8, 8 )
	
	SetColor(255,255,255)
	DrawText( "view angle     : " + viewAngle + " degrees", 0, 0 )
	DrawText( "view direction : " + pdir + " degrees", 0, 16 )
	
	Flip 
	
	If ( KeyDown( key_left ) ) pdir :+ 2
	If ( KeyDown( key_right ) ) pdir :- 2
	
	If ( KeyDown( key_Up ) ) viewAngle = Min( viewAngle + 2, 120 )
	If ( KeyDown( Key_Down ) ) viewangle = Max( 5, viewAngle - 2 )
	
	If ( KeyDown( key_a ) ) px :- 2
	If ( KeyDown( key_d ) ) pX :+ 2
	If ( KeyDown( key_w ) ) py :- 2
	If ( KeyDown( key_s ) ) py :+ 2
	
Wend 
'
'	PointInViewAngle
'
'	Returns True if point (x, y) lies inside (or on the edges of) a 2d cone at position ( coneX, coneY )
'	at an angle of coneDir, with a view angle of coneAngle 
'	
Function PointInViewAngle:Int ( x:Float, y:Float, coneX:Float, coneY:Float, coneDir:Float, coneAngle:Float )

	Local minAngle:Float = clampAngle( coneDir - coneAngle / 2 )
	Local maxAngle:Float = clampAngle( coneDir + coneAngle / 2 )
	
	Local angle:Float = clampAngle( ATan2( y - coney, x - conex ) )
	
	If ( minAngle > maxAngle )
		If (( angle >=0 And angle <= maxAngle ) Or ( angle >= minAngle And angle <= 360 )) Return True 
	End If 
	
	Return ((angle >= minAngle) And (angle <= maxAngle))
	
End Function 
'
'	ClampAngle
'
'	Limits a floating point angle to the range 360 > a > 0
'
Function clampAngle:Float( a:Float )
	While a < 0
		a :+ 360
	Wend 
	While a > 360
		a :- 360
	Wend 
	Return a
End Function

matibee

(Posted 2012) [#8]

Actually I've just realised there's some redundant code in the PointInViewAngle function. Since 'angle' is clamped to 0 to 360

If ( minAngle > maxAngle )
    If (( angle >=0 And angle <= maxAngle ) Or ( angle >= minAngle And angle <= 360 )) Return True 
End If

can just be..

If ( minAngle > maxAngle )
    If ( angle <= maxAngle Or angle >= minAngle ) Return True 
End If

redmoth

(Posted 2012) [#9]

@matibee

Thanks, that's exactly what I was looking for and I've implemented a version of it in my code. You have saved me life.

matibee

(Posted 2012) [#10]

You're welcome :)

redmoth

(Posted 2012) [#11]

I'm wondering if I can get any more help with my mathematics.

I've got square roots coming out of my ears.

Now, that I can detect a player, I want to check against my 2d array map, to see if there is a solid block in the way between the player and the enemy which would prevent him seeing the player.

the tileMap array stores the an int which is the type of tile, anything greater than 27 is a solid.( tileMap[x,y])

I've had many ideas here is one in pseudocode that didn't work.

'The distance between the enemy to the player
distance = sqr(player1.x-enemy.x)*(player1.x-enemy.x) + (player1.y-enemy.y)*(player1.y-enemy.y) 

For(i = 0 to distance)
   if(tileMap[enemy.x+i,enemy.y+i] > 27
      print "view of player blocked"
      exit loop

   end if

next

UPDATE: I've realised that this code is rubbish and doesn't take into account the direction/angle the enemy is facing in

Last edited 2012

matibee

(Posted 2012) [#12]

It would be useful to see the rest of your code. Can I assume your player and enemy positions are floating point values, where their integer positions match the tile array...

ie Enemy( x1.444, y3.222) maps to tileMap[ 1, 3 ]

??

If that's the case you can probably use the direction vector ( vx = cos(angle), vy = sin(angle ) ) and incrementally add it to the enemy position

Function VisibilityTest( enemy, distance-to-player )
checklength = 1
  vx = cos( enemy.angle )
  vy = sin( enemy.angle )
  while checklength < distance-to-player
   if ( tilemap[ enemy.x + (checklength * vx), enemy.y + (checklength * vy) ] > 27 )
       return blocked
   end if 
   checklength :+ 1
  wend
  return not-blocked
end function

Something like that anyway. If you can post code I can write and test in it would really help.

redmoth

(Posted 2012) [#13]

my other similar idea that just came but didn't work was

(by the way, both of these are in the excellent PointInViewAngle function)

       for(float i= 0 to distance) {
           if(tileMap[(x+(i*cos(angle)),y+(i*sin(angle))) > 27]
             print "view of player blocked"
             exit loop
           end if
       next

UPDATE: this only really works if the enemy is facing to the right,

Last edited 2012

Last edited 2012

Last edited 2012

matibee

(Posted 2012) [#14]

Here's an update version of my code above, with an added line of sight test..

SuperStrict 
Graphics 800, 600

' enemy view cone parameters
Local px:Int = 400			' position
Local py:Int = 300

Local pdir:Int = 90			' angular direction
Local viewAngle:Float = 10.0 	' viewing angle

Global map:Int[40,30]

For Local t:Int = 10 To 20
	map[t, 12] = 1
	map[t, 22] = 1
Next 

'
'	LOS  (Line of sight)
'
'  Checks if the centre of one tile can 'see' the centre of another tile
'
'
Function LOS:Int ( targetX:Float, targetY:Float, px:Float, py:Float )
	
	Local x0:Int = (targetX +0.5) / 20.0
	Local y0:Int = (targetY +0.5) / 20.0
	
	Local x1:Int = (px +0.5) / 20.0
	Local y1:Int = (py +0.5) / 20.0
	
	Local sx:Int, sy:Int   

	Local dx:Int = Abs(x1-x0)
  	Local dy:Int = Abs(y1-y0) 
   
	If x0 < x1 Then 
		sx = 1 
	Else 
		sx = -1
	End If 
	
   	If y0 < y1 Then 
		sy = 1 
	Else 
		sy = -1
	End If 
   
	Local err:Int = dx-dy
 
   	Repeat 
		If map[ x0, y0 ]
			Return False 
		End If 

     	If x0 = x1 And y0 = y1 
			Return True 
		End If 
		
     	Local e2:int = 2*err
     	If e2 > -dy Then 
       		err :- dy
       		x0 :+ sx
     	End If
     	If e2 < dx Then 
       		err :+ dx
       		y0 :+ sy 
     	End If
   Forever 
	
End Function 

Function DrawLOS ( targetX:Float, targetY:Float, px:Float, py:Float )
	
	Local x0:Int = (targetX +0.5) / 20.0
	Local y0:Int = (targetY +0.5) / 20.0
	
	Local x1:Int = (px +0.5) / 20.0
	Local y1:Int = (py +0.5) / 20.0
	
	Local sx:Int, sy:Int   

	Local dx:Int = Abs(x1-x0)
  	Local dy:Int = Abs(y1-y0) 
   
	If x0 < x1 Then 
		sx = 1 
	Else 
		sx = -1
	End If 
	
   	If y0 < y1 Then 
		sy = 1 
	Else 
		sy = -1
	End If 
   
	Local err:Int = dx-dy
 
   	Repeat 
		DrawRect( X0 * 20, y0 * 20, 20, 20 )

     	If x0 = x1 And y0 = y1 
			DrawRect( X0 * 20, y0 * 20, 20, 20 )
			Return
		End If 
		
     	Local e2:Int = 2*err
     	If e2 > -dy Then 
       		err :- dy
       		x0 :+ sx
     	End If
     	If e2 < dx Then 
       		err :+ dx
       		y0 :+ sy 
     	End If
   Forever 
	
End Function 


While Not AppTerminate()
	
	Cls
	
	SetColor ( 0,64,0 )
	For Local xm:Int = 0 To 39
		For Local ym:Int = 0 To 29
			If ( map[xm, ym] )
				DrawRect( xm * 20, ym * 20, 20, 20 )
			End If 
		Next 
	Next 
	
	SetColor( 64,64,64 )
	DrawLOS( px, py, MouseX(), MouseY() )
	
	SetColor( 0,128,0 )
	For Local i:Int = 0 To 800 Step 20
		DrawLine( i, 0, i, 800 )
		DrawLine( 0, i, 800, i )
	Next 
	

	
	SetColor ( 0, 0, 255 )
	DrawLine ( px, py, px + (Cos(pdir + viewAngle / 2) * 400), py + (Sin(pdir + viewAngle / 2) * 400) )
	DrawLine ( px, py, px + (Cos(pdir - viewAngle / 2) * 400), py + (Sin(pdir - viewAngle / 2) * 400) )
	DrawOval ( px - 3, py - 3, 6, 6 )
	
	If ( PointInViewAngle( MouseX(), MouseY(), px, py, pdir, viewAngle ) And LOS( MouseX(), MouseY(), px, py )  )
		SetColor( 255, 0, 0 )
	Else 
		SetColor( 255,255,255 )
	End If 
	
	DrawOval ( MouseX() - 4, MouseY() - 4, 8, 8 )
	
	SetColor(255,255,255)
	DrawText( "view angle     : " + viewAngle + " degrees", 0, 0 )
	DrawText( "view direction : " + pdir + " degrees", 0, 16 )
	
	Flip 
	
	If ( KeyDown( key_left ) ) pdir :+ 2
	If ( KeyDown( key_right ) ) pdir :- 2
	
	If ( KeyDown( key_Up ) ) viewAngle = Min( viewAngle + 2, 120 )
	If ( KeyDown( Key_Down ) ) viewangle = Max( 5, viewAngle - 2 )
	
	If ( KeyDown( key_a ) ) px :- 2
	If ( KeyDown( key_d ) ) pX :+ 2
	If ( KeyDown( key_w ) ) py :- 2
	If ( KeyDown( key_s ) ) py :+ 2
	
Wend 
'
'	PointInViewAngle
'
'	Returns True if point (x, y) lies inside (or on the edges of) a 2d cone at position ( coneX, coneY )
'	at an angle of coneDir, with a view angle of coneAngle 
'	
Function PointInViewAngle:Int ( x:Float, y:Float, coneX:Float, coneY:Float, coneDir:Float, coneAngle:Float )

	Local minAngle:Float = clampAngle( coneDir - coneAngle / 2 )
	Local maxAngle:Float = clampAngle( coneDir + coneAngle / 2 )
	
	Local angle:Float = clampAngle( ATan2( y - coney, x - conex ) )
	
	If ( minAngle > maxAngle )
		If ( angle <= maxAngle Or angle >= minAngle ) Return True 
	End If 
	
	Return ((angle >= minAngle) And (angle <= maxAngle))
	
End Function 
'
'	ClampAngle
'
'	Limits a floating point angle to the range 360 > a > 0
'
Function clampAngle:Float( a:Float )
	While a < 0
		a :+ 360
	Wend 
	While a > 360
		a :- 360
	Wend 
	Return a
End Function

This only takes the centre of the enemy and player tiles into account though, but it should be close enough.

It uses an implementation of Bresenhams line drawing algorithm from here:
http://en.wikipedia.org/wiki/Bresenham%27s_line_algorithm

You'll still have issues where it can 'see through' corners..

[*][.][.][.]
[.][\][X][X]
[.][X][\][.]
[.][X][.][*]

[*] can 'see' [*] even though there are walls [X] forming a corner between them.

I'm afraid I'm too busy to help much more atm. :)

Edit -- added line of sight drawing code...

Last edited 2012

Last edited 2012