Right Click Buttons with RequestFile Error

BlitzMax Forums/BlitzMax Beginners Area/Right Click Buttons with RequestFile Error

xmlspy

(Posted 2010) [#1]

Recently I added sensitivity to some buttons for right button clicks. My problem is that for some reason when you pair it with RequestFile it seems like the event is repeated again and again, and again. Try it out.

Strict
Import MaxGui.Drivers

Global mWin:TGadget = CreateWindow("Window",0,0,200, 200 ,Null, WINDOW_RESIZABLE + WINDOW_TOOL + WINDOW_TITLEBAR)
Global mWin_B1:TGadget = CreateButton("My Button", 5, 5, ClientWidth(mWin)-10, ClientHeight(mWin)-10, mWin, BUTTON_PUSH)
SetGadgetSensitivity( mWin_B1, SENSITIZE_MOUSE )

AddHook EmitEventHook, eventHandler

'Main Loop
Repeat
	WaitEvent()
Forever


Function eventHandler:Object( pID%, pData:Object, pContext:Object )
	Local pEvent:TEvent = TEvent(pData)
	If Not pEvent Then Return pData
	
	Local file:String
	Local filter:String = "All Files:*"
		
	Select pEvent.id
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			End
		
		'Classic left click
		Case EVENT_GADGETACTION
			Select pEvent.Source
				Case mWin_B1
					Print "Left Click"
					SetGadgetText(mWin_B1, "Left Click")
			End Select
		
		'Right click on gadgets
		Case EVENT_MOUSEUP
			If pEvent.Data = 2 Then
				Select pEvent.Source
					Case mWin_B1
						Print "Right Click"
						file = RequestFile("Pick Any", filter)
						SetGadgetText(mWin_B1, file)
				End Select
			EndIf
	End Select
End Function

If you remove the RequestFile function then there's no issues. If you can't emulate the problem try switching to another program and then right click on the button directly instead of the window. Anyone know a fix for this?

Is there a way to maybe flush all of the events after a RequestFile? I'm new to BlitzMax so I'm not familiar with many things. Thanks.

Other details:
Win 7 Home Premium
BlitzMax 1.41 and MaxGui 1.41

xmlspy

(Posted 2010) [#2]

There are lots of events when you do right clicks. So, what needs to be done is to have a method that will allow one click per button to happen even if there's tons of events.

Solution:


Strict
Import MaxGui.Drivers

'This is what you need per button
Global mWin_B1_Pressed:Int = 0

Global mWin:TGadget = CreateWindow("Window",0,0,200, 200 ,Null, WINDOW_RESIZABLE + WINDOW_TOOL + WINDOW_TITLEBAR)
Global mWin_B1:TGadget = CreateButton("My Button", 5, 5, ClientWidth(mWin)-10, ClientHeight(mWin)-10, mWin, BUTTON_PUSH)
SetGadgetSensitivity( mWin_B1, SENSITIZE_MOUSE )

AddHook EmitEventHook, eventHandler

'Main Loop
Repeat
	WaitEvent()
Forever


Function eventHandler:Object( pID%, pData:Object, pContext:Object )
	Local pEvent:TEvent = TEvent(pData)
	If Not pEvent Then Return pData
	
	Local file:String
	Local filter:String = "All Files:*"
		
	Select pEvent.id
		Case EVENT_WINDOWCLOSE, EVENT_APPTERMINATE
			End
		
		'Classic left click
		Case EVENT_GADGETACTION
			Select pEvent.Source
				Case mWin_B1
					Print "Left Click"
					SetGadgetText(mWin_B1, "Left Click")
			End Select
		
		'Right click on gadgets
		Case EVENT_MOUSEUP
			If pEvent.Data = 2 Then
				Select pEvent.Source
					Case mWin_B1
						If mWin_B1_Pressed = 0 Then
							mWin_B1_Pressed = 1
							Print "Right Click"
							file = RequestFile("Pick Any", filter)
							SetGadgetText(mWin_B1, file)
							mWin_B1_Pressed = 0
						EndIf
				End Select
			EndIf
	End Select
End Function