PopupWindowMenu and Labels

BlitzMax Forums/BlitzMax Beginners Area/PopupWindowMenu and Labels

Marco A G Pinto

(Posted 2012) [#1]

Hello!

I want to use popmenus to select existing addresses from a panel, stored in labels inside the panel.

First I was trying to detect the right mouse click inside the panel but, after placing the labels, it starts working badly.

Is there a command to check if we are right clicking over a label?

Thanks!

Kind regards,
>Marco A.G.Pinto
--------------------

	Import MaxGui.Drivers
	
	'open a window
	Global window:TGadget = CreateWindow( "ZX Life Shield Professional", 100, 100, 640, 480, Null, WINDOW_TITLEBAR|WINDOW_RESIZABLE|WINDOW_MENU|WINDOW_CLIENTCOORDS|WINDOW_CENTER)

	'Addresses found panel of results
	Global panel_addresses_found_results:TGadget=CreatePanel(6+1,262+1-10-1+25-1-1,630,16+2+2+3+100+40,window,PANEL_SUNKEN|PANEL_ACTIVE)
	SetGadgetSensitivity(panel_addresses_found_results:TGadget,SENSITIZE_MOUSE)
	SetGadgetColor(panel_addresses_found_results,0,0,240)
	SetGadgetTextColor(panel_addresses_found_results,255,0,0)
	' Coordinates of x,y for displaying addresses
	x=1
	y=1 
	t=0 ' Used To display 7 addresses per line
	Global address_found[72+1]
	For f=1 To 72
		address_found[f]=CreateLabel("",x,y,50+8,18,panel_addresses_found_results)
		SetGadgetColor(address_found[f],0,0,240)
		SetGadgetTextColor(address_found[f],255,255,0)
		x=x+72+8
		t=t+1
		If t>7
			x=1
			y=y+16
			t=0
		EndIf
	Next


	Global MENU_POPUP=305
	Global MENU_POPUP_MARK=114
	Global MENU_POPUP_COPY=115

	' Create a Popup Menu - 24/JUN/2012
	Global menupopup:TGadget=CreateMenu("popup",0,Null)
	Global popupmenumark=CreateMenu("Mark/Unmark",MENU_POPUP_MARK,menupopup)
	Global popupmenucopy=CreateMenu("Copy",MENU_POPUP_COPY,menupopup)


#lp

		WaitEvent()
		t = EventID()

		If t = EVENT_APPTERMINATE End
		If t = EVENT_WINDOWCLOSE End

		'POPUP MENU
		If EventSource()=panel_addresses_found_results
			If EventData() = MOUSE_RIGHT
				Print "Popup Menu shown"
				PopupWindowMenu(window,menupopup)
			EndIf
		EndIf

		Goto lp

Scaremonger

(Posted 2012) [#2]

I suspect the problem is that your mouse click is being captured by the labels instead of the panel.

Add the following line after creating the labels but your event will not come from the panel.

SetGadgetSensitivity( address_found[f], SENSITIZE_MOUSE )

Last edited 2012

Scaremonger

(Posted 2012) [#3]

Just had a look through your code and amended it a bit. Because a label doesn't pass the event up to the panel, I added some extra data to the label objects so that I can identify them within the loop later.

SuperStrict
	Import MaxGui.Drivers
	
	'open a window
	Global window:TGadget = CreateWindow( "ZX Life Shield Professional", 100, 100, 640, 480, Null, WINDOW_TITLEBAR|WINDOW_RESIZABLE|WINDOW_MENU|WINDOW_CLIENTCOORDS|WINDOW_CENTER)

	'Addresses found panel of results
	Global panel_addresses_found_results:TGadget=CreatePanel(6+1,262+1-10-1+25-1-1,630,16+2+2+3+100+40,window,PANEL_SUNKEN|PANEL_ACTIVE)
'	SetGadgetSensitivity(panel_addresses_found_results:TGadget,SENSITIZE_MOUSE)
	SetGadgetColor(panel_addresses_found_results,0,0,240)
	SetGadgetTextColor(panel_addresses_found_results,255,0,0)
	' Coordinates of x,y for displaying addresses
	Local x%, y%, f%
	Global address_found:TGadget[72+1]
	For f=1 To 72
		address_found[f]=CreateLabel("LABEL",x,y,50+8,18,panel_addresses_found_results)

		'# Sensitize the mouse on the label and add extra information to identify it later
		SetGadgetSensitivity(address_found[f],SENSITIZE_MOUSE)
		SetGadgetExtra( address_found[f],"LABEL")
		'#
				
		SetGadgetColor(address_found[f],0,0,240)
		SetGadgetTextColor(address_found[f],255,255,0)
		
		'# Calculate next button position
		x = ( f Mod 8 ) * 80
		y = Int(f/8) *16
	Next


Global MENU_POPUP%=305
Global MENU_POPUP_MARK%=114
Global MENU_POPUP_COPY%=115

' Create a Popup Menu - 24/JUN/2012
Global menupopup:TGadget=CreateMenu("popup",0,Null)
Global popupmenumark:TGadget=CreateMenu("Mark/Unmark",MENU_POPUP_MARK,menupopup)
Global popupmenucopy:TGadget=CreateMenu("Copy",MENU_POPUP_COPY,menupopup)

Repeat
	WaitEvent()
	Select EventID()
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			End
		Case EVENT_MOUSEDOWN
			Local extra$ = String( GadgetExtra( TGadget(EventSource()) ) )
			If extra = "LABEL" Then 
						Print "Popup Menu shown"
						PopupWindowMenu(window,menupopup)
			End If			
		Default
'			DebugLog "event" + EventID()
	End Select
Forever

I also cleaned up your X/Y calculation a little and removed the GOTO. :)

Marco A G Pinto

(Posted 2012) [#4]

Thanks,

I will have a closer look at it tomorrow since it is late in Europe.

Kind regards,
>Marco A.G.Pinto
--------------------