laser beam code

BlitzMax Forums/BlitzMax Beginners Area/laser beam code

hub	(Posted 2010) [#1]

Hi !

i'm searching a fast method to draw a long beam. i've the following code. Perhaps have you some idea to improve/optimize it.
Thanks !

Strict

Graphics 800,600

HideMouse()

Global List_beams:TList = CreateList()

Global hImage:TImage = CreateImage (3,1)

Local pixmap:TPixmap=LockImage(hImage)
For Local i=0 To 2
	WritePixel(pixmap,i,0,$ffffffff)
Next
UnlockImage(hImage)

Type Tbeam

	Field ox#
	Field oy#
	Field dx#
	Field dy#
	Field Width
	Field Speed#
	
	Function Init:Tbeam (x,y, Width, Speed#)
	
		Local l:Tbeam = New Tbeam
		
		l.ox# = x
		l.oy# = y
		l.dx# = x
		l.dy# = y
		l.Width = Width	
		l.Speed = Speed
		
		ListAddLast List_beams, l
	
	End Function	
	
	Function Compute_all()
		For Local l:Tbeam = EachIn List_beams
			If Abs (l.oy-l.dy) <> l.Width Then
				l.dy = l.dy - 1 * l.Speed#
			Else
				If l.dy > 0 Then
					l.dy = l.dy - 1 * l.Speed#
				End If
				If l.oy > 0 Then 
					l.oy = l.oy - 1 * l.Speed#
				End If
			End If
			If l.oy# < 0 Then
				List_beams.remove l
			End If
		Next
	End Function
	
	Function Draw_all()
		For Local l:Tbeam = EachIn List_beams
			'SetColor 0,255,0
			'DrawLine l.ox-10, l.oy,l.dx#-10, l.dy#
			SetColor 255,0,0
			SetScale 1.0,l.dy#-l.oy#
			DrawImage himage, l.ox, l.oy
			SetScale 1,1
			SetColor 255,255,255

		Next
	End Function
	
End Type

While Not KeyDown(KEY_eSCAPE)
	Cls
		SetColor 255,255,255
		Plot MouseX(), MouseY()
		
		If MouseHit(1) Then Tbeam.Init (MouseX(), MouseY(), 200,10)
		
		Tbeam.Compute_all()
		Tbeam.Draw_all()
		
	Flip
Wend

ShowMouse()

Last edited 2010

Perturbatio

(Posted 2010) [#2]

To demonstrate the speed up from my code, here's your one modified to have a simple FPS calc and no refresh limit (with some bug fixes):

Strict

Graphics 800,600,0,0

HideMouse()

Global List_beams:TList = CreateList()

Global hImage:TImage = CreateImage (3,1)

Local pixmap:TPixmap=LockImage(hImage)
For Local i=0 To 2
	WritePixel(pixmap,i,0,$ffffffff)
Next
UnlockImage(hImage)

Type Tbeam

	Field ox#
	Field oy#
	Field dx#
	Field dy#
	Field Width
	Field Speed#
	
	Function Init:Tbeam (x,y, Width, Speed#)
	
		Local l:Tbeam = New Tbeam
		
		l.ox# = x
		l.oy# = y
		l.dx# = x
		l.dy# = y
		l.Width = Width	
		l.Speed = Speed
		
		ListAddLast List_beams, l
	
	End Function	
	
	Function Compute_all()
		For Local l:Tbeam = EachIn List_beams
			If Abs (l.oy-l.dy) <> l.Width Then
				l.dy = l.dy - 1 * l.Speed#
			Else

				l.dy = l.dy - 1 * l.Speed#
				l.oy = l.oy - 1 * l.Speed#

			End If
			If l.oy# < 0 Then
				List_beams.remove l
			End If
		Next
	End Function
	
	Function Draw_all()
		For Local l:Tbeam = EachIn List_beams
			'SetColor 0,255,0
			'DrawLine l.ox-10, l.oy,l.dx#-10, l.dy#
			SetColor 255,0,0
			SetScale 1.0,l.dy#-l.oy#
			DrawImage himage, l.ox, l.oy
			SetScale 1,1
			SetColor 255,255,255

		Next
	End Function
	
End Type

Local frameCount: Int = 0
Local fps:Int = 0
Local startTime:Int = MilliSecs()

While Not KeyDown(KEY_eSCAPE)
	Cls
		SetColor 255,255,255
		Plot MouseX(), MouseY()
		
		If MouseDown(1) Then Tbeam.Init (MouseX(), MouseY(), 200,10)
		
		Tbeam.Compute_all()
		Tbeam.Draw_all()
		DrawText "FPS: " + fps, 10, 10
		DrawText "count: " + CountList(List_beams), 10, 22
		frameCount:+1
		If (MilliSecs()-startTime >= 1000) Then
			fps = frameCount
			frameCount = 0;
			startTime = MilliSecs()
		EndIf
	Flip
Wend

ShowMouse()

And my code:

SuperStrict
Graphics 800,600',0, 0

HideMouse()

Global List_beams:TList = CreateList()
Global hImage:TImage = CreateImage (5,1)
Global laserLength:Float = 20
Global laserSpeed:Float = 10
Global laserRepeatRate:Int = 200
Global laserLastFired:Int = 0

Local pixmap:TPixmap=LockImage(hImage)
Local colourMap:String[hImage.width]
Local stp:Int = 180/(hImage.width-1)
Local i:Float, index:Int


While index < hImage.width

	colourMap[index] = ( "$" + ByteHex( 255*Sin(i) ) + "777777" )
	'Print (colourMap[ index ])

	i:+ stp
	index:+ 1
	
Wend


For Local y:Int=0 To hImage.height-1

	For Local x:Int=0 To hImage.width-1
		
		WritePixel( pixmap,x,y, Int(colourMap[x] ))
		
	Next
Next

UnlockImage(hImage)


Type Tbeam

	Field ox:Float
	Field oy:Float
	Field dx:Float
	Field dy:Float
	Field Length:Float
	Field Speed:Float
	Field link:TLink
	
	Function Init:Tbeam (x:Float,y:Float, Length:Float, Speed:Float)
	
		Local l:Tbeam = New Tbeam
		
		l.ox# = x
		l.oy# = y
		l.dx# = x
		l.dy# = y
		l.Length = Length	
		l.Speed = Speed
		
		l.link:TLink = List_beams.addLast( l ) 'store a TLink reference in the object for fast reference and removal

	
	End Function	
	
	
	Function Compute_all()
		For Local l:Tbeam = EachIn List_beams
		
			If Abs (l.oy-l.dy) < l.Length Then
				l.dy = l.dy - 1 * l.Speed#
			Else
				l.dy = l.dy - 1 * l.Speed#
				l.oy = l.oy - 1 * l.Speed#
			End If
			
			If l.oy# < 0 Then 
				l.link.remove() 'removing a link is much faster since it can just re-assign it's prev and next items to each other
			End If
		Next
	End Function
	
	
	Function Draw_all()
		Local oldR : Int, oldG : Int, oldB : Int
		Local oldBlend :Int = GetBlend()
		GetColor oldR, oldG, oldB
		'SetColor 50,50,255
		SetColor 255,0,0
		SetBlend LIGHTBLEND
		For Local l:Tbeam = EachIn List_beams
			'SetColor 0,255,0
			'DrawLine l.ox-10, l.oy,l.dx#-10, l.dy#
			
			SetAlpha(0.25)
			SetScale 4, (l.dy#-l.oy#)'*1.1
			DrawImage himage, l.ox - ( himage.width * 1.5), l.oy' + (l.length * 0.05)
			
			SetAlpha(0.5)
			SetScale 2, (l.dy#-l.oy#)'*1.05
			DrawImage himage, l.ox - ( himage.width / 2), l.oy' + (l.length * 0.025)
			
			SetAlpha(1)
			
			SetScale 1.0,l.dy#-l.oy#
			DrawImage himage, l.ox, l.oy
			SetScale 1,1


		Next
		SetColor oldR,oldG,oldB
		SetBlend oldBlend
	End Function
	
End Type

SetColor 255,255,255

Local frameCount: Int = 0
Local fps:Int = 0
Local startTime:Int = MilliSecs()

While Not KeyDown(KEY_eSCAPE)
	Cls

		Plot MouseX(), MouseY()
		
		If MouseDown(1) Then 
			If (MilliSecs() - laserRepeatRate > laserLastFired) Then
				Tbeam.Init (MouseX(), MouseY(), laserLength, laserSpeed)
				laserLastFired = MilliSecs()
			EndIf
		EndIf
		
		Tbeam.Compute_all()
		Tbeam.Draw_all()
		DrawText "FPS: " + fps, 10, 10
		'DrawText "count: " + CountList(List_beams), 10, 22
		frameCount:+1
		If (MilliSecs()-startTime >= 1000) Then
			fps = frameCount
			frameCount = 0;
			startTime = MilliSecs()
		EndIf
	Flip
	
	
Wend

ShowMouse()

Function ByteHex:String( val:Byte )
	Local buf:Short[2]
	For Local k:Int=1 To 0 Step -1
		Local n:Int=(val&15)+Asc("0")
		If n>Asc("9") n=n+(Asc("A")-Asc("9")-1)
		buf[k]=n
		val:Shr 4
	Next
	Return String.FromShorts( buf,2 )
End Function

I get a difference of about 2000 FPS between yours and mine (and it looks a little nicer)

I added the ability to adjust the width of the graphic, added alpha to the graphic edges and created blurred duplicates to try to add a glow.

Also added laser repeat rate and speed

Last edited 2010

Last edited 2010

hub	(Posted 2010) [#3]

Thanks Perturbatio !

Perturbatio

(Posted 2010) [#4]

yar!