Brain stops! Play how to count the keys in TMap?

BlitzMax Forums/BlitzMax Beginners Area/Brain stops! Play how to count the keys in TMap?

Arowx

(Posted 2009) [#1]

That's it really how do I get the count of elements in a Map?

Brucey

(Posted 2009) [#2]

Subclass it, and override the Insert/Remove to keep a count yourself? :-)

Arowx

(Posted 2009) [#3]

TMapCounter hmm just wrap the insert and remove calls...

Yep that would be the clever way to do it!

But I've gone for the the hack of reading through all the keys and adding them to a list then counting them! ;o)

Did I mention that my brain doesn't seem to wake up until early evening and then not for long!

Brucey

(Posted 2009) [#4]

TMapCounter hmm just wrap the insert and remove calls...

And Clear() too, I suppose.

But I've gone for the the hack of reading through all the keys and adding them to a list then counting them!

That's certainly one way to do it ;-)

GfK	(Posted 2009) [#5]

But I've gone for the the hack of reading through all the keys and adding them to a list then counting them! ;o)

If you must do it that way, you don't need to add them to a list then count the list - just increment a counter.

Arowx

(Posted 2009) [#6]

If you must do it that way, you don't need to add them to a list then count the list - just increment a counter.

Yep but I'm streaming them to a file next, so I thought I might as well keep the keys in a list to loop through accessing the values for streaming, but I could be wrong maybe I should benchmark it ;o)

Azathoth

(Posted 2009) [#7]

For EachIn?

plash

(Posted 2009) [#8]

From duct.objectmap:

Rem
	bbdoc: The ObjectMap type.
	about: This type is intended to be used abstractly (extend it), but still usable otherwise.
End Rem
Type TObjectMap
	
	Field m_count:Int
	Field m_map:TMap
	
		Method New()
			
			m_map = New TMap
			
		End Method
		
		Rem
			bbdoc: Insert an object into the map.
			returns: Nothing.
			about: This method does not provide Null checking.
		End Rem
		Method _Insert(key:Object, value:Object)
			
			m_map.Insert(key, value)
			m_count:+1
			
		End Method
		
		Rem
			bbdoc: Remove a key from the map.
			returns: True if the key was removed from the map, or False if it was not.
			about: Count is lowered by 1 if the key was removed.
		End Rem
		Method _Remove:Int(key:Object)
			
			If m_map.Remove(key) = True
				
				m_count:-1
				Return True
				
			End If
			
			Return False
			
		End Method
		
		Rem
			bbdoc: Get a value by its key.
			returns: An object or Null (not found).
		End Rem
		Method _ValueByKey:Object(key:Object)
			
			If key = Null Then Return Null
			Return m_map.ValueForKey(key)
			
		End Method
		
		Rem
			bbdoc: Check if a key is in the map.
			returns: True if the key is in the map, or False if it is not.
		End Rem
		Method _Contains:Int(key:Object)
			
			Return m_map.Contains(key)
			
		End Method
		
		Rem
			bbdoc: Clear the map.
			returns: Nothing.
			about: Count is zeroed.
		End Rem
		Method Clear()
			
			m_map.Clear()
			m_count = 0
			
		End Method
		
		Rem
			bbdoc: Get the number of entries in the map.
			returns: Nothing.
		End Rem
		Method Count:Int()
			
			Return m_count
			
		End Method
		
		Rem
			bbdoc: Get the value enumerator for the map.
			returns: Nothing.
		End Rem
		Method ValueEnumerator:TMapEnumerator()
			
			Return m_map.Values()
			
		End Method
		
		Rem
			bbdoc: Get the key enumerator for the map.
			returns: Nothing.
		End Rem
		Method KeyEnumerator:TMapEnumerator()
			
			Return m_map.Keys()
			
		End Method
		
End Type

NOTE: This does not check if it should really add to the counter if you set a value to a key that has already been set.

kfprimm

(Posted 2009) [#9]

Function CountMapKeys(map:TMap)
	Local count
	For Local key=EachIn MapKeys(map)
		count:+1
	Next
	Return count
End Function

Something like this, maybe?

N	(Posted 2009) [#10]

While we're posting random solutions...

Strict

Type TCountingMap Extends TMap
	Field _count:Int
	
	Method Count:Int()
		Return _count
	End Method
	
	Method Insert(key:Object, value:Object)
		If Not Self.Contains(key) Then
			_count :+ 1
		EndIf
		Super.Insert key, value
	End Method
	
	Method Remove(key:Object)
		If Self.Contains(key) Then
			_count :- 1
			Super.Remove key
		EndIf
	End Method
End Type

Costs more to insert/remove items, since I decided not to override the private methods to handle counting and instead stuck to the public interface like a good boy would.

plash

(Posted 2009) [#11]

Costs more to insert/remove items

The speed bit is why I did not do that to my type. Also, I hardly ever use the count feature.