Decreasing Timer

BlitzMax Forums/BlitzMax Beginners Area/Decreasing Timer

doswelk

(Posted 2009) [#1]

I need a little help:

I am trying to work out how to have a timer that stores 10 seconds that will count down backwards when a key is pressed. This timer would need to be real time not based on the games logic speed.

If the same key is pressed again the timer stops.

The code is set to run under superstrict what is the best variable type to store millsecs? Long ? or given the length of time her just an int or float?

Also is a player picks up a power up I want it to add 5 seconds of time back to the timer (but not exceeding the original 10 seconds).

I know this probably easy but for some reason I am stumped.

matibee

(Posted 2009) [#2]

Here's one way using Millisecs() and keeping track of delta time (the time between frames)..

SuperStrict 

Graphics 300,300

Local countdown:Int = 10000
Local lastMillisecs:Int = MilliSecs()
Local currentMillisecs:Int 

repeat
	' get the time now
	currentMillisecs = MilliSecs()
	
	' work out how much time has elapsed since we last ran this loop
	Local timeElapsed:Int = currentMillisecs - lastMillisecs 
	
	' keep the time for the next run round this loop
	lastMillisecs = currentMillisecs

	
	If ( keyhit( KEY_SPACE ) )
		countdown = Min( countdown + 5000, 10000 ) ' add 5 seconds, or 5 * 1000 milliseconds
	End if
	
	' decrease the countdown if it's greater than zero
	If ( countdown > 0 )
		countdown :- timeElapsed
		' check we've not gone below zero
		If ( countdown < 0 )
			countdown = 0
		End If 
	End If 
	
	cls
	
	' wholeSecondsRemaining is the countdown / 1000
	' but for the purpose of the display we do (countdown + 999) / 1000
	'
	' example; 999 to 0 	will return Zero seconds (so the player gets a 
	'					whole second of time where the clock reads zero,
	'					which is a bit odd, don't you think?)
	'
	' By adding 999, we round it down to a more natural number
	'
	Local wholeSecondsRemaining:Int = (countdown + 999) / 1000
	
	If ( wholeSecondsRemaining )
		SetColor 255,255,255
	else
		SetColor 255,0,0
	End If 
	
	DrawText( "countdown: " + wholeSecondsRemaining, 20, 20 )
	
	Flip 
	
Until (KeyHit( key_escape) )

If you're moving sprites around the screen and want their movement to be independent of the frame time too, their speed has to be in relation to timeElapsed.

Another, simpler way, is to set up a timer that limits your logic to a fixed frames per second...

SuperStrict 

Graphics 300,300

Local countdown:Int = 10000

' start a timer running at 30 frames per second
Local timer:TTimer = CreateTimer( 30 )

Repeat
	
	' wait until the timer lets us continue
	WaitTimer( timer )
	
	If ( KeyHit( KEY_SPACE ) )
		countdown = Min( countdown + 5000, 10000 ) ' add 5 seconds, or 5 * 1000 milliseconds
	End If
	
	' decrease the countdown if it's greater than zero
	If ( countdown > 0 )
		countdown :- 33  ' decrease the counter by 1000 / 30
		' check we've not gone below zero
		If ( countdown < 0 )
			countdown = 0
		End If 
	End If 
	
	Cls
	
	Local wholeSecondsRemaining:Int = (countdown + 999) / 1000
	
	If ( wholeSecondsRemaining )
		SetColor 255,255,255
	Else
		SetColor 255,0,0
	End If 
	
	DrawText( "countdown: " + wholeSecondsRemaining, 20, 20 )
	
	Flip 
	
Until (KeyHit( key_escape) )

doswelk

(Posted 2009) [#3]

Thanks for those most useful...