Level editor.

BlitzMax Forums/BlitzMax Beginners Area/Level editor.

Awesome

(Posted 2012) [#1]

Hey, I'm having an issue with some code for a level editor, everything worked fine until I tried to put in the ability for it to load a previously saved file. After that the array for drawing the tiles on the screen decided it didn't need to work anymore.

For Local y:Int = 0 To mapy-1
For Local x:Int = 0 To mapx-1
Local Backtile:Int = map[x,y,0]
If Backtile > -1 Then DrawImage img_tiles:TImage,(x*tsize)-scn_left,(y*tsize) - scn_top,Backtile
Next
Next

It works if I take off the last "Backtile" and replace it with pretty much any number or other variable I've found, but then of course it draws only the tile associated with that number, or the drawn tile changes as the variable changes.

This is the full code:

SuperStrict
AppTitle="Level Editor"
Const  gwidth:Int = 1024
Const  gheight:Int = 768

Graphics gwidth, gheight

Const  tsize:Int = 32
Global mapx:Int 
Global mapy:Int 
Global mapz:Int 
Global scn_top:Int = (mapy*tsize)
Global numtiles:Int = 30
Global scn_left:Int = 0
Global CurrentTile:Int = 0
'AutoMidHandle(True)

Global img_tiles:TImage = LoadAnimImage("images\tiles.png",tsize,tsize,0,numtiles)

Local file:TStream = OpenFile("map1.txt",True,True)

If file <> Null Then 
	mapx = ReadInt(file)
	mapy = ReadInt(file)
	mapz = ReadInt(file)
Else 
	mapx = 75
	mapy = 50
	mapz = 4
EndIf 

Global map:Int[mapx,mapy,mapz]

If file <> Null Then 
	For Local x:Int = 0 To mapx-1
		For Local y:Int = 0 To mapy-1
			For Local z:Int = 0 To mapz-1
				map[x,y,z] = ReadInt(file)
			Next 
		Next
	Next
Else 
	For Local x:Int = 0 To mapx-1
		For Local y:Int = 0 To mapy-1
			For Local z:Int = 0 To mapz-1
				map[x,y,z] = -1
			Next 
		Next
	Next
EndIf 



Repeat
	
	Cls
	
	''''' Use WASD keys to move the screen '''''
	If KeyDown(key_down) And scn_top < (mapy*tsize-gheight) Then scn_top = scn_top+32
	If KeyDown(key_right) And scn_left < (mapx*tsize-gwidth) Then scn_left = scn_left+32
	If KeyDown(key_left) And scn_left > 0 Then scn_left = scn_left-32
	If KeyDown(key_up) And scn_top > 0 Then scn_top = scn_top-32
	If scn_top > (mapy*tsize-gheight)-1 Then scn_top = (mapy*tsize-gheight)-1
	If scn_left > (mapx*tsize-gwidth)-1 Then scn_left = (mapx*tsize-gwidth)-1
	''''''''''''''''''''''''''''''''''''''''''''
	
	'Local Layer:Int
		
	'If KeyHit(key_1) Then Layer=1
	'If KeyHit(key_2) Then Layer=2
	'If KeyHit(key_3) Then Layer=3
	'If KeyHit(key_4) Then Layer=4
		
	'Select Layer
	'	Case 1 'Foreground
	'	Case 2 'Collision
	'	Case 3 'Background
	'	Case 4
	'End Select	
	
	If MouseDown(1) And MouseX() > 0 And (MouseX()+scn_left)/tsize < mapx And MouseY() > 0 And (MouseY()+scn_top)/tsize < mapy Then map[(MouseX()+scn_left)/tsize,(MouseY()+scn_top)/tsize,0] = CurrentTile
	If MouseDown(2) And MouseX() > 0 And (MouseX()+scn_left)/tsize < mapx And MouseY() > 0 And (MouseY()+scn_top)/tsize < mapy Then map[(MouseX()+scn_left)/tsize,(MouseY()+scn_top)/tsize,0] = -1
	
	''''' Use mousewheel to change tile '''''
	If MouseZ() > 0 Then CurrentTile = CurrentTile + 1 ; FlushMouse 
	If MouseZ() < 0 Then CurrentTile = CurrentTile - 1 ; FlushMouse
	If MouseHit(3) Then CurrentTile = CurrentTile +1

	If CurrentTile > numtiles-1 Then CurrentTile = 0
	If CurrentTile < 0 Then CurrentTile = numtiles-1
	'''''''''''''''''''''''''''''''''''''''''

	''''' Press C to Clear the map '''''
	If KeyHit(key_c) Then 
		For Local x:Int = 0 To mapx-1
			For Local y:Int = 0 To mapy-1
				For Local z:Int = 0 To 1
					map[x,y,z] = -1
				Next 
			Next
		Next
	EndIf 
	''''''''''''''''''''''''''''''''''''
	
	''''' Press F to Fill the map '''''
	If KeyHit(key_f) Then 
		For Local x:Int = 0 To mapx-1
			For Local y:Int = 0 To mapy-1
				For Local z:Int = 0 To 1
					map[x,y,z] = CurrentTile
				Next 
			Next
		Next
	EndIf 
	''''''''''''''''''''''''''''''''''''
	
	''''' Press S to save the map '''''
	If KeyHit(key_s) Then 
		Local fileout:TStream = WriteFile("map1.txt")
		'write map dimensions
			WriteInt fileout,mapx
			WriteInt fileout,mapy
			WriteInt fileout,mapz
			WriteInt fileout,tsize

			For Local x:Int = 0 To mapx-1
				For Local y:Int = 0 To mapy-1
					For Local z:Int = 0 To mapz-1
						WriteInt fileout,map[x,y,z]
					Next 
				Next
			Next
	
		CloseFile fileout
	EndIf 
	
	'''''''''''''''''''''''''''''''''''
	
	''''''''''''''''''''''''''''''''''' Draw images '''''''''''''''''''''''''''''''''''
	
	For Local y:Int = 0 To mapy-1
		For Local x:Int = 0 To mapx-1
			Local Backtile:Int = map[x,y,0]
			If Backtile > -1 Then DrawImage img_tiles:TImage,(x*tsize)-scn_left,(y*tsize) - scn_top,Backtile
		Next
	Next
	
	If CurrentTile > -1 Then DrawImage (img_tiles:TImage,(MouseX()/tsize)*tsize,(MouseY()/tsize)*tsize,CurrentTile)
	
	Flip

Until AppTerminate() Or KeyHit(key_escape)

End

col	(Posted 2012) [#2]

Hiya,

When you're saving the file you're saving the 4 values before the map data :-

WriteInt fileout,mapx
WriteInt fileout,mapy
WriteInt fileout,mapz
WriteInt fileout,tsize

When loading them back in you're only loading back in 3 before the map data :-

If file <> Null Then 
	mapx = ReadInt(file)
	mapy = ReadInt(file)
	mapz = ReadInt(file)
	tsize = ReadInt(file) '      <--------- This was missing
Else 
	mapx = 75
	mapy = 50
	mapz = 4
EndIf

Because you have tsize as Const BMax will probably complain about this, so either don't save it or make it a variable.
Also, you're not closing the file after loading the data :-

If file <> Null Then 
	For Local x:Int = 0 To mapx-1
		For Local y:Int = 0 To mapy-1
			For Local z:Int = 0 To mapz-1
				map[x,y,z] = ReadInt(file)
			Next 
		Next
	Next
	CloseFile file '<-------------- Don't forget to close
Else 
	For Local x:Int = 0 To mapx-1
		For Local y:Int = 0 To mapy-1
			For Local z:Int = 0 To mapz-1
				map[x,y,z] = -1
			Next 
		Next
	Next
EndIf

Have fun :D

Last edited 2012

Awesome

(Posted 2012) [#3]

Perfect! Thank you very much!