Explode and Count Functions inside

BlitzMax Forums/BlitzMax Beginners Area/Explode and Count Functions inside

coffeedotbean

(Posted 2010) [#1]

I had to use PHP for a bit and realised Blitz does not have an Explode function (unless I missed it). So I made my own, I also had to make a count function to to return the number of elements in an array. Works on Strict did not attempt to fix it for superstrict.

For those that dont know what explode is then... Explode returns an array of strings, each of which is a substring of string formed by splitting it on boundaries formed by the string delimiter.

Added an Implode function.. why not. =D

Function syntax

Explode(String:String , Delimiter:string , [Add_Last_Part=True])

Implode(Array:string , Delimiter:String , [Add_Delimiter_To_End=False]

Count(array[]:String)

Example

' Example 2
Print ""
Local Name_String:String = "James Brown[+]Emma Hillman[+]David Bean[+]Laura King[+]Bill Jones[+]Santa Clause"
Local Name_Delimiter:String = "[+]"
Local Names:String[] = explode(Name_String , Name_Delimiter)
Print "Total Names: "+Count(Names)
For Local i=0 To Count(Names)-1 ; Print i+": "+Names[i] ; Next
Print ""
Local New_Name_String:String = Implode(Names , "%")
Print New_Name_String

' Example 1
Print ""
Local Numbers:String[] = explode("1,0,2,1,1,1,2,0,0,1" , ",")
Print "Total Numbers: "+Count(Numbers)
For Local i=0 To Count(Numbers)-1 ; Print i+": "+Numbers[i] ; Next
Print""
Local New_Numbers_String:String = Implode(Numbers , "abc" , 1)
Print New_Numbers_String

Explode Function

 
Function Explode:String[]( Raw_String:String , Delimiter:String , Add_Last_Part:Int = True)
	
	' Store the number of parts created
	Local Parts_Count:Int = 1
	
	' Store the exploded parts in an array
	Local Parts_Array:String[]
	
	' Replace original delimiter with a rarly used extened ascii character "" (ascii # 17) - change this If you use this character
	Raw_String = Replace(Raw_String , Delimiter , Chr(17))
	
	' Set delimiter to "" (ascii # 17)
	Delimiter = Chr(17)
	
	' Store string for a part
	Local Part_String:String
	
	' Position within the String
	Local Chr_Pos
	
	' Break up the string into parts
	Repeat
		Local Chr_r:String = Mid(Raw_String , Chr_Pos , 1)
		If Chr_r = Delimiter
			' Add Part to array
			Parts_Array = Parts_Array[..Parts_Count] ; Parts_Array[Parts_Count-1] = Part_String ; Parts_Count:+ 1 
			Part_String = ""
			Chr_Pos:+ 1
		Else
			' Build Part
			Part_String:+ Chr_r
			Chr_Pos:+ 1
		EndIf
		' Exit as we reached the end of the string - dont add last part if flagged
		If Chr_Pos > Len(Raw_String)
			If Add_Last_Part = True Then Parts_Array = Parts_Array[..Parts_Count] ; Parts_Array[Parts_Count-1] = Part_String
			Exit
		EndIf
	Forever
	
	' Return the array of parts  		
	Return Parts_Array
	
EndFunction

Implode Function

Function Implode:String(Temp_Array:String[] , Delimiter:String , Add_Delimiter_To_End:Int = False)
	
	Local New_String:String
	
	For Local i = 0 To Count(Temp_Array)-1
		If i > 0 Then New_String:+ Delimiter
		New_String:+ Temp_Array[i]
	Next
	
	If Add_Delimiter_To_End = True Then New_String:+ Delimiter
	
	Return New_String
End Function

Count Function

Function Count:Int(temp_array:String[])
	
	' Count the array elements
	Local i ; For i=EachIn temp_array.Dimensions() ; Next		
	
	' Return the number of elements starting at 1
	Return i
	
End Function

Czar Flavius

(Posted 2010) [#2]

Do you know about array.Length?

degac

(Posted 2010) [#3]

mmm

String.Join and String.Split are already present in BlitzMax and they work in a similar way of Explode and Implode

Jesse

(Posted 2010) [#4]

we can all blame this thread on BlitzMax great documentation.

Czar Flavius

(Posted 2010) [#5]

Well, it would have been good for the soul in any case.

coffeedotbean

(Posted 2010) [#6]

HAHA no I didn't know about String.Join, String.Split or Array.Length.

But my main focus was retaining the simpleness of the explode and associated functions.

My_Array$[] = Explode(MyString$,MyDelimiter$)

Returns all the elements of the string in My_Array$[], You can then do this

for i = 0 to count(My_Array)-1
print i
next

handy for saving, loading level files that store data like:

1,0,2,3,1,67,32,12,34,8 etc..

Dreamora

(Posted 2010) [#7]

its count(My_Array)-1 cause you start indexing at 0 not 1

coffeedotbean

(Posted 2010) [#8]

^^ ah of course.... just testing you guys.

Oddball

(Posted 2010) [#9]

I prefer using Until instead of -1.

For i=0 Until count(My_Array)

But that's just a personal preference.

Czar Flavius

(Posted 2010) [#10]

Use an editor like Blide and the autosuggestions will allow you to discover all kinds of commands you never knew existed!

Kurator

(Posted 2010) [#11]

these are your functions using methods provided by BMax

Function Explode:String[](Raw_String:String , Delimiter:String , Add_Last_Part:Int = True )
	Local result:String[] = Raw_String.Split(Delimiter)
	If Not Add_Last_Part Then
		result = result[..result.Length-1]
	EndIf
	Return result
EndFunction

Function Implode:String(Temp_Array:String[] , Delimiter:String , Add_Delimiter_To_End:Int = False)
	Local result:String = Delimiter.Join(Temp_Array)
	If Add_Delimiter_To_End = True Then result:+ Delimiter
	Return result
End Function

Function Count:Int(temp_array:String[])
	Return temp_array.Length
End Function

coffeedotbean

(Posted 2010) [#12]

^^ nice one.

Think I need to try and find some info on methods, the only built in one I knew about was Sort.

Thanks all.

Htbaa

(Posted 2010) [#13]

A quote from the Array documentation:

Arrays also provide a read-only length field that returns the total number of elements in the array

Although it's easy enough to overlook it :-).

But why use these functions? I find using array.Length, string.Join and string.Split easier and more natural.

coffeedotbean

(Posted 2010) [#14]

Any way of finding the number of elements in a multidimensional array?

eg,

Width =19
Height = 14
Array[Width,Height]

Lets pretend we dont know that Width & Height is.

Array.length will return 266 which is Width*Height - all elements

Any way of finding the number of Width elements which in this case should return 19?

Array.Dimensions() will return the number of elements in the last Dimension, that's as close as I have got.

EDIT:

Ok I found a solution

[quote]
print Array.Dimensions()[1]
print Array.Dimensions()[0]
..etc
[quote]