Track & Field power bar

BlitzMax Forums/BlitzMax Beginners Area/Track & Field power bar

redmoth

(Posted 2012) [#1]

I'm trying to make a running game, like from the classic Track & Field olympics game and I'm confused about the best way to make the computer competitors build up their power/sprint bar.

The player will build up their sprint bar by quickly pressing two keys as quickly as possible, and the more power, the quicker they run.
I'm a bit confused of the best way to do this, so I'm writing it here, I may solve it myself or someone else may if they are feeling helpful.

Variables for each runner object:
power (the power bar)
speed (the current speed of tapping the keys)
maxSpeed (the rate at which the computer taps the keys)

Here's my start:

Power = power - 1 //subtract 1 automatically
if power < 0 then power = 0 // make sure it can't be a negative number

//for computers
speed = speed + maxSpeed //maxSpeed will be for example 0.01
power = power + speed

x = x + power // add to the x position of the player

redmoth

(Posted 2012) [#2]

That will continue to accelerate, so maybe if I add:
if power > 2 then power = 2

matibee

(Posted 2012) [#3]

I came up with this....

Ignore the circular buffer stuff, that's just to graph the power value. I control power between 0 and 1.0 so if your player has a very maximum speed of 20.0/second, say, (pixels, feet, inches, whatever), you just do:

x = x + 20 * power

(assuming x is also a floating point value.)

For the computer player, simply set his newPower to 0.9 or some value depending on the difficulty you require. Don't give him max power as he'll be completely unbeatable.

(Edit played with figures and added CPU opponent value)

SuperStrict 
Graphics 800, 600

Global leftKeyTime:Int
Global rightKeyTime:Int 

Global power:Float 

Type circularbuffer
	
	Global values:Float[800]
	Global pos:Int 
	
	Function AddValue( v:float )
		values[pos] = v
		pos = (pos + 1) Mod 800
	End Function 
	
	Function Draw()
		For Local x:Int = 0 To 798
			Local v:Float = 550 - ( values[ ( pos + x ) Mod 800 ] * 100 )
			Local v2:Float = 550 - ( values[ ( pos + x + 1) Mod 800 ] * 100 )
			DrawLine( x, v, x+1, v2 )
		Next 		
	End Function 
	
End Type 

	
While Not AppTerminate()
	
	
	' 	Uncomment this for an example computer opponent 
	'	and don't hit any keys...
	'
	Local newPower:Float  = 0.7 + RndFloat() * 0.2
	
	'	.. or uncomment this line and try it yourself
	'
	'Local newPower:Float

	If ( KeyHit( KEY_N ) ) 
		leftKeyTime = MilliSecs()
		newPower = 200.0 / Abs( leftKeyTime - rightKeyTime )
	Else If ( KeyHit( KEY_M ) ) 
		newPower = 200.0 / Abs( leftKeyTime - rightKeyTime )
		rightKeyTime = MilliSecs()
	End If 

	If ( newPower >= power )
		power :+ 0.03
		If ( power > newPower )
			power = newPower
		End if
	Else 
		power :- 0.005
	End If 
	
	If ( power < 0.0 ) 
		power = 0.0
	Else If ( power > 1.0 ) 
		power = 1.0
	End If 
	
	circularbuffer.AddValue( power )
		
	Cls 
		SetColor 128,128,128
		DrawLine( 0,450,800,450 )
		DrawLine( 0,550,800,550 )
		SetColor( 255,255,255 )
		DrawRect( 0, 50, power * 800, 70 )
		circularbuffer.Draw()
	Flip 1
	
Wend

Last edited 2012

Derron

(Posted 2012) [#4]

	If ( power < 0.0 ) 
		power = 0.0
	Else If ( power > 1.0 ) 
		power = 1.0
	End If

Could be exchanged with

power = Max(0, Min(1, power)) 'clamping

But than you would be "set" each update, not only in case the value is out of boundaries.

Just a personal note.

bye
Ron

redmoth

(Posted 2012) [#5]

Thank you that's awsome, and easily convertable for my game